cgelsx.f

Go to the documentation of this file.

*> \brief <b> CGELSX solves overdetermined or underdetermined systems for GE matrices</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at 
*            http://www.netlib.org/lapack/explore-html/ 
*
*> \htmlonly
*> Download CGELSX + dependencies 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgelsx.f"> 
*> [TGZ]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgelsx.f"> 
*> [ZIP]</a> 
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgelsx.f"> 
*> [TXT]</a>
*> \endhtmlonly 
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGELSX( M, N, NRHS, A, LDA, B, LDB, JPVT, RCOND, RANK,
*                          WORK, RWORK, INFO )
* 
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDB, M, N, NRHS, RANK
*       REAL               RCOND
*       ..
*       .. Array Arguments ..
*       INTEGER            JPVT( * )
*       REAL               RWORK( * )
*       COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*  
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> This routine is deprecated and has been replaced by routine CGELSY.
*>
*> CGELSX computes the minimum-norm solution to a complex linear least
*> squares problem:
*>     minimize || A * X - B ||
*> using a complete orthogonal factorization of A.  A is an M-by-N
*> matrix which may be rank-deficient.
*>
*> Several right hand side vectors b and solution vectors x can be
*> handled in a single call; they are stored as the columns of the
*> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
*> matrix X.
*>
*> The routine first computes a QR factorization with column pivoting:
*>     A * P = Q * [ R11 R12 ]
*>                 [  0  R22 ]
*> with R11 defined as the largest leading submatrix whose estimated
*> condition number is less than 1/RCOND.  The order of R11, RANK,
*> is the effective rank of A.
*>
*> Then, R22 is considered to be negligible, and R12 is annihilated
*> by unitary transformations from the right, arriving at the
*> complete orthogonal factorization:
*>    A * P = Q * [ T11 0 ] * Z
*>                [  0  0 ]
*> The minimum-norm solution is then
*>    X = P * Z**H [ inv(T11)*Q1**H*B ]
*>                 [        0         ]
*> where Q1 consists of the first RANK columns of Q.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of
*>          columns of matrices B and X. NRHS >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit, A has been overwritten by details of its
*>          complete orthogonal factorization.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the M-by-NRHS right hand side matrix B.
*>          On exit, the N-by-NRHS solution matrix X.
*>          If m >= n and RANK = n, the residual sum-of-squares for
*>          the solution in the i-th column is given by the sum of
*>          squares of elements N+1:M in that column.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= max(1,M,N).
*> \endverbatim
*>
*> \param[in,out] JPVT
*> \verbatim
*>          JPVT is INTEGER array, dimension (N)
*>          On entry, if JPVT(i) .ne. 0, the i-th column of A is an
*>          initial column, otherwise it is a free column.  Before
*>          the QR factorization of A, all initial columns are
*>          permuted to the leading positions; only the remaining
*>          free columns are moved as a result of column pivoting
*>          during the factorization.
*>          On exit, if JPVT(i) = k, then the i-th column of A*P
*>          was the k-th column of A.
*> \endverbatim
*>
*> \param[in] RCOND
*> \verbatim
*>          RCOND is REAL
*>          RCOND is used to determine the effective rank of A, which
*>          is defined as the order of the largest leading triangular
*>          submatrix R11 in the QR factorization with pivoting of A,
*>          whose estimated condition number < 1/RCOND.
*> \endverbatim
*>
*> \param[out] RANK
*> \verbatim
*>          RANK is INTEGER
*>          The effective rank of A, i.e., the order of the submatrix
*>          R11.  This is the same as the order of the submatrix T11
*>          in the complete orthogonal factorization of A.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension
*>                      (min(M,N) + max( N, 2*min(M,N)+NRHS )),
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee 
*> \author Univ. of California Berkeley 
*> \author Univ. of Colorado Denver 
*> \author NAG Ltd. 
*
*> \date November 2011
*
*> \ingroup complexGEsolve
*
*  =====================================================================
      SUBROUTINE cgelsx( M, N, NRHS, A, LDA, B, LDB, JPVT, RCOND, RANK,
     $                   work, rwork, info )
*
*  -- LAPACK driver routine (version 3.4.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2011
*
*     .. Scalar Arguments ..
      INTEGER            info, lda, ldb, m, n, nrhs, rank
      REAL               rcond
*     ..
*     .. Array Arguments ..
      INTEGER            jpvt( * )
      REAL               rwork( * )
      COMPLEX            a( lda, * ), b( ldb, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            imax, imin
      parameter( imax = 1, imin = 2 )
      REAL               zero, one, done, ntdone
      parameter( zero = 0.0e+0, one = 1.0e+0, done = zero,
     $                   ntdone = one )
      COMPLEX            czero, cone
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            i, iascl, ibscl, ismax, ismin, j, k, mn
      REAL               anrm, bignum, bnrm, smax, smaxpr, smin, sminpr,
     $                   smlnum
      COMPLEX            c1, c2, s1, s2, t1, t2
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgeqpf, claic1, clascl, claset, clatzm, ctrsm,
     $                   ctzrqf, cunm2r, slabad, xerbla
*     ..
*     .. External Functions ..
      REAL               clange, slamch
      EXTERNAL           clange, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, conjg, max, min
*     ..
*     .. Executable Statements ..
*
      mn = min( m, n )
      ismin = mn + 1
      ismax = 2*mn + 1
*
*     Test the input arguments.
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, m, n ) ) THEN
         info = -7
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELSX', -info )
         return
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, nrhs ).EQ.0 ) THEN
         rank = 0
         return
      END IF
*
*     Get machine parameters
*
      smlnum = slamch( 'S' ) / slamch( 'P' )
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Scale A, B if max elements outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         rank = 0
         go to 100
      END IF
*
      bnrm = clange( 'M', m, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, bnrm, smlnum, m, nrhs, b, ldb, info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, bnrm, bignum, m, nrhs, b, ldb, info )
         ibscl = 2
      END IF
*
*     Compute QR factorization with column pivoting of A:
*        A * P = Q * R
*
      CALL cgeqpf( m, n, a, lda, jpvt, work( 1 ), work( mn+1 ), rwork,
     $             info )
*
*     complex workspace MN+N. Real workspace 2*N. Details of Householder
*     rotations stored in WORK(1:MN).
*
*     Determine RANK using incremental condition estimation
*
      work( ismin ) = cone
      work( ismax ) = cone
      smax = abs( a( 1, 1 ) )
      smin = smax
      IF( abs( a( 1, 1 ) ).EQ.zero ) THEN
         rank = 0
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         go to 100
      ELSE
         rank = 1
      END IF
*
   10 continue
      IF( rank.LT.mn ) THEN
         i = rank + 1
         CALL claic1( imin, rank, work( ismin ), smin, a( 1, i ),
     $                a( i, i ), sminpr, s1, c1 )
         CALL claic1( imax, rank, work( ismax ), smax, a( 1, i ),
     $                a( i, i ), smaxpr, s2, c2 )
*
         IF( smaxpr*rcond.LE.sminpr ) THEN
            DO 20 i = 1, rank
               work( ismin+i-1 ) = s1*work( ismin+i-1 )
               work( ismax+i-1 ) = s2*work( ismax+i-1 )
   20       continue
            work( ismin+rank ) = c1
            work( ismax+rank ) = c2
            smin = sminpr
            smax = smaxpr
            rank = rank + 1
            go to 10
         END IF
      END IF
*
*     Logically partition R = [ R11 R12 ]
*                             [  0  R22 ]
*     where R11 = R(1:RANK,1:RANK)
*
*     [R11,R12] = [ T11, 0 ] * Y
*
      IF( rank.LT.n )
     $   CALL ctzrqf( rank, n, a, lda, work( mn+1 ), info )
*
*     Details of Householder rotations stored in WORK(MN+1:2*MN)
*
*     B(1:M,1:NRHS) := Q**H * B(1:M,1:NRHS)
*
      CALL cunm2r( 'Left', 'Conjugate transpose', m, nrhs, mn, a, lda,
     $             work( 1 ), b, ldb, work( 2*mn+1 ), info )
*
*     workspace NRHS
*
*      B(1:RANK,1:NRHS) := inv(T11) * B(1:RANK,1:NRHS)
*
      CALL ctrsm( 'Left', 'Upper', 'No transpose', 'Non-unit', rank,
     $            nrhs, cone, a, lda, b, ldb )
*
      DO 40 i = rank + 1, n
         DO 30 j = 1, nrhs
            b( i, j ) = czero
   30    continue
   40 continue
*
*     B(1:N,1:NRHS) := Y**H * B(1:N,1:NRHS)
*
      IF( rank.LT.n ) THEN
         DO 50 i = 1, rank
            CALL clatzm( 'Left', n-rank+1, nrhs, a( i, rank+1 ), lda,
     $                   conjg( work( mn+i ) ), b( i, 1 ),
     $                   b( rank+1, 1 ), ldb, work( 2*mn+1 ) )
   50    continue
      END IF
*
*     workspace NRHS
*
*     B(1:N,1:NRHS) := P * B(1:N,1:NRHS)
*
      DO 90 j = 1, nrhs
         DO 60 i = 1, n
            work( 2*mn+i ) = ntdone
   60    continue
         DO 80 i = 1, n
            IF( work( 2*mn+i ).EQ.ntdone ) THEN
               IF( jpvt( i ).NE.i ) THEN
                  k = i
                  t1 = b( k, j )
                  t2 = b( jpvt( k ), j )
   70             continue
                  b( jpvt( k ), j ) = t1
                  work( 2*mn+k ) = done
                  t1 = t2
                  k = jpvt( k )
                  t2 = b( jpvt( k ), j )
                  IF( jpvt( k ).NE.i )
     $               go to 70
                  b( i, j ) = t1
                  work( 2*mn+k ) = done
               END IF
            END IF
   80    continue
   90 continue
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, anrm, smlnum, n, nrhs, b, ldb, info )
         CALL clascl( 'U', 0, 0, smlnum, anrm, rank, rank, a, lda,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, anrm, bignum, n, nrhs, b, ldb, info )
         CALL clascl( 'U', 0, 0, bignum, anrm, rank, rank, a, lda,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, smlnum, bnrm, n, nrhs, b, ldb, info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, bignum, bnrm, n, nrhs, b, ldb, info )
      END IF
*
  100 continue
*
      return
*
*     End of CGELSX
*
      END