clarnv()

subroutine clarnv	(	integer	idist,
		integer, dimension( 4 )	iseed,
		integer	n,
		complex, dimension( * )	x )

CLARNV returns a vector of random numbers from a uniform or normal distribution.

Download CLARNV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CLARNV returns a vector of n random complex numbers from a uniform or
!> normal distribution.
!> 

Parameters

[in]	IDIST	!> IDIST is INTEGER !> Specifies the distribution of the random numbers: !> = 1: real and imaginary parts each uniform (0,1) !> = 2: real and imaginary parts each uniform (-1,1) !> = 3: real and imaginary parts each normal (0,1) !> = 4: uniformly distributed on the disc abs(z) < 1 !> = 5: uniformly distributed on the circle abs(z) = 1 !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry, the seed of the random number generator; the array !> elements must be between 0 and 4095, and ISEED(4) must be !> odd. !> On exit, the seed is updated. !>
[in]	N	!> N is INTEGER !> The number of random numbers to be generated. !>
[out]	X	!> X is COMPLEX array, dimension (N) !> The generated random numbers. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  This routine calls the auxiliary routine SLARUV to generate random
!>  real numbers from a uniform (0,1) distribution, in batches of up to
!>  128 using vectorisable code. The Box-Muller method is used to
!>  transform numbers from a uniform to a normal distribution.
!> 

Definition at line 96 of file clarnv.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IDIST, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      COMPLEX            X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
      INTEGER            LV
      parameter( lv = 128 )
      REAL               TWOPI
      parameter( twopi = 6.28318530717958647692528676655900576839e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IL, IV
*     ..
*     .. Local Arrays ..
      REAL               U( LV )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, exp, log, min, sqrt
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaruv
*     ..
*     .. Executable Statements ..
*
      DO 60 iv = 1, n, lv / 2
         il = min( lv / 2, n-iv+1 )
*
*        Call SLARUV to generate 2*IL real numbers from a uniform (0,1)
*        distribution (2*IL <= LV)
*
         CALL slaruv( iseed, 2*il, u )
*
         IF( idist.EQ.1 ) THEN
*
*           Copy generated numbers
*
            DO 10 i = 1, il
               x( iv+i-1 ) = cmplx( u( 2*i-1 ), u( 2*i ) )
   10       CONTINUE
         ELSE IF( idist.EQ.2 ) THEN
*
*           Convert generated numbers to uniform (-1,1) distribution
*
            DO 20 i = 1, il
               x( iv+i-1 ) = cmplx( two*u( 2*i-1 )-one,
     $                       two*u( 2*i )-one )
   20       CONTINUE
         ELSE IF( idist.EQ.3 ) THEN
*
*           Convert generated numbers to normal (0,1) distribution
*
            DO 30 i = 1, il
               x( iv+i-1 ) = sqrt( -two*log( u( 2*i-1 ) ) )*
     $                       exp( cmplx( zero, twopi*u( 2*i ) ) )
   30       CONTINUE
         ELSE IF( idist.EQ.4 ) THEN
*
*           Convert generated numbers to complex numbers uniformly
*           distributed on the unit disk
*
            DO 40 i = 1, il
               x( iv+i-1 ) = sqrt( u( 2*i-1 ) )*
     $                       exp( cmplx( zero, twopi*u( 2*i ) ) )
   40       CONTINUE
         ELSE IF( idist.EQ.5 ) THEN
*
*           Convert generated numbers to complex numbers uniformly
*           distributed on the unit circle
*
            DO 50 i = 1, il
               x( iv+i-1 ) = exp( cmplx( zero, twopi*u( 2*i ) ) )
   50       CONTINUE
         END IF
   60 CONTINUE
      RETURN
*
*     End of CLARNV
*

Here is the call graph for this function:

Here is the caller graph for this function: