cpstrf.f

Go to the documentation of this file.

*> \brief \b CPSTRF
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CPSTRF + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cpstrf.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cpstrf.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cpstrf.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CPSTRF( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
* 
*       .. Scalar Arguments ..
*       REAL               TOL
*       INTEGER            INFO, LDA, N, RANK
*       CHARACTER          UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX            A( LDA, * )
*       REAL               WORK( 2*N )
*       INTEGER            PIV( N )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CPSTRF computes the Cholesky factorization with complete
*> pivoting of a complex Hermitian positive semidefinite matrix A.
*>
*> The factorization has the form
*>    P**T * A * P = U**H * U ,  if UPLO = 'U',
*>    P**T * A * P = L  * L**H,  if UPLO = 'L',
*> where U is an upper triangular matrix and L is lower triangular, and
*> P is stored as vector PIV.
*>
*> This algorithm does not attempt to check that A is positive
*> semidefinite. This version of the algorithm calls level 3 BLAS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrix A is stored.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
*>          n by n upper triangular part of A contains the upper
*>          triangular part of the matrix A, and the strictly lower
*>          triangular part of A is not referenced.  If UPLO = 'L', the
*>          leading n by n lower triangular part of A contains the lower
*>          triangular part of the matrix A, and the strictly upper
*>          triangular part of A is not referenced.
*>
*>          On exit, if INFO = 0, the factor U or L from the Cholesky
*>          factorization as above.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] PIV
*> \verbatim
*>          PIV is INTEGER array, dimension (N)
*>          PIV is such that the nonzero entries are P( PIV(K), K ) = 1.
*> \endverbatim
*>
*> \param[out] RANK
*> \verbatim
*>          RANK is INTEGER
*>          The rank of A given by the number of steps the algorithm
*>          completed.
*> \endverbatim
*>
*> \param[in] TOL
*> \verbatim
*>          TOL is REAL
*>          User defined tolerance. If TOL < 0, then N*U*MAX( A(K,K) )
*>          will be used. The algorithm terminates at the (K-1)st step
*>          if the pivot <= TOL.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (2*N)
*>          Work space.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          < 0: If INFO = -K, the K-th argument had an illegal value,
*>          = 0: algorithm completed successfully, and
*>          > 0: the matrix A is either rank deficient with computed rank
*>               as returned in RANK, or is indefinite.  See Section 7 of
*>               LAPACK Working Note #161 for further information.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complexOTHERcomputational
*
*  =====================================================================
      SUBROUTINE cpstrf( UPLO, N, A, LDA, PIV, RANK, TOL, WORK, INFO )
*
*  -- LAPACK computational routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      REAL               tol
      INTEGER            info, lda, n, rank
      CHARACTER          uplo
*     ..
*     .. Array Arguments ..
      COMPLEX            a( lda, * )
      REAL               work( 2*n )
      INTEGER            piv( n )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      COMPLEX            cone
      parameter( cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      COMPLEX            ctemp
      REAL               ajj, sstop, stemp
      INTEGER            i, itemp, j, jb, k, nb, pvt
      LOGICAL            upper
*     ..
*     .. External Functions ..
      REAL               slamch
      INTEGER            ilaenv
      LOGICAL            lsame, sisnan
      EXTERNAL           slamch, ilaenv, lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, cherk, clacgv, cpstf2, csscal, cswap,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          conjg, max, min, REAL, sqrt, maxloc
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CPSTRF', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   return
*
*     Get block size
*
      nb = ilaenv( 1, 'CPOTRF', uplo, n, -1, -1, -1 )
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL cpstf2( uplo, n, a( 1, 1 ), lda, piv, rank, tol, work,
     $                info )
         go to 230
*
      ELSE
*
*     Initialize PIV
*
         DO 100 i = 1, n
            piv( i ) = i
  100    continue
*
*     Compute stopping value
*
         DO 110 i = 1, n
            work( i ) = REAL( A( I, I ) )
  110    continue
         pvt = maxloc( work( 1:n ), 1 )
         ajj = REAL( A( PVT, PVT ) )
         IF( ajj.EQ.zero.OR.sisnan( ajj ) ) THEN
            rank = 0
            info = 1
            go to 230
         END IF
*
*     Compute stopping value if not supplied
*
         IF( tol.LT.zero ) THEN
            sstop = n * slamch( 'Epsilon' ) * ajj
         ELSE
            sstop = tol
         END IF
*
*
         IF( upper ) THEN
*
*           Compute the Cholesky factorization P**T * A * P = U**H * U
*
            DO 160 k = 1, n, nb
*
*              Account for last block not being NB wide
*
               jb = min( nb, n-k+1 )
*
*              Set relevant part of first half of WORK to zero,
*              holds dot products
*
               DO 120 i = k, n
                  work( i ) = 0
  120          continue
*
               DO 150 j = k, k + jb - 1
*
*              Find pivot, test for exit, else swap rows and columns
*              Update dot products, compute possible pivots which are
*              stored in the second half of WORK
*
                  DO 130 i = j, n
*
                     IF( j.GT.k ) THEN
                        work( i ) = work( i ) +
     $                              REAL( CONJG( A( J-1, I ) )*
     $                                    a( j-1, i ) )
                     END IF
                     work( n+i ) = REAL( A( I, I ) ) - work( i )
*
  130             continue
*
                  IF( j.GT.1 ) THEN
                     itemp = maxloc( work( (n+j):(2*n) ), 1 )
                     pvt = itemp + j - 1
                     ajj = work( n+pvt )
                     IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
                        a( j, j ) = ajj
                        go to 220
                     END IF
                  END IF
*
                  IF( j.NE.pvt ) THEN
*
*                    Pivot OK, so can now swap pivot rows and columns
*
                     a( pvt, pvt ) = a( j, j )
                     CALL cswap( j-1, a( 1, j ), 1, a( 1, pvt ), 1 )
                     IF( pvt.LT.n )
     $                  CALL cswap( n-pvt, a( j, pvt+1 ), lda,
     $                              a( pvt, pvt+1 ), lda )
                     DO 140 i = j + 1, pvt - 1
                        ctemp = conjg( a( j, i ) )
                        a( j, i ) = conjg( a( i, pvt ) )
                        a( i, pvt ) = ctemp
  140                continue
                     a( j, pvt ) = conjg( a( j, pvt ) )
*
*                    Swap dot products and PIV
*
                     stemp = work( j )
                     work( j ) = work( pvt )
                     work( pvt ) = stemp
                     itemp = piv( pvt )
                     piv( pvt ) = piv( j )
                     piv( j ) = itemp
                  END IF
*
                  ajj = sqrt( ajj )
                  a( j, j ) = ajj
*
*                 Compute elements J+1:N of row J.
*
                  IF( j.LT.n ) THEN
                     CALL clacgv( j-1, a( 1, j ), 1 )
                     CALL cgemv( 'Trans', j-k, n-j, -cone, a( k, j+1 ),
     $                           lda, a( k, j ), 1, cone, a( j, j+1 ),
     $                           lda )
                     CALL clacgv( j-1, a( 1, j ), 1 )
                     CALL csscal( n-j, one / ajj, a( j, j+1 ), lda )
                  END IF
*
  150          continue
*
*              Update trailing matrix, J already incremented
*
               IF( k+jb.LE.n ) THEN
                  CALL cherk( 'Upper', 'Conj Trans', n-j+1, jb, -one,
     $                        a( k, j ), lda, one, a( j, j ), lda )
               END IF
*
  160       continue
*
         ELSE
*
*        Compute the Cholesky factorization P**T * A * P = L * L**H
*
            DO 210 k = 1, n, nb
*
*              Account for last block not being NB wide
*
               jb = min( nb, n-k+1 )
*
*              Set relevant part of first half of WORK to zero,
*              holds dot products
*
               DO 170 i = k, n
                  work( i ) = 0
  170          continue
*
               DO 200 j = k, k + jb - 1
*
*              Find pivot, test for exit, else swap rows and columns
*              Update dot products, compute possible pivots which are
*              stored in the second half of WORK
*
                  DO 180 i = j, n
*
                     IF( j.GT.k ) THEN
                        work( i ) = work( i ) +
     $                              REAL( CONJG( A( I, J-1 ) )*
     $                                    a( i, j-1 ) )
                     END IF
                     work( n+i ) = REAL( A( I, I ) ) - work( i )
*
  180             continue
*
                  IF( j.GT.1 ) THEN
                     itemp = maxloc( work( (n+j):(2*n) ), 1 )
                     pvt = itemp + j - 1
                     ajj = work( n+pvt )
                     IF( ajj.LE.sstop.OR.sisnan( ajj ) ) THEN
                        a( j, j ) = ajj
                        go to 220
                     END IF
                  END IF
*
                  IF( j.NE.pvt ) THEN
*
*                    Pivot OK, so can now swap pivot rows and columns
*
                     a( pvt, pvt ) = a( j, j )
                     CALL cswap( j-1, a( j, 1 ), lda, a( pvt, 1 ), lda )
                     IF( pvt.LT.n )
     $                  CALL cswap( n-pvt, a( pvt+1, j ), 1,
     $                              a( pvt+1, pvt ), 1 )
                     DO 190 i = j + 1, pvt - 1
                        ctemp = conjg( a( i, j ) )
                        a( i, j ) = conjg( a( pvt, i ) )
                        a( pvt, i ) = ctemp
  190                continue
                     a( pvt, j ) = conjg( a( pvt, j ) )
*
*                    Swap dot products and PIV
*
                     stemp = work( j )
                     work( j ) = work( pvt )
                     work( pvt ) = stemp
                     itemp = piv( pvt )
                     piv( pvt ) = piv( j )
                     piv( j ) = itemp
                  END IF
*
                  ajj = sqrt( ajj )
                  a( j, j ) = ajj
*
*                 Compute elements J+1:N of column J.
*
                  IF( j.LT.n ) THEN
                     CALL clacgv( j-1, a( j, 1 ), lda )
                     CALL cgemv( 'No Trans', n-j, j-k, -cone,
     $                           a( j+1, k ), lda, a( j, k ), lda, cone,
     $                           a( j+1, j ), 1 )
                     CALL clacgv( j-1, a( j, 1 ), lda )
                     CALL csscal( n-j, one / ajj, a( j+1, j ), 1 )
                  END IF
*
  200          continue
*
*              Update trailing matrix, J already incremented
*
               IF( k+jb.LE.n ) THEN
                  CALL cherk( 'Lower', 'No Trans', n-j+1, jb, -one,
     $                        a( j, k ), lda, one, a( j, j ), lda )
               END IF
*
  210       continue
*
         END IF
      END IF
*
*     Ran to completion, A has full rank
*
      rank = n
*
      go to 230
  220 continue
*
*     Rank is the number of steps completed.  Set INFO = 1 to signal
*     that the factorization cannot be used to solve a system.
*
      rank = j - 1
      info = 1
*
  230 continue
      return
*
*     End of CPSTRF
*
      END