dggevx()

subroutine dggevx	(	character	balanc,
		character	jobvl,
		character	jobvr,
		character	sense,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( * )	alphar,
		double precision, dimension( * )	alphai,
		double precision, dimension( * )	beta,
		double precision, dimension( ldvl, * )	vl,
		integer	ldvl,
		double precision, dimension( ldvr, * )	vr,
		integer	ldvr,
		integer	ilo,
		integer	ihi,
		double precision, dimension( * )	lscale,
		double precision, dimension( * )	rscale,
		double precision	abnrm,
		double precision	bbnrm,
		double precision, dimension( * )	rconde,
		double precision, dimension( * )	rcondv,
		double precision, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		logical, dimension( * )	bwork,
		integer	info )

DGGEVX computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices

Download DGGEVX + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DGGEVX computes for a pair of N-by-N real nonsymmetric matrices (A,B)
!> the generalized eigenvalues, and optionally, the left and/or right
!> generalized eigenvectors.
!>
!> Optionally also, it computes a balancing transformation to improve
!> the conditioning of the eigenvalues and eigenvectors (ILO, IHI,
!> LSCALE, RSCALE, ABNRM, and BBNRM), reciprocal condition numbers for
!> the eigenvalues (RCONDE), and reciprocal condition numbers for the
!> right eigenvectors (RCONDV).
!>
!> A generalized eigenvalue for a pair of matrices (A,B) is a scalar
!> lambda or a ratio alpha/beta = lambda, such that A - lambda*B is
!> singular. It is usually represented as the pair (alpha,beta), as
!> there is a reasonable interpretation for beta=0, and even for both
!> being zero.
!>
!> The right eigenvector v(j) corresponding to the eigenvalue lambda(j)
!> of (A,B) satisfies
!>
!>                  A * v(j) = lambda(j) * B * v(j) .
!>
!> The left eigenvector u(j) corresponding to the eigenvalue lambda(j)
!> of (A,B) satisfies
!>
!>                  u(j)**H * A  = lambda(j) * u(j)**H * B.
!>
!> where u(j)**H is the conjugate-transpose of u(j).
!>
!> 

Parameters

[in]	BALANC	!> BALANC is CHARACTER*1 !> Specifies the balance option to be performed. !> = 'N': do not diagonally scale or permute; !> = 'P': permute only; !> = 'S': scale only; !> = 'B': both permute and scale. !> Computed reciprocal condition numbers will be for the !> matrices after permuting and/or balancing. Permuting does !> not change condition numbers (in exact arithmetic), but !> balancing does. !>
[in]	JOBVL	!> JOBVL is CHARACTER*1 !> = 'N': do not compute the left generalized eigenvectors; !> = 'V': compute the left generalized eigenvectors. !>
[in]	JOBVR	!> JOBVR is CHARACTER*1 !> = 'N': do not compute the right generalized eigenvectors; !> = 'V': compute the right generalized eigenvectors. !>
[in]	SENSE	!> SENSE is CHARACTER*1 !> Determines which reciprocal condition numbers are computed. !> = 'N': none are computed; !> = 'E': computed for eigenvalues only; !> = 'V': computed for eigenvectors only; !> = 'B': computed for eigenvalues and eigenvectors. !>
[in]	N	!> N is INTEGER !> The order of the matrices A, B, VL, and VR. N >= 0. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA, N) !> On entry, the matrix A in the pair (A,B). !> On exit, A has been overwritten. If JOBVL='V' or JOBVR='V' !> or both, then A contains the first part of the real Schur !> form of the versions of the input A and B. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of A. LDA >= max(1,N). !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB, N) !> On entry, the matrix B in the pair (A,B). !> On exit, B has been overwritten. If JOBVL='V' or JOBVR='V' !> or both, then B contains the second part of the real Schur !> form of the versions of the input A and B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of B. LDB >= max(1,N). !>
[out]	ALPHAR	!> ALPHAR is DOUBLE PRECISION array, dimension (N) !>
[out]	ALPHAI	!> ALPHAI is DOUBLE PRECISION array, dimension (N) !>
[out]	BETA	!> BETA is DOUBLE PRECISION array, dimension (N) !> On exit, (ALPHAR(j) + ALPHAI(j)*i)/BETA(j), j=1,...,N, will !> be the generalized eigenvalues. If ALPHAI(j) is zero, then !> the j-th eigenvalue is real; if positive, then the j-th and !> (j+1)-st eigenvalues are a complex conjugate pair, with !> ALPHAI(j+1) negative. !> !> Note: the quotients ALPHAR(j)/BETA(j) and ALPHAI(j)/BETA(j) !> may easily over- or underflow, and BETA(j) may even be zero. !> Thus, the user should avoid naively computing the ratio !> ALPHA/BETA. However, ALPHAR and ALPHAI will be always less !> than and usually comparable with norm(A) in magnitude, and !> BETA always less than and usually comparable with norm(B). !>
[out]	VL	!> VL is DOUBLE PRECISION array, dimension (LDVL,N) !> If JOBVL = 'V', the left eigenvectors u(j) are stored one !> after another in the columns of VL, in the same order as !> their eigenvalues. If the j-th eigenvalue is real, then !> u(j) = VL(:,j), the j-th column of VL. If the j-th and !> (j+1)-th eigenvalues form a complex conjugate pair, then !> u(j) = VL(:,j)+i*VL(:,j+1) and u(j+1) = VL(:,j)-i*VL(:,j+1). !> Each eigenvector will be scaled so the largest component have !> abs(real part) + abs(imag. part) = 1. !> Not referenced if JOBVL = 'N'. !>
[in]	LDVL	!> LDVL is INTEGER !> The leading dimension of the matrix VL. LDVL >= 1, and !> if JOBVL = 'V', LDVL >= N. !>
[out]	VR	!> VR is DOUBLE PRECISION array, dimension (LDVR,N) !> If JOBVR = 'V', the right eigenvectors v(j) are stored one !> after another in the columns of VR, in the same order as !> their eigenvalues. If the j-th eigenvalue is real, then !> v(j) = VR(:,j), the j-th column of VR. If the j-th and !> (j+1)-th eigenvalues form a complex conjugate pair, then !> v(j) = VR(:,j)+i*VR(:,j+1) and v(j+1) = VR(:,j)-i*VR(:,j+1). !> Each eigenvector will be scaled so the largest component have !> abs(real part) + abs(imag. part) = 1. !> Not referenced if JOBVR = 'N'. !>
[in]	LDVR	!> LDVR is INTEGER !> The leading dimension of the matrix VR. LDVR >= 1, and !> if JOBVR = 'V', LDVR >= N. !>
[out]	ILO	!> ILO is INTEGER !>
[out]	IHI	!> IHI is INTEGER !> ILO and IHI are integer values such that on exit !> A(i,j) = 0 and B(i,j) = 0 if i > j and !> j = 1,...,ILO-1 or i = IHI+1,...,N. !> If BALANC = 'N' or 'S', ILO = 1 and IHI = N. !>
[out]	LSCALE	!> LSCALE is DOUBLE PRECISION array, dimension (N) !> Details of the permutations and scaling factors applied !> to the left side of A and B. If PL(j) is the index of the !> row interchanged with row j, and DL(j) is the scaling !> factor applied to row j, then !> LSCALE(j) = PL(j) for j = 1,...,ILO-1 !> = DL(j) for j = ILO,...,IHI !> = PL(j) for j = IHI+1,...,N. !> The order in which the interchanges are made is N to IHI+1, !> then 1 to ILO-1. !>
[out]	RSCALE	!> RSCALE is DOUBLE PRECISION array, dimension (N) !> Details of the permutations and scaling factors applied !> to the right side of A and B. If PR(j) is the index of the !> column interchanged with column j, and DR(j) is the scaling !> factor applied to column j, then !> RSCALE(j) = PR(j) for j = 1,...,ILO-1 !> = DR(j) for j = ILO,...,IHI !> = PR(j) for j = IHI+1,...,N !> The order in which the interchanges are made is N to IHI+1, !> then 1 to ILO-1. !>
[out]	ABNRM	!> ABNRM is DOUBLE PRECISION !> The one-norm of the balanced matrix A. !>
[out]	BBNRM	!> BBNRM is DOUBLE PRECISION !> The one-norm of the balanced matrix B. !>
[out]	RCONDE	!> RCONDE is DOUBLE PRECISION array, dimension (N) !> If SENSE = 'E' or 'B', the reciprocal condition numbers of !> the eigenvalues, stored in consecutive elements of the array. !> For a complex conjugate pair of eigenvalues two consecutive !> elements of RCONDE are set to the same value. Thus RCONDE(j), !> RCONDV(j), and the j-th columns of VL and VR all correspond !> to the j-th eigenpair. !> If SENSE = 'N or 'V', RCONDE is not referenced. !>
[out]	RCONDV	!> RCONDV is DOUBLE PRECISION array, dimension (N) !> If SENSE = 'V' or 'B', the estimated reciprocal condition !> numbers of the eigenvectors, stored in consecutive elements !> of the array. For a complex eigenvector two consecutive !> elements of RCONDV are set to the same value. If the !> eigenvalues cannot be reordered to compute RCONDV(j), !> RCONDV(j) is set to 0; this can only occur when the true !> value would be very small anyway. !> If SENSE = 'N' or 'E', RCONDV is not referenced. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,2*N). !> If BALANC = 'S' or 'B', or JOBVL = 'V', or JOBVR = 'V', !> LWORK >= max(1,6*N). !> If SENSE = 'E' or 'B', LWORK >= max(1,10*N). !> If SENSE = 'V' or 'B', LWORK >= 2*N*N+8*N+16. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N+6) !> If SENSE = 'E', IWORK is not referenced. !>
[out]	BWORK	!> BWORK is LOGICAL array, dimension (N) !> If SENSE = 'N', BWORK is not referenced. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> = 1,...,N: !> The QZ iteration failed. No eigenvectors have been !> calculated, but ALPHAR(j), ALPHAI(j), and BETA(j) !> should be correct for j=INFO+1,...,N. !> > N: =N+1: other than QZ iteration failed in DHGEQZ. !> =N+2: error return from DTGEVC. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  Balancing a matrix pair (A,B) includes, first, permuting rows and
!>  columns to isolate eigenvalues, second, applying diagonal similarity
!>  transformation to the rows and columns to make the rows and columns
!>  as close in norm as possible. The computed reciprocal condition
!>  numbers correspond to the balanced matrix. Permuting rows and columns
!>  will not change the condition numbers (in exact arithmetic) but
!>  diagonal scaling will.  For further explanation of balancing, see
!>  section 4.11.1.2 of LAPACK Users' Guide.
!>
!>  An approximate error bound on the chordal distance between the i-th
!>  computed generalized eigenvalue w and the corresponding exact
!>  eigenvalue lambda is
!>
!>       chord(w, lambda) <= EPS * norm(ABNRM, BBNRM) / RCONDE(I)
!>
!>  An approximate error bound for the angle between the i-th computed
!>  eigenvector VL(i) or VR(i) is given by
!>
!>       EPS * norm(ABNRM, BBNRM) / DIF(i).
!>
!>  For further explanation of the reciprocal condition numbers RCONDE
!>  and RCONDV, see section 4.11 of LAPACK User's Guide.
!> 

Definition at line 385 of file dggevx.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          BALANC, JOBVL, JOBVR, SENSE
      INTEGER            IHI, ILO, INFO, LDA, LDB, LDVL, LDVR, LWORK, N
      DOUBLE PRECISION   ABNRM, BBNRM
*     ..
*     .. Array Arguments ..
      LOGICAL            BWORK( * )
      INTEGER            IWORK( * )
      DOUBLE PRECISION   A( LDA, * ), ALPHAI( * ), ALPHAR( * ),
     $                   B( LDB, * ), BETA( * ), LSCALE( * ),
     $                   RCONDE( * ), RCONDV( * ), RSCALE( * ),
     $                   VL( LDVL, * ), VR( LDVR, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ILASCL, ILBSCL, ILV, ILVL, ILVR, LQUERY, NOSCL,
     $                   PAIR, WANTSB, WANTSE, WANTSN, WANTSV
      CHARACTER          CHTEMP
      INTEGER            I, ICOLS, IERR, IJOBVL, IJOBVR, IN, IROWS,
     $                   ITAU, IWRK, IWRK1, J, JC, JR, M, MAXWRK,
     $                   MINWRK, MM
      DOUBLE PRECISION   ANRM, ANRMTO, BIGNUM, BNRM, BNRMTO, EPS,
     $                   SMLNUM, TEMP
*     ..
*     .. Local Arrays ..
      LOGICAL            LDUMMA( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgeqrf, dggbak, dggbal, dgghrd, dhgeqz,
     $                   dlacpy,
     $                   dlascl, dlaset, dorgqr, dormqr, dtgevc, dtgsna,
     $                   xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           lsame, ilaenv, dlamch, dlange
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Decode the input arguments
*
      IF( lsame( jobvl, 'N' ) ) THEN
         ijobvl = 1
         ilvl = .false.
      ELSE IF( lsame( jobvl, 'V' ) ) THEN
         ijobvl = 2
         ilvl = .true.
      ELSE
         ijobvl = -1
         ilvl = .false.
      END IF
*
      IF( lsame( jobvr, 'N' ) ) THEN
         ijobvr = 1
         ilvr = .false.
      ELSE IF( lsame( jobvr, 'V' ) ) THEN
         ijobvr = 2
         ilvr = .true.
      ELSE
         ijobvr = -1
         ilvr = .false.
      END IF
      ilv = ilvl .OR. ilvr
*
      noscl  = lsame( balanc, 'N' ) .OR. lsame( balanc, 'P' )
      wantsn = lsame( sense, 'N' )
      wantse = lsame( sense, 'E' )
      wantsv = lsame( sense, 'V' )
      wantsb = lsame( sense, 'B' )
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( .NOT.( lsame( balanc, 'N' ) .OR. lsame( balanc,
     $    'S' ) .OR.
     $                      lsame( balanc, 'P' ) .OR.
     $                      lsame( balanc, 'B' ) ) )
     $     THEN
         info = -1
      ELSE IF( ijobvl.LE.0 ) THEN
         info = -2
      ELSE IF( ijobvr.LE.0 ) THEN
         info = -3
      ELSE IF( .NOT.( wantsn .OR. wantse .OR. wantsb .OR. wantsv ) )
     $          THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      ELSE IF( ldvl.LT.1 .OR. ( ilvl .AND. ldvl.LT.n ) ) THEN
         info = -14
      ELSE IF( ldvr.LT.1 .OR. ( ilvr .AND. ldvr.LT.n ) ) THEN
         info = -16
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV. The workspace is
*       computed assuming ILO = 1 and IHI = N, the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            IF( noscl .AND. .NOT.ilv ) THEN
               minwrk = 2*n
            ELSE
               minwrk = 6*n
            END IF
            IF( wantse .OR. wantsb ) THEN
               minwrk = 10*n
            END IF
            IF( wantsv .OR. wantsb ) THEN
               minwrk = max( minwrk, 2*n*( n + 4 ) + 16 )
            END IF
            maxwrk = minwrk
            maxwrk = max( maxwrk,
     $                    n + n*ilaenv( 1, 'DGEQRF', ' ', n, 1, n,
     $                                  0 ) )
            maxwrk = max( maxwrk,
     $                    n + n*ilaenv( 1, 'DORMQR', ' ', n, 1, n,
     $                                  0 ) )
            IF( ilvl ) THEN
               maxwrk = max( maxwrk, n +
     $                       n*ilaenv( 1, 'DORGQR', ' ', n, 1, n,
     $                                 0 ) )
            END IF
         END IF
         work( 1 ) = maxwrk
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -26
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGGEVX', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = dlange( 'M', n, n, a, lda, work )
      ilascl = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         anrmto = smlnum
         ilascl = .true.
      ELSE IF( anrm.GT.bignum ) THEN
         anrmto = bignum
         ilascl = .true.
      END IF
      IF( ilascl )
     $   CALL dlascl( 'G', 0, 0, anrm, anrmto, n, n, a, lda, ierr )
*
*     Scale B if max element outside range [SMLNUM,BIGNUM]
*
      bnrm = dlange( 'M', n, n, b, ldb, work )
      ilbscl = .false.
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
         bnrmto = smlnum
         ilbscl = .true.
      ELSE IF( bnrm.GT.bignum ) THEN
         bnrmto = bignum
         ilbscl = .true.
      END IF
      IF( ilbscl )
     $   CALL dlascl( 'G', 0, 0, bnrm, bnrmto, n, n, b, ldb, ierr )
*
*     Permute and/or balance the matrix pair (A,B)
*     (Workspace: need 6*N if BALANC = 'S' or 'B', 1 otherwise)
*
      CALL dggbal( balanc, n, a, lda, b, ldb, ilo, ihi, lscale,
     $             rscale,
     $             work, ierr )
*
*     Compute ABNRM and BBNRM
*
      abnrm = dlange( '1', n, n, a, lda, work( 1 ) )
      IF( ilascl ) THEN
         work( 1 ) = abnrm
         CALL dlascl( 'G', 0, 0, anrmto, anrm, 1, 1, work( 1 ), 1,
     $                ierr )
         abnrm = work( 1 )
      END IF
*
      bbnrm = dlange( '1', n, n, b, ldb, work( 1 ) )
      IF( ilbscl ) THEN
         work( 1 ) = bbnrm
         CALL dlascl( 'G', 0, 0, bnrmto, bnrm, 1, 1, work( 1 ), 1,
     $                ierr )
         bbnrm = work( 1 )
      END IF
*
*     Reduce B to triangular form (QR decomposition of B)
*     (Workspace: need N, prefer N*NB )
*
      irows = ihi + 1 - ilo
      IF( ilv .OR. .NOT.wantsn ) THEN
         icols = n + 1 - ilo
      ELSE
         icols = irows
      END IF
      itau = 1
      iwrk = itau + irows
      CALL dgeqrf( irows, icols, b( ilo, ilo ), ldb, work( itau ),
     $             work( iwrk ), lwork+1-iwrk, ierr )
*
*     Apply the orthogonal transformation to A
*     (Workspace: need N, prefer N*NB)
*
      CALL dormqr( 'L', 'T', irows, icols, irows, b( ilo, ilo ), ldb,
     $             work( itau ), a( ilo, ilo ), lda, work( iwrk ),
     $             lwork+1-iwrk, ierr )
*
*     Initialize VL and/or VR
*     (Workspace: need N, prefer N*NB)
*
      IF( ilvl ) THEN
         CALL dlaset( 'Full', n, n, zero, one, vl, ldvl )
         IF( irows.GT.1 ) THEN
            CALL dlacpy( 'L', irows-1, irows-1, b( ilo+1, ilo ), ldb,
     $                   vl( ilo+1, ilo ), ldvl )
         END IF
         CALL dorgqr( irows, irows, irows, vl( ilo, ilo ), ldvl,
     $                work( itau ), work( iwrk ), lwork+1-iwrk, ierr )
      END IF
*
      IF( ilvr )
     $   CALL dlaset( 'Full', n, n, zero, one, vr, ldvr )
*
*     Reduce to generalized Hessenberg form
*     (Workspace: none needed)
*
      IF( ilv .OR. .NOT.wantsn ) THEN
*
*        Eigenvectors requested -- work on whole matrix.
*
         CALL dgghrd( jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb, vl,
     $                ldvl, vr, ldvr, ierr )
      ELSE
         CALL dgghrd( 'N', 'N', irows, 1, irows, a( ilo, ilo ), lda,
     $                b( ilo, ilo ), ldb, vl, ldvl, vr, ldvr, ierr )
      END IF
*
*     Perform QZ algorithm (Compute eigenvalues, and optionally, the
*     Schur forms and Schur vectors)
*     (Workspace: need N)
*
      IF( ilv .OR. .NOT.wantsn ) THEN
         chtemp = 'S'
      ELSE
         chtemp = 'E'
      END IF
*
      CALL dhgeqz( chtemp, jobvl, jobvr, n, ilo, ihi, a, lda, b, ldb,
     $             alphar, alphai, beta, vl, ldvl, vr, ldvr, work,
     $             lwork, ierr )
      IF( ierr.NE.0 ) THEN
         IF( ierr.GT.0 .AND. ierr.LE.n ) THEN
            info = ierr
         ELSE IF( ierr.GT.n .AND. ierr.LE.2*n ) THEN
            info = ierr - n
         ELSE
            info = n + 1
         END IF
         GO TO 130
      END IF
*
*     Compute Eigenvectors and estimate condition numbers if desired
*     (Workspace: DTGEVC: need 6*N
*                 DTGSNA: need 2*N*(N+2)+16 if SENSE = 'V' or 'B',
*                         need N otherwise )
*
      IF( ilv .OR. .NOT.wantsn ) THEN
         IF( ilv ) THEN
            IF( ilvl ) THEN
               IF( ilvr ) THEN
                  chtemp = 'B'
               ELSE
                  chtemp = 'L'
               END IF
            ELSE
               chtemp = 'R'
            END IF
*
            CALL dtgevc( chtemp, 'B', ldumma, n, a, lda, b, ldb, vl,
     $                   ldvl, vr, ldvr, n, in, work, ierr )
            IF( ierr.NE.0 ) THEN
               info = n + 2
               GO TO 130
            END IF
         END IF
*
         IF( .NOT.wantsn ) THEN
*
*           compute eigenvectors (DTGEVC) and estimate condition
*           numbers (DTGSNA). Note that the definition of the condition
*           number is not invariant under transformation (u,v) to
*           (Q*u, Z*v), where (u,v) are eigenvectors of the generalized
*           Schur form (S,T), Q and Z are orthogonal matrices. In order
*           to avoid using extra 2*N*N workspace, we have to recalculate
*           eigenvectors and estimate one condition numbers at a time.
*
            pair = .false.
            DO 20 i = 1, n
*
               IF( pair ) THEN
                  pair = .false.
                  GO TO 20
               END IF
               mm = 1
               IF( i.LT.n ) THEN
                  IF( a( i+1, i ).NE.zero ) THEN
                     pair = .true.
                     mm = 2
                  END IF
               END IF
*
               DO 10 j = 1, n
                  bwork( j ) = .false.
   10          CONTINUE
               IF( mm.EQ.1 ) THEN
                  bwork( i ) = .true.
               ELSE IF( mm.EQ.2 ) THEN
                  bwork( i ) = .true.
                  bwork( i+1 ) = .true.
               END IF
*
               iwrk = mm*n + 1
               iwrk1 = iwrk + mm*n
*
*              Compute a pair of left and right eigenvectors.
*              (compute workspace: need up to 4*N + 6*N)
*
               IF( wantse .OR. wantsb ) THEN
                  CALL dtgevc( 'B', 'S', bwork, n, a, lda, b, ldb,
     $                         work( 1 ), n, work( iwrk ), n, mm, m,
     $                         work( iwrk1 ), ierr )
                  IF( ierr.NE.0 ) THEN
                     info = n + 2
                     GO TO 130
                  END IF
               END IF
*
               CALL dtgsna( sense, 'S', bwork, n, a, lda, b, ldb,
     $                      work( 1 ), n, work( iwrk ), n, rconde( i ),
     $                      rcondv( i ), mm, m, work( iwrk1 ),
     $                      lwork-iwrk1+1, iwork, ierr )
*
   20       CONTINUE
         END IF
      END IF
*
*     Undo balancing on VL and VR and normalization
*     (Workspace: none needed)
*
      IF( ilvl ) THEN
         CALL dggbak( balanc, 'L', n, ilo, ihi, lscale, rscale, n,
     $                vl,
     $                ldvl, ierr )
*
         DO 70 jc = 1, n
            IF( alphai( jc ).LT.zero )
     $         GO TO 70
            temp = zero
            IF( alphai( jc ).EQ.zero ) THEN
               DO 30 jr = 1, n
                  temp = max( temp, abs( vl( jr, jc ) ) )
   30          CONTINUE
            ELSE
               DO 40 jr = 1, n
                  temp = max( temp, abs( vl( jr, jc ) )+
     $                   abs( vl( jr, jc+1 ) ) )
   40          CONTINUE
            END IF
            IF( temp.LT.smlnum )
     $         GO TO 70
            temp = one / temp
            IF( alphai( jc ).EQ.zero ) THEN
               DO 50 jr = 1, n
                  vl( jr, jc ) = vl( jr, jc )*temp
   50          CONTINUE
            ELSE
               DO 60 jr = 1, n
                  vl( jr, jc ) = vl( jr, jc )*temp
                  vl( jr, jc+1 ) = vl( jr, jc+1 )*temp
   60          CONTINUE
            END IF
   70    CONTINUE
      END IF
      IF( ilvr ) THEN
         CALL dggbak( balanc, 'R', n, ilo, ihi, lscale, rscale, n,
     $                vr,
     $                ldvr, ierr )
         DO 120 jc = 1, n
            IF( alphai( jc ).LT.zero )
     $         GO TO 120
            temp = zero
            IF( alphai( jc ).EQ.zero ) THEN
               DO 80 jr = 1, n
                  temp = max( temp, abs( vr( jr, jc ) ) )
   80          CONTINUE
            ELSE
               DO 90 jr = 1, n
                  temp = max( temp, abs( vr( jr, jc ) )+
     $                   abs( vr( jr, jc+1 ) ) )
   90          CONTINUE
            END IF
            IF( temp.LT.smlnum )
     $         GO TO 120
            temp = one / temp
            IF( alphai( jc ).EQ.zero ) THEN
               DO 100 jr = 1, n
                  vr( jr, jc ) = vr( jr, jc )*temp
  100          CONTINUE
            ELSE
               DO 110 jr = 1, n
                  vr( jr, jc ) = vr( jr, jc )*temp
                  vr( jr, jc+1 ) = vr( jr, jc+1 )*temp
  110          CONTINUE
            END IF
  120    CONTINUE
      END IF
*
*     Undo scaling if necessary
*
  130 CONTINUE
*
      IF( ilascl ) THEN
         CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphar, n,
     $                ierr )
         CALL dlascl( 'G', 0, 0, anrmto, anrm, n, 1, alphai, n,
     $                ierr )
      END IF
*
      IF( ilbscl ) THEN
         CALL dlascl( 'G', 0, 0, bnrmto, bnrm, n, 1, beta, n, ierr )
      END IF
*
      work( 1 ) = maxwrk
      RETURN
*
*     End of DGGEVX
*

Here is the call graph for this function:

Here is the caller graph for this function: