LAPACK 3.12.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
scasum.f
Go to the documentation of this file.
1*> \brief \b SCASUM
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* REAL FUNCTION SCASUM(N,CX,INCX)
12*
13* .. Scalar Arguments ..
14* INTEGER INCX,N
15* ..
16* .. Array Arguments ..
17* COMPLEX CX(*)
18* ..
19*
20*
21*> \par Purpose:
22* =============
23*>
24*> \verbatim
25*>
26*> SCASUM takes the sum of the (|Re(.)| + |Im(.)|)'s of a complex vector and
27*> returns a single precision result.
28*> \endverbatim
29*
30* Arguments:
31* ==========
32*
33*> \param[in] N
34*> \verbatim
35*> N is INTEGER
36*> number of elements in input vector(s)
37*> \endverbatim
38*>
39*> \param[in,out] CX
40*> \verbatim
41*> CX is COMPLEX array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
42*> \endverbatim
43*>
44*> \param[in] INCX
45*> \verbatim
46*> INCX is INTEGER
47*> storage spacing between elements of SX
48*> \endverbatim
49*
50* Authors:
51* ========
52*
53*> \author Univ. of Tennessee
54*> \author Univ. of California Berkeley
55*> \author Univ. of Colorado Denver
56*> \author NAG Ltd.
57*
58*> \ingroup asum
59*
60*> \par Further Details:
61* =====================
62*>
63*> \verbatim
64*>
65*> jack dongarra, linpack, 3/11/78.
66*> modified 3/93 to return if incx .le. 0.
67*> modified 12/3/93, array(1) declarations changed to array(*)
68*> \endverbatim
69*>
70* =====================================================================
71 REAL function scasum(n,cx,incx)
72*
73* -- Reference BLAS level1 routine --
74* -- Reference BLAS is a software package provided by Univ. of Tennessee, --
75* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
76*
77* .. Scalar Arguments ..
78 INTEGER incx,n
79* ..
80* .. Array Arguments ..
81 COMPLEX cx(*)
82* ..
83*
84* =====================================================================
85*
86* .. Local Scalars ..
87 REAL stemp
88 INTEGER i,nincx
89* ..
90* .. Intrinsic Functions ..
91 INTRINSIC abs,aimag,real
92* ..
93 scasum = 0.0e0
94 stemp = 0.0e0
95 IF (n.LE.0 .OR. incx.LE.0) RETURN
96 IF (incx.EQ.1) THEN
97*
98* code for increment equal to 1
99*
100 DO i = 1,n
101 stemp = stemp + abs(real(cx(i))) + abs(aimag(cx(i)))
102 END DO
103 ELSE
104*
105* code for increment not equal to 1
106*
107 nincx = n*incx
108 DO i = 1,nincx,incx
109 stemp = stemp + abs(real(cx(i))) + abs(aimag(cx(i)))
110 END DO
111 END IF
112 scasum = stemp
113 RETURN
114*
115* End of SCASUM
116*
117 END
scasum
real function scasum(n, cx, incx)
SCASUM
Definition scasum.f:72