cchkgt()

subroutine cchkgt	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nns,
		integer, dimension( * )	nsval,
		real	thresh,
		logical	tsterr,
		complex, dimension( * )	a,
		complex, dimension( * )	af,
		complex, dimension( * )	b,
		complex, dimension( * )	x,
		complex, dimension( * )	xact,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout )

CCHKGT

Purpose:

!>
!> CCHKGT tests CGTTRF, -TRS, -RFS, and -CON
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix dimension N. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is REAL !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[out]	A	!> A is COMPLEX array, dimension (NMAX*4) !>
[out]	AF	!> AF is COMPLEX array, dimension (NMAX*4) !>
[out]	B	!> B is COMPLEX array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is REAL array, dimension !> (max(NMAX)+2*NSMAX) !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (NMAX) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 145 of file cchkgt.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
      REAL               RWORK( * )
      COMPLEX            A( * ), AF( * ), B( * ), WORK( * ), X( * ),
     $                   XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter( ntypes = 12 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, NORM, TRANS, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IMAT, IN, INFO, IRHS, ITRAN, IX, IZERO, J,
     $                   K, KL, KOFF, KU, LDA, M, MODE, N, NERRS, NFAIL,
     $                   NIMAT, NRHS, NRUN
      REAL               AINVNM, ANORM, COND, RCOND, RCONDC, RCONDI,
     $                   RCONDO
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( 3 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
      COMPLEX            Z( 3 )
*     ..
*     .. External Functions ..
      REAL               CLANGT, SCASUM, SGET06
      EXTERNAL           clangt, scasum, sget06
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, ccopy, cerrge, cget04,
     $                   cgtcon, cgtrfs, cgtt01, cgtt02, cgtt05, cgttrf,
     $                   cgttrs, clacpy, clagtm, clarnv, clatb4, clatms,
     $                   csscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 / , transs / 'N', 'T',
     $                   'C' /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'GT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrge( path, nout )
      infot = 0
*
      DO 110 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         m = max( n-1, 0 )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 100 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 100
*
*           Set up parameters with CLATB4.
*
            CALL clatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                   COND, DIST )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Types 1-6:  generate matrices of known condition number.
*
               koff = max( 2-ku, 3-max( 1, n ) )
               srnamt = 'CLATMS'
               CALL clatms( n, n, dist, iseed, TYPE, RWORK, MODE, COND,
     $                      ANORM, KL, KU, 'Z', AF( KOFF ), 3, WORK,
     $                      INFO )
*
*              Check the error code from CLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'CLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
               izero = 0
*
               IF( n.GT.1 ) THEN
                  CALL ccopy( n-1, af( 4 ), 3, a, 1 )
                  CALL ccopy( n-1, af( 3 ), 3, a( n+m+1 ), 1 )
               END IF
               CALL ccopy( n, af( 2 ), 3, a( m+1 ), 1 )
            ELSE
*
*              Types 7-12:  generate tridiagonal matrices with
*              unknown condition numbers.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Generate a matrix with elements whose real and
*                 imaginary parts are from [-1,1].
*
                  CALL clarnv( 2, iseed, n+2*m, a )
                  IF( anorm.NE.one )
     $               CALL csscal( n+2*m, anorm, a, 1 )
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     a( n ) = z( 2 )
                     IF( n.GT.1 )
     $                  a( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     a( 3*n-2 ) = z( 1 )
                     a( 2*n-1 ) = z( 2 )
                  ELSE
                     a( 2*n-2+izero ) = z( 1 )
                     a( n-1+izero ) = z( 2 )
                     a( izero ) = z( 3 )
                  END IF
               END IF
*
*              If IMAT > 7, set one column of the matrix to 0.
*
               IF( .NOT.zerot ) THEN
                  izero = 0
               ELSE IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = a( n )
                  a( n ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = a( 1 )
                     a( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  z( 1 ) = a( 3*n-2 )
                  z( 2 ) = a( 2*n-1 )
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               ELSE
                  izero = ( n+1 ) / 2
                  DO 20 i = izero, n - 1
                     a( 2*n-2+i ) = zero
                     a( n-1+i ) = zero
                     a( i ) = zero
   20             CONTINUE
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               END IF
            END IF
*
*+    TEST 1
*           Factor A as L*U and compute the ratio
*              norm(L*U - A) / (n * norm(A) * EPS )
*
            CALL ccopy( n+2*m, a, 1, af, 1 )
            srnamt = 'CGTTRF'
            CALL cgttrf( n, af, af( m+1 ), af( n+m+1 ), af( n+2*m+1 ),
     $                   iwork, info )
*
*           Check error code from CGTTRF.
*
            IF( info.NE.izero )
     $         CALL alaerh( path, 'CGTTRF', info, izero, ' ', n, n, 1,
     $                      1, -1, imat, nfail, nerrs, nout )
            trfcon = info.NE.0
*
            CALL cgtt01( n, a, a( m+1 ), a( n+m+1 ), af, af( m+1 ),
     $                   af( n+m+1 ), af( n+2*m+1 ), iwork, work, lda,
     $                   rwork, result( 1 ) )
*
*           Print the test ratio if it is .GE. THRESH.
*
            IF( result( 1 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 1, result( 1 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
*
            DO 50 itran = 1, 2
               trans = transs( itran )
               IF( itran.EQ.1 ) THEN
                  norm = 'O'
               ELSE
                  norm = 'I'
               END IF
               anorm = clangt( norm, n, a, a( m+1 ), a( n+m+1 ) )
*
               IF( .NOT.trfcon ) THEN
*
*                 Use CGTTRS to solve for one column at a time of
*                 inv(A), computing the maximum column sum as we go.
*
                  ainvnm = zero
                  DO 40 i = 1, n
                     DO 30 j = 1, n
                        x( j ) = zero
   30                CONTINUE
                     x( i ) = one
                     CALL cgttrs( trans, n, 1, af, af( m+1 ),
     $                            af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                            lda, info )
                     ainvnm = max( ainvnm, scasum( n, x, 1 ) )
   40             CONTINUE
*
*                 Compute RCONDC = 1 / (norm(A) * norm(inv(A))
*
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondc = one
                  ELSE
                     rcondc = ( one / anorm ) / ainvnm
                  END IF
                  IF( itran.EQ.1 ) THEN
                     rcondo = rcondc
                  ELSE
                     rcondi = rcondc
                  END IF
               ELSE
                  rcondc = zero
               END IF
*
*+    TEST 7
*              Estimate the reciprocal of the condition number of the
*              matrix.
*
               srnamt = 'CGTCON'
               CALL cgtcon( norm, n, af, af( m+1 ), af( n+m+1 ),
     $                      af( n+2*m+1 ), iwork, anorm, rcond, work,
     $                      info )
*
*              Check error code from CGTCON.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'CGTCON', info, 0, norm, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
               result( 7 ) = sget06( rcond, rcondc )
*
*              Print the test ratio if it is .GE. THRESH.
*
               IF( result( 7 ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  WRITE( nout, fmt = 9997 )norm, n, imat, 7,
     $               result( 7 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
   50       CONTINUE
*
*           Skip the remaining tests if the matrix is singular.
*
            IF( trfcon )
     $         GO TO 100
*
            DO 90 irhs = 1, nns
               nrhs = nsval( irhs )
*
*              Generate NRHS random solution vectors.
*
               ix = 1
               DO 60 j = 1, nrhs
                  CALL clarnv( 2, iseed, n, xact( ix ) )
                  ix = ix + lda
   60          CONTINUE
*
               DO 80 itran = 1, 3
                  trans = transs( itran )
                  IF( itran.EQ.1 ) THEN
                     rcondc = rcondo
                  ELSE
                     rcondc = rcondi
                  END IF
*
*                 Set the right hand side.
*
                  CALL clagtm( trans, n, nrhs, one, a,
     $                         a( m+1 ), a( n+m+1 ), xact, lda,
     $                         zero, b, lda )
*
*+    TEST 2
*              Solve op(A) * X = B and compute the residual.
*
                  CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
                  srnamt = 'CGTTRS'
                  CALL cgttrs( trans, n, nrhs, af, af( m+1 ),
     $                         af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                         lda, info )
*
*              Check error code from CGTTRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CGTTRS', info, 0, trans, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL clacpy( 'Full', n, nrhs, b, lda, work, lda )
                  CALL cgtt02( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         x, lda, work, lda, result( 2 ) )
*
*+    TEST 3
*              Check solution from generated exact solution.
*
                  CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 3 ) )
*
*+    TESTS 4, 5, and 6
*              Use iterative refinement to improve the solution.
*
                  srnamt = 'CGTRFS'
                  CALL cgtrfs( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         af, af( m+1 ), af( n+m+1 ),
     $                         af( n+2*m+1 ), iwork, b, lda, x, lda,
     $                         rwork, rwork( nrhs+1 ), work,
     $                         rwork( 2*nrhs+1 ), info )
*
*              Check error code from CGTRFS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CGTRFS', info, 0, trans, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 4 ) )
                  CALL cgtt05( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         b, lda, x, lda, xact, lda, rwork,
     $                         rwork( nrhs+1 ), result( 5 ) )
*
*              Print information about the tests that did not pass the
*              threshold.
*
                  DO 70 k = 2, 6
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 )trans, n, nrhs, imat,
     $                     k, result( k )
                        nfail = nfail + 1
                     END IF
   70             CONTINUE
                  nrun = nrun + 5
   80          CONTINUE
   90       CONTINUE
  100    CONTINUE
  110 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 12x, 'N =', i5, ',', 10x, ' type ', i2, ', test(', i2,
     $      ') = ', g12.5 )
 9998 FORMAT( ' TRANS=''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') = ', g12.5 )
 9997 FORMAT( ' NORM =''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') = ', g12.5 )
      RETURN
*
*     End of CCHKGT
*

Here is the call graph for this function:

Here is the caller graph for this function: