clatb4.f

Go to the documentation of this file.

*> \brief \b CLATB4
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CLATB4( PATH, IMAT, M, N, TYPE, KL, KU, ANORM, MODE,
*                          CNDNUM, DIST )
*
*       .. Scalar Arguments ..
*       CHARACTER          DIST, TYPE
*       CHARACTER*3        PATH
*       INTEGER            IMAT, KL, KU, M, MODE, N
*       REAL               ANORM, CNDNUM
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLATB4 sets parameters for the matrix generator based on the type of
*> matrix to be generated.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] PATH
*> \verbatim
*>          PATH is CHARACTER*3
*>          The LAPACK path name.
*> \endverbatim
*>
*> \param[in] IMAT
*> \verbatim
*>          IMAT is INTEGER
*>          An integer key describing which matrix to generate for this
*>          path.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows in the matrix to be generated.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns in the matrix to be generated.
*> \endverbatim
*>
*> \param[out] TYPE
*> \verbatim
*>          TYPE is CHARACTER*1
*>          The type of the matrix to be generated:
*>          = 'S':  symmetric matrix
*>          = 'H':  Hermitian matrix
*>          = 'P':  Hermitian positive (semi)definite matrix
*>          = 'N':  nonsymmetric matrix
*> \endverbatim
*>
*> \param[out] KL
*> \verbatim
*>          KL is INTEGER
*>          The lower band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] KU
*> \verbatim
*>          KU is INTEGER
*>          The upper band width of the matrix to be generated.
*> \endverbatim
*>
*> \param[out] ANORM
*> \verbatim
*>          ANORM is REAL
*>          The desired norm of the matrix to be generated.  The diagonal
*>          matrix of singular values or eigenvalues is scaled by this
*>          value.
*> \endverbatim
*>
*> \param[out] MODE
*> \verbatim
*>          MODE is INTEGER
*>          A key indicating how to choose the vector of eigenvalues.
*> \endverbatim
*>
*> \param[out] CNDNUM
*> \verbatim
*>          CNDNUM is REAL
*>          The desired condition number.
*> \endverbatim
*>
*> \param[out] DIST
*> \verbatim
*>          DIST is CHARACTER*1
*>          The type of distribution to be used by the random number
*>          generator.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE clatb4( PATH, IMAT, M, N, TYPE, KL, KU, ANORM, MODE,
     $                   CNDNUM, DIST )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIST, TYPE
      CHARACTER*3        PATH
      INTEGER            IMAT, KL, KU, M, MODE, N
      REAL               ANORM, CNDNUM
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               SHRINK, TENTH
      parameter( shrink = 0.25e0, tenth = 0.1e+0 )
      REAL               ONE
      parameter( one = 1.0e+0 )
      REAL               TWO
      parameter( two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            FIRST
      CHARACTER*2        C2
      INTEGER            MAT
      REAL               BADC1, BADC2, EPS, LARGE, SMALL
*     ..
*     .. External Functions ..
      LOGICAL            LSAMEN
      REAL               SLAMCH
      EXTERNAL           lsamen, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     ..
*     .. External Subroutines ..
      EXTERNAL           slabad
*     ..
*     .. Save statement ..
      SAVE               eps, small, large, badc1, badc2, first
*     ..
*     .. Data statements ..
      DATA               first / .true. /
*     ..
*     .. Executable Statements ..
*
*     Set some constants for use in the subroutine.
*
      IF( first ) THEN
         first = .false.
         eps = slamch( 'Precision' )
         badc2 = tenth / eps
         badc1 = sqrt( badc2 )
         small = slamch( 'Safe minimum' )
         large = one / small
*
*        If it looks like we're on a Cray, take the square root of
*        SMALL and LARGE to avoid overflow and underflow problems.
*
         CALL slabad( small, large )
         small = shrink*( small / eps )
         large = one / small
      END IF
*
      c2 = path( 2: 3 )
*
*     Set some parameters we don't plan to change.
*
      dist = 'S'
      mode = 3
*
*     xQR, xLQ, xQL, xRQ:  Set parameters to generate a general
*                          M x N matrix.
*
      IF( lsamen( 2, c2, 'QR' ) .OR. lsamen( 2, c2, 'LQ' ) .OR.
     $    lsamen( 2, c2, 'QL' ) .OR. lsamen( 2, c2, 'RQ' ) ) THEN
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the lower and upper bandwidths.
*
         IF( imat.EQ.1 ) THEN
            kl = 0
            ku = 0
         ELSE IF( imat.EQ.2 ) THEN
            kl = 0
            ku = max( n-1, 0 )
         ELSE IF( imat.EQ.3 ) THEN
            kl = max( m-1, 0 )
            ku = 0
         ELSE
            kl = max( m-1, 0 )
            ku = max( n-1, 0 )
         END IF
*
*        Set the condition number and norm.
*
         IF( imat.EQ.5 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.6 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.7 ) THEN
            anorm = small
         ELSE IF( imat.EQ.8 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'GE' ) ) THEN
*
*        xGE:  Set parameters to generate a general M x N matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the lower and upper bandwidths.
*
         IF( imat.EQ.1 ) THEN
            kl = 0
            ku = 0
         ELSE IF( imat.EQ.2 ) THEN
            kl = 0
            ku = max( n-1, 0 )
         ELSE IF( imat.EQ.3 ) THEN
            kl = max( m-1, 0 )
            ku = 0
         ELSE
            kl = max( m-1, 0 )
            ku = max( n-1, 0 )
         END IF
*
*        Set the condition number and norm.
*
         IF( imat.EQ.8 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.9 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.10 ) THEN
            anorm = small
         ELSE IF( imat.EQ.11 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'GB' ) ) THEN
*
*        xGB:  Set parameters to generate a general banded matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the condition number and norm.
*
         IF( imat.EQ.5 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.6 ) THEN
            cndnum = tenth*badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.7 ) THEN
            anorm = small
         ELSE IF( imat.EQ.8 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'GT' ) ) THEN
*
*        xGT:  Set parameters to generate a general tridiagonal matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the lower and upper bandwidths.
*
         IF( imat.EQ.1 ) THEN
            kl = 0
         ELSE
            kl = 1
         END IF
         ku = kl
*
*        Set the condition number and norm.
*
         IF( imat.EQ.3 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.4 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.5 .OR. imat.EQ.11 ) THEN
            anorm = small
         ELSE IF( imat.EQ.6 .OR. imat.EQ.12 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'PO' ) .OR. lsamen( 2, c2, 'PP' ) ) THEN
*
*        xPO, xPP: Set parameters to generate a
*        symmetric or Hermitian positive definite matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = c2( 1: 1 )
*
*        Set the lower and upper bandwidths.
*
         IF( imat.EQ.1 ) THEN
            kl = 0
         ELSE
            kl = max( n-1, 0 )
         END IF
         ku = kl
*
*        Set the condition number and norm.
*
         IF( imat.EQ.6 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.7 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.8 ) THEN
            anorm = small
         ELSE IF( imat.EQ.9 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'HE' ) .OR. lsamen( 2, c2, 'HP' ) .OR.
     $         lsamen( 2, c2, 'SY' ) .OR. lsamen( 2, c2, 'SP' ) ) THEN
*
*        xHE, xHP, xSY, xSP: Set parameters to generate a
*        symmetric or Hermitian matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = c2( 1: 1 )
*
*        Set the lower and upper bandwidths.
*
         IF( imat.EQ.1 ) THEN
            kl = 0
         ELSE
            kl = max( n-1, 0 )
         END IF
         ku = kl
*
*        Set the condition number and norm.
*
         IF( imat.EQ.7 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.8 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.9 ) THEN
            anorm = small
         ELSE IF( imat.EQ.10 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'PB' ) ) THEN
*
*        xPB:  Set parameters to generate a symmetric band matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'P'
*
*        Set the norm and condition number.
*
         IF( imat.EQ.5 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.6 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.7 ) THEN
            anorm = small
         ELSE IF( imat.EQ.8 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'PT' ) ) THEN
*
*        xPT:  Set parameters to generate a symmetric positive definite
*        tridiagonal matrix.
*
         TYPE = 'P'
         IF( imat.EQ.1 ) THEN
            kl = 0
         ELSE
            kl = 1
         END IF
         ku = kl
*
*        Set the condition number and norm.
*
         IF( imat.EQ.3 ) THEN
            cndnum = badc1
         ELSE IF( imat.EQ.4 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( imat.EQ.5 .OR. imat.EQ.11 ) THEN
            anorm = small
         ELSE IF( imat.EQ.6 .OR. imat.EQ.12 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'TR' ) .OR. lsamen( 2, c2, 'TP' ) ) THEN
*
*        xTR, xTP:  Set parameters to generate a triangular matrix
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the lower and upper bandwidths.
*
         mat = abs( imat )
         IF( mat.EQ.1 .OR. mat.EQ.7 ) THEN
            kl = 0
            ku = 0
         ELSE IF( imat.LT.0 ) THEN
            kl = max( n-1, 0 )
            ku = 0
         ELSE
            kl = 0
            ku = max( n-1, 0 )
         END IF
*
*        Set the condition number and norm.
*
         IF( mat.EQ.3 .OR. mat.EQ.9 ) THEN
            cndnum = badc1
         ELSE IF( mat.EQ.4 .OR. mat.EQ.10 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( mat.EQ.5 ) THEN
            anorm = small
         ELSE IF( mat.EQ.6 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
*
      ELSE IF( lsamen( 2, c2, 'TB' ) ) THEN
*
*        xTB:  Set parameters to generate a triangular band matrix.
*
*        Set TYPE, the type of matrix to be generated.
*
         TYPE = 'N'
*
*        Set the norm and condition number.
*
         mat = abs( imat )
         IF( mat.EQ.2 .OR. mat.EQ.8 ) THEN
            cndnum = badc1
         ELSE IF( mat.EQ.3 .OR. mat.EQ.9 ) THEN
            cndnum = badc2
         ELSE
            cndnum = two
         END IF
*
         IF( mat.EQ.4 ) THEN
            anorm = small
         ELSE IF( mat.EQ.5 ) THEN
            anorm = large
         ELSE
            anorm = one
         END IF
      END IF
      IF( n.LE.1 )
     $   cndnum = one
*
      RETURN
*
*     End of CLATB4
*
      END