zgelst.f

Go to the documentation of this file.

*> \brief <b> ZGELST solves overdetermined or underdetermined systems for GE matrices using QR or LQ factorization with compact WY representation of Q.</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZGELST + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zgelst.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zgelst.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zgelst.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZGELST( TRANS, M, N, NRHS, A, LDA, B, LDB, WORK, LWORK,
*                          INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZGELST solves overdetermined or underdetermined real linear systems
*> involving an M-by-N matrix A, or its conjugate-transpose, using a QR
*> or LQ factorization of A with compact WY representation of Q.
*> It is assumed that A has full rank.
*>
*> The following options are provided:
*>
*> 1. If TRANS = 'N' and m >= n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A*X ||.
*>
*> 2. If TRANS = 'N' and m < n:  find the minimum norm solution of
*>    an underdetermined system A * X = B.
*>
*> 3. If TRANS = 'C' and m >= n:  find the minimum norm solution of
*>    an underdetermined system A**T * X = B.
*>
*> 4. If TRANS = 'C' and m < n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A**T * X ||.
*>
*> Several right hand side vectors b and solution vectors x can be
*> handled in a single call; they are stored as the columns of the
*> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
*> matrix X.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N': the linear system involves A;
*>          = 'C': the linear system involves A**H.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of
*>          columns of the matrices B and X. NRHS >=0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit,
*>            if M >= N, A is overwritten by details of its QR
*>                       factorization as returned by ZGEQRT;
*>            if M <  N, A is overwritten by details of its LQ
*>                       factorization as returned by ZGELQT.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (LDB,NRHS)
*>          On entry, the matrix B of right hand side vectors, stored
*>          columnwise; B is M-by-NRHS if TRANS = 'N', or N-by-NRHS
*>          if TRANS = 'C'.
*>          On exit, if INFO = 0, B is overwritten by the solution
*>          vectors, stored columnwise:
*>          if TRANS = 'N' and m >= n, rows 1 to n of B contain the least
*>          squares solution vectors; the residual sum of squares for the
*>          solution in each column is given by the sum of squares of
*>          modulus of elements N+1 to M in that column;
*>          if TRANS = 'N' and m < n, rows 1 to N of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'C' and m >= n, rows 1 to M of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'C' and m < n, rows 1 to M of B contain the
*>          least squares solution vectors; the residual sum of squares
*>          for the solution in each column is given by the sum of
*>          squares of the modulus of elements M+1 to N in that column.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= MAX(1,M,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          LWORK >= max( 1, MN + max( MN, NRHS ) ).
*>          For optimal performance,
*>          LWORK >= max( 1, (MN + max( MN, NRHS ))*NB ).
*>          where MN = min(M,N) and NB is the optimum block size.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO =  i, the i-th diagonal element of the
*>                triangular factor of A is zero, so that A does not have
*>                full rank; the least squares solution could not be
*>                computed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup gelst
*
*> \par Contributors:
*  ==================
*>
*> \verbatim
*>
*>  November 2022,  Igor Kozachenko,
*>                  Computer Science Division,
*>                  University of California, Berkeley
*> \endverbatim
*
*  =====================================================================
      SUBROUTINE zgelst( TRANS, M, N, NRHS, A, LDA, B, LDB, WORK, LWORK,
     $                   INFO )
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO
      parameter( czero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, TPSD
      INTEGER            BROW, I, IASCL, IBSCL, J, LWOPT, MN, MNNRHS,
     $                   nb, nbmin, scllen
      DOUBLE PRECISION   ANRM, BIGNUM, BNRM, SMLNUM
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, ZLANGE
      EXTERNAL           lsame, ilaenv, dlamch, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgelqt, zgeqrt, zgemlqt, zgemqrt, zlascl,
     $                   zlaset, ztrtrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      mn = min( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( .NOT.( lsame( trans, 'N' ) .OR. lsame( trans, 'C' ) ) ) THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, m, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.max( 1, mn+max( mn, nrhs ) ) .AND. .NOT.lquery )
     $          THEN
         info = -10
      END IF
*
*     Figure out optimal block size and optimal workspace size
*
      IF( info.EQ.0 .OR. info.EQ.-10 ) THEN
*
         tpsd = .true.
         IF( lsame( trans, 'N' ) )
     $      tpsd = .false.
*
         nb = ilaenv( 1, 'ZGELST', ' ', m, n, -1, -1 )
*
         mnnrhs = max( mn, nrhs )
         lwopt = max( 1, (mn+mnnrhs)*nb )
         work( 1 ) = dble( lwopt )
*
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZGELST ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, nrhs ).EQ.0 ) THEN
         CALL zlaset( 'Full', max( m, n ), nrhs, czero, czero, b, ldb )
         work( 1 ) = dble( lwopt )
         RETURN
      END IF
*
*     *GEQRT and *GELQT routines cannot accept NB larger than min(M,N)
*
      IF( nb.GT.mn ) nb = mn
*
*     Determine the block size from the supplied LWORK
*     ( at this stage we know that LWORK >= (minimum required workspace,
*     but it may be less than optimal)
*
      nb = min( nb, lwork/( mn + mnnrhs ) )
*
*     The minimum value of NB, when blocked code is used
*
      nbmin = max( 2, ilaenv( 2, 'ZGELST', ' ', m, n, -1, -1 ) )
*
      IF( nb.LT.nbmin ) THEN
         nb = 1
      END IF
*
*     Get machine parameters
*
      smlnum = dlamch( 'S' ) / dlamch( 'P' )
      bignum = one / smlnum
*
*     Scale A, B if max element outside range [SMLNUM,BIGNUM]
*
      anrm = zlange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL zlascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL zlascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL zlaset( 'Full', max( m, n ), nrhs, czero, czero, b, ldb )
         work( 1 ) = dble( lwopt )
         RETURN
      END IF
*
      brow = m
      IF( tpsd )
     $   brow = n
      bnrm = zlange( 'M', brow, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL zlascl( 'G', 0, 0, bnrm, smlnum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL zlascl( 'G', 0, 0, bnrm, bignum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
      IF( m.GE.n ) THEN
*
*        M > N:
*        Compute the blocked QR factorization of A,
*        using the compact WY representation of Q,
*        workspace at least N, optimally N*NB.
*
         CALL zgeqrt( m, n, nb, a, lda, work( 1 ), nb,
     $                work( mn*nb+1 ), info )
*
         IF( .NOT.tpsd ) THEN
*
*           M > N, A is not transposed:
*           Overdetermined system of equations,
*           least-squares problem, min || A * X - B ||.
*
*           Compute B(1:M,1:NRHS) := Q**T * B(1:M,1:NRHS),
*           using the compact WY representation of Q,
*           workspace at least NRHS, optimally NRHS*NB.
*
            CALL zgemqrt( 'Left', 'Conjugate transpose', m, nrhs, n, nb,
     $                    a, lda, work( 1 ), nb, b, ldb,
     $                    work( mn*nb+1 ), info )
*
*           Compute B(1:N,1:NRHS) := inv(R) * B(1:N,1:NRHS)
*
            CALL ztrtrs( 'Upper', 'No transpose', 'Non-unit', n, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
            scllen = n
*
         ELSE
*
*           M > N, A is transposed:
*           Underdetermined system of equations,
*           minimum norm solution of A**T * X = B.
*
*           Compute B := inv(R**T) * B in two row blocks of B.
*
*           Block 1: B(1:N,1:NRHS) := inv(R**T) * B(1:N,1:NRHS)
*
            CALL ztrtrs( 'Upper', 'Conjugate transpose', 'Non-unit',
     $                   n, nrhs, a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           Block 2: Zero out all rows below the N-th row in B:
*           B(N+1:M,1:NRHS) = ZERO
*
            DO  j = 1, nrhs
               DO i = n + 1, m
                  b( i, j ) = zero
               END DO
            END DO
*
*           Compute B(1:M,1:NRHS) := Q(1:N,:) * B(1:N,1:NRHS),
*           using the compact WY representation of Q,
*           workspace at least NRHS, optimally NRHS*NB.
*
            CALL zgemqrt( 'Left', 'No transpose', m, nrhs, n, nb,
     $                    a, lda, work( 1 ), nb, b, ldb,
     $                    work( mn*nb+1 ), info )
*
            scllen = m
*
         END IF
*
      ELSE
*
*        M < N:
*        Compute the blocked LQ factorization of A,
*        using the compact WY representation of Q,
*        workspace at least M, optimally M*NB.
*
         CALL zgelqt( m, n, nb, a, lda, work( 1 ), nb,
     $                work( mn*nb+1 ), info )
*
         IF( .NOT.tpsd ) THEN
*
*           M < N, A is not transposed:
*           Underdetermined system of equations,
*           minimum norm solution of A * X = B.
*
*           Compute B := inv(L) * B in two row blocks of B.
*
*           Block 1: B(1:M,1:NRHS) := inv(L) * B(1:M,1:NRHS)
*
            CALL ztrtrs( 'Lower', 'No transpose', 'Non-unit', m, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           Block 2: Zero out all rows below the M-th row in B:
*           B(M+1:N,1:NRHS) = ZERO
*
            DO j = 1, nrhs
               DO i = m + 1, n
                  b( i, j ) = zero
               END DO
            END DO
*
*           Compute B(1:N,1:NRHS) := Q(1:N,:)**T * B(1:M,1:NRHS),
*           using the compact WY representation of Q,
*           workspace at least NRHS, optimally NRHS*NB.
*
            CALL zgemlqt( 'Left', 'Conjugate transpose', n, nrhs, m, nb,
     $                   a, lda, work( 1 ), nb, b, ldb,
     $                   work( mn*nb+1 ), info )
*
            scllen = n
*
         ELSE
*
*           M < N, A is transposed:
*           Overdetermined system of equations,
*           least-squares problem, min || A**T * X - B ||.
*
*           Compute B(1:N,1:NRHS) := Q * B(1:N,1:NRHS),
*           using the compact WY representation of Q,
*           workspace at least NRHS, optimally NRHS*NB.
*
            CALL zgemlqt( 'Left', 'No transpose', n, nrhs, m, nb,
     $                    a, lda, work( 1 ), nb, b, ldb,
     $                    work( mn*nb+1), info )
*
*           Compute B(1:M,1:NRHS) := inv(L**T) * B(1:M,1:NRHS)
*
            CALL ztrtrs( 'Lower', 'Conjugate transpose', 'Non-unit',
     $                   m, nrhs, a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
            scllen = m
*
         END IF
*
      END IF
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL zlascl( 'G', 0, 0, anrm, smlnum, scllen, nrhs, b, ldb,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL zlascl( 'G', 0, 0, anrm, bignum, scllen, nrhs, b, ldb,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL zlascl( 'G', 0, 0, smlnum, bnrm, scllen, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL zlascl( 'G', 0, 0, bignum, bnrm, scllen, nrhs, b, ldb,
     $                info )
      END IF
*
      work( 1 ) = dble( lwopt )
*
      RETURN
*
*     End of ZGELST
*
      END