LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
zlanhb.f
Go to the documentation of this file.
1*> \brief \b ZLANHB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a Hermitian band matrix.
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download ZLANHB + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zlanhb.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zlanhb.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zlanhb.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* DOUBLE PRECISION FUNCTION ZLANHB( NORM, UPLO, N, K, AB, LDAB,
22* WORK )
23*
24* .. Scalar Arguments ..
25* CHARACTER NORM, UPLO
26* INTEGER K, LDAB, N
27* ..
28* .. Array Arguments ..
29* DOUBLE PRECISION WORK( * )
30* COMPLEX*16 AB( LDAB, * )
31* ..
32*
33*
34*> \par Purpose:
35* =============
36*>
37*> \verbatim
38*>
39*> ZLANHB returns the value of the one norm, or the Frobenius norm, or
40*> the infinity norm, or the element of largest absolute value of an
41*> n by n hermitian band matrix A, with k super-diagonals.
42*> \endverbatim
43*>
44*> \return ZLANHB
45*> \verbatim
46*>
47*> ZLANHB = ( max(abs(A(i,j))), NORM = 'M' or 'm'
48*> (
49*> ( norm1(A), NORM = '1', 'O' or 'o'
50*> (
51*> ( normI(A), NORM = 'I' or 'i'
52*> (
53*> ( normF(A), NORM = 'F', 'f', 'E' or 'e'
54*>
55*> where norm1 denotes the one norm of a matrix (maximum column sum),
56*> normI denotes the infinity norm of a matrix (maximum row sum) and
57*> normF denotes the Frobenius norm of a matrix (square root of sum of
58*> squares). Note that max(abs(A(i,j))) is not a consistent matrix norm.
59*> \endverbatim
60*
61* Arguments:
62* ==========
63*
64*> \param[in] NORM
65*> \verbatim
66*> NORM is CHARACTER*1
67*> Specifies the value to be returned in ZLANHB as described
68*> above.
69*> \endverbatim
70*>
71*> \param[in] UPLO
72*> \verbatim
73*> UPLO is CHARACTER*1
74*> Specifies whether the upper or lower triangular part of the
75*> band matrix A is supplied.
76*> = 'U': Upper triangular
77*> = 'L': Lower triangular
78*> \endverbatim
79*>
80*> \param[in] N
81*> \verbatim
82*> N is INTEGER
83*> The order of the matrix A. N >= 0. When N = 0, ZLANHB is
84*> set to zero.
85*> \endverbatim
86*>
87*> \param[in] K
88*> \verbatim
89*> K is INTEGER
90*> The number of super-diagonals or sub-diagonals of the
91*> band matrix A. K >= 0.
92*> \endverbatim
93*>
94*> \param[in] AB
95*> \verbatim
96*> AB is COMPLEX*16 array, dimension (LDAB,N)
97*> The upper or lower triangle of the hermitian band matrix A,
98*> stored in the first K+1 rows of AB. The j-th column of A is
99*> stored in the j-th column of the array AB as follows:
100*> if UPLO = 'U', AB(k+1+i-j,j) = A(i,j) for max(1,j-k)<=i<=j;
101*> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+k).
102*> Note that the imaginary parts of the diagonal elements need
103*> not be set and are assumed to be zero.
104*> \endverbatim
105*>
106*> \param[in] LDAB
107*> \verbatim
108*> LDAB is INTEGER
109*> The leading dimension of the array AB. LDAB >= K+1.
110*> \endverbatim
111*>
112*> \param[out] WORK
113*> \verbatim
114*> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
115*> where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
116*> WORK is not referenced.
117*> \endverbatim
118*
119* Authors:
120* ========
121*
122*> \author Univ. of Tennessee
123*> \author Univ. of California Berkeley
124*> \author Univ. of Colorado Denver
125*> \author NAG Ltd.
126*
127*> \ingroup complex16OTHERauxiliary
128*
129* =====================================================================
130 DOUBLE PRECISION FUNCTION zlanhb( NORM, UPLO, N, K, AB, LDAB,
131 $ WORK )
132*
133* -- LAPACK auxiliary routine --
134* -- LAPACK is a software package provided by Univ. of Tennessee, --
135* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
136*
137* .. Scalar Arguments ..
138 CHARACTER norm, uplo
139 INTEGER k, ldab, n
140* ..
141* .. Array Arguments ..
142 DOUBLE PRECISION work( * )
143 COMPLEX*16 ab( ldab, * )
144* ..
145*
146* =====================================================================
147*
148* .. Parameters ..
149 DOUBLE PRECISION one, zero
150 parameter( one = 1.0d+0, zero = 0.0d+0 )
151* ..
152* .. Local Scalars ..
153 INTEGER i, j, l
154 DOUBLE PRECISION absa, scale, sum, value
155* ..
156* .. External Functions ..
157 LOGICAL lsame, disnan
158 EXTERNAL lsame, disnan
159* ..
160* .. External Subroutines ..
161 EXTERNAL zlassq
162* ..
163* .. Intrinsic Functions ..
164 INTRINSIC abs, dble, max, min, sqrt
165* ..
166* .. Executable Statements ..
167*
168 IF( n.EQ.0 ) THEN
169 VALUE = zero
170 ELSE IF( lsame( norm, 'M' ) ) THEN
171*
172* Find max(abs(A(i,j))).
173*
174 VALUE = zero
175 IF( lsame( uplo, 'U' ) ) THEN
176 DO 20 j = 1, n
177 DO 10 i = max( k+2-j, 1 ), k
178 sum = abs( ab( i, j ) )
179 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
180 10 CONTINUE
181 sum = abs( dble( ab( k+1, j ) ) )
182 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
183 20 CONTINUE
184 ELSE
185 DO 40 j = 1, n
186 sum = abs( dble( ab( 1, j ) ) )
187 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
188 DO 30 i = 2, min( n+1-j, k+1 )
189 sum = abs( ab( i, j ) )
190 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
191 30 CONTINUE
192 40 CONTINUE
193 END IF
194 ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
195 $ ( norm.EQ.'1' ) ) THEN
196*
197* Find normI(A) ( = norm1(A), since A is hermitian).
198*
199 VALUE = zero
200 IF( lsame( uplo, 'U' ) ) THEN
201 DO 60 j = 1, n
202 sum = zero
203 l = k + 1 - j
204 DO 50 i = max( 1, j-k ), j - 1
205 absa = abs( ab( l+i, j ) )
206 sum = sum + absa
207 work( i ) = work( i ) + absa
208 50 CONTINUE
209 work( j ) = sum + abs( dble( ab( k+1, j ) ) )
210 60 CONTINUE
211 DO 70 i = 1, n
212 sum = work( i )
213 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
214 70 CONTINUE
215 ELSE
216 DO 80 i = 1, n
217 work( i ) = zero
218 80 CONTINUE
219 DO 100 j = 1, n
220 sum = work( j ) + abs( dble( ab( 1, j ) ) )
221 l = 1 - j
222 DO 90 i = j + 1, min( n, j+k )
223 absa = abs( ab( l+i, j ) )
224 sum = sum + absa
225 work( i ) = work( i ) + absa
226 90 CONTINUE
227 IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
228 100 CONTINUE
229 END IF
230 ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
231*
232* Find normF(A).
233*
234 scale = zero
235 sum = one
236 IF( k.GT.0 ) THEN
237 IF( lsame( uplo, 'U' ) ) THEN
238 DO 110 j = 2, n
239 CALL zlassq( min( j-1, k ), ab( max( k+2-j, 1 ), j ),
240 $ 1, scale, sum )
241 110 CONTINUE
242 l = k + 1
243 ELSE
244 DO 120 j = 1, n - 1
245 CALL zlassq( min( n-j, k ), ab( 2, j ), 1, scale,
246 $ sum )
247 120 CONTINUE
248 l = 1
249 END IF
250 sum = 2*sum
251 ELSE
252 l = 1
253 END IF
254 DO 130 j = 1, n
255 IF( dble( ab( l, j ) ).NE.zero ) THEN
256 absa = abs( dble( ab( l, j ) ) )
257 IF( scale.LT.absa ) THEN
258 sum = one + sum*( scale / absa )**2
259 scale = absa
260 ELSE
261 sum = sum + ( absa / scale )**2
262 END IF
263 END IF
264 130 CONTINUE
265 VALUE = scale*sqrt( sum )
266 END IF
267*
268 zlanhb = VALUE
269 RETURN
270*
271* End of ZLANHB
272*
273 END
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:59
subroutine zlassq(n, x, incx, scl, sumsq)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f90:137
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:53
double precision function zlanhb(NORM, UPLO, N, K, AB, LDAB, WORK)
ZLANHB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlanhb.f:132