cgelss()

subroutine cgelss	(	integer	m,
		integer	n,
		integer	nrhs,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	s,
		real	rcond,
		integer	rank,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	info )

CGELSS solves overdetermined or underdetermined systems for GE matrices

Download CGELSS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CGELSS computes the minimum norm solution to a complex linear
!> least squares problem:
!>
!> Minimize 2-norm(| b - A*x |).
!>
!> using the singular value decomposition (SVD) of A. A is an M-by-N
!> matrix which may be rank-deficient.
!>
!> Several right hand side vectors b and solution vectors x can be
!> handled in a single call; they are stored as the columns of the
!> M-by-NRHS right hand side matrix B and the N-by-NRHS solution matrix
!> X.
!>
!> The effective rank of A is determined by treating as zero those
!> singular values which are less than RCOND times the largest singular
!> value.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices B and X. NRHS >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, the first min(m,n) rows of A are overwritten with !> its right singular vectors, stored rowwise. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in,out]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> On entry, the M-by-NRHS right hand side matrix B. !> On exit, B is overwritten by the N-by-NRHS solution matrix X. !> If m >= n and RANK = n, the residual sum-of-squares for !> the solution in the i-th column is given by the sum of !> squares of the modulus of elements n+1:m in that column. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,M,N). !>
[out]	S	!> S is REAL array, dimension (min(M,N)) !> The singular values of A in decreasing order. !> The condition number of A in the 2-norm = S(1)/S(min(m,n)). !>
[in]	RCOND	!> RCOND is REAL !> RCOND is used to determine the effective rank of A. !> Singular values S(i) <= RCOND*S(1) are treated as zero. !> If RCOND < 0, machine precision is used instead. !>
[out]	RANK	!> RANK is INTEGER !> The effective rank of A, i.e., the number of singular values !> which are greater than RCOND*S(1). !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= 1, and also: !> LWORK >= 2*min(M,N) + max(M,N,NRHS) !> For good performance, LWORK should generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	RWORK	!> RWORK is REAL array, dimension (5*min(M,N)) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: the algorithm for computing the SVD failed to converge; !> if INFO = i, i off-diagonal elements of an intermediate !> bidiagonal form did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 174 of file cgelss.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS, RANK
      REAL               RCOND
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * ), S( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            BL, CHUNK, I, IASCL, IBSCL, IE, IL, IRWORK,
     $                   ITAU, ITAUP, ITAUQ, IWORK, LDWORK, MAXMN,
     $                   MAXWRK, MINMN, MINWRK, MM, MNTHR
      INTEGER            LWORK_CGEQRF, LWORK_CUNMQR, LWORK_CGEBRD,
     $                   LWORK_CUNMBR, LWORK_CUNGBR, LWORK_CUNMLQ,
     $                   LWORK_CGELQF
      REAL               ANRM, BIGNUM, BNRM, EPS, SFMIN, SMLNUM, THR
*     ..
*     .. Local Arrays ..
      COMPLEX            DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           cbdsqr, ccopy, cgebrd, cgelqf, cgemm,
     $                   cgemv,
     $                   cgeqrf, clacpy, clascl, claset, csrscl, cungbr,
     $                   cunmbr, cunmlq, cunmqr, slascl, slaset, xerbla
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               CLANGE, SLAMCH, SROUNDUP_LWORK
      EXTERNAL           ilaenv, clange, slamch,
     $                   sroundup_lwork
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      minmn = min( m, n )
      maxmn = max( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, maxmn ) ) THEN
         info = -7
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       CWorkspace refers to complex workspace, and RWorkspace refers
*       to real workspace. NB refers to the optimal block size for the
*       immediately following subroutine, as returned by ILAENV.)
*
      IF( info.EQ.0 ) THEN
         minwrk = 1
         maxwrk = 1
         IF( minmn.GT.0 ) THEN
            mm = m
            mnthr = ilaenv( 6, 'CGELSS', ' ', m, n, nrhs, -1 )
            IF( m.GE.n .AND. m.GE.mnthr ) THEN
*
*              Path 1a - overdetermined, with many more rows than
*                        columns
*
*              Compute space needed for CGEQRF
               CALL cgeqrf( m, n, a, lda, dum(1), dum(1), -1, info )
               lwork_cgeqrf = int( dum(1) )
*              Compute space needed for CUNMQR
               CALL cunmqr( 'L', 'C', m, nrhs, n, a, lda, dum(1), b,
     $                   ldb, dum(1), -1, info )
               lwork_cunmqr = int( dum(1) )
               mm = n
               maxwrk = max( maxwrk, n + n*ilaenv( 1, 'CGEQRF', ' ',
     $                       m,
     $                       n, -1, -1 ) )
               maxwrk = max( maxwrk, n + nrhs*ilaenv( 1, 'CUNMQR',
     $                       'LC',
     $                       m, nrhs, n, -1 ) )
            END IF
            IF( m.GE.n ) THEN
*
*              Path 1 - overdetermined or exactly determined
*
*              Compute space needed for CGEBRD
               CALL cgebrd( mm, n, a, lda, s, s, dum(1), dum(1),
     $                      dum(1),
     $                      -1, info )
               lwork_cgebrd = int( dum(1) )
*              Compute space needed for CUNMBR
               CALL cunmbr( 'Q', 'L', 'C', mm, nrhs, n, a, lda,
     $                      dum(1),
     $                b, ldb, dum(1), -1, info )
               lwork_cunmbr = int( dum(1) )
*              Compute space needed for CUNGBR
               CALL cungbr( 'P', n, n, n, a, lda, dum(1),
     $                   dum(1), -1, info )
               lwork_cungbr = int( dum(1) )
*              Compute total workspace needed
               maxwrk = max( maxwrk, 2*n + lwork_cgebrd )
               maxwrk = max( maxwrk, 2*n + lwork_cunmbr )
               maxwrk = max( maxwrk, 2*n + lwork_cungbr )
               maxwrk = max( maxwrk, n*nrhs )
               minwrk = 2*n + max( nrhs, m )
            END IF
            IF( n.GT.m ) THEN
               minwrk = 2*m + max( nrhs, n )
               IF( n.GE.mnthr ) THEN
*
*                 Path 2a - underdetermined, with many more columns
*                 than rows
*
*                 Compute space needed for CGELQF
                  CALL cgelqf( m, n, a, lda, dum(1), dum(1),
     $                -1, info )
                  lwork_cgelqf = int( dum(1) )
*                 Compute space needed for CGEBRD
                  CALL cgebrd( m, m, a, lda, s, s, dum(1), dum(1),
     $                         dum(1), -1, info )
                  lwork_cgebrd = int( dum(1) )
*                 Compute space needed for CUNMBR
                  CALL cunmbr( 'Q', 'L', 'C', m, nrhs, n, a, lda,
     $                dum(1), b, ldb, dum(1), -1, info )
                  lwork_cunmbr = int( dum(1) )
*                 Compute space needed for CUNGBR
                  CALL cungbr( 'P', m, m, m, a, lda, dum(1),
     $                   dum(1), -1, info )
                  lwork_cungbr = int( dum(1) )
*                 Compute space needed for CUNMLQ
                  CALL cunmlq( 'L', 'C', n, nrhs, m, a, lda, dum(1),
     $                 b, ldb, dum(1), -1, info )
                  lwork_cunmlq = int( dum(1) )
*                 Compute total workspace needed
                  maxwrk = m + lwork_cgelqf
                  maxwrk = max( maxwrk, 3*m + m*m + lwork_cgebrd )
                  maxwrk = max( maxwrk, 3*m + m*m + lwork_cunmbr )
                  maxwrk = max( maxwrk, 3*m + m*m + lwork_cungbr )
                  IF( nrhs.GT.1 ) THEN
                     maxwrk = max( maxwrk, m*m + m + m*nrhs )
                  ELSE
                     maxwrk = max( maxwrk, m*m + 2*m )
                  END IF
                  maxwrk = max( maxwrk, m + lwork_cunmlq )
               ELSE
*
*                 Path 2 - underdetermined
*
*                 Compute space needed for CGEBRD
                  CALL cgebrd( m, n, a, lda, s, s, dum(1), dum(1),
     $                         dum(1), -1, info )
                  lwork_cgebrd = int( dum(1) )
*                 Compute space needed for CUNMBR
                  CALL cunmbr( 'Q', 'L', 'C', m, nrhs, m, a, lda,
     $                dum(1), b, ldb, dum(1), -1, info )
                  lwork_cunmbr = int( dum(1) )
*                 Compute space needed for CUNGBR
                  CALL cungbr( 'P', m, n, m, a, lda, dum(1),
     $                   dum(1), -1, info )
                  lwork_cungbr = int( dum(1) )
                  maxwrk = 2*m + lwork_cgebrd
                  maxwrk = max( maxwrk, 2*m + lwork_cunmbr )
                  maxwrk = max( maxwrk, 2*m + lwork_cungbr )
                  maxwrk = max( maxwrk, n*nrhs )
               END IF
            END IF
            maxwrk = max( minwrk, maxwrk )
         END IF
         work( 1 ) = sroundup_lwork(maxwrk)
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery )
     $      info = -12
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELSS', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 ) THEN
         rank = 0
         RETURN
      END IF
*
*     Get machine parameters
*
      eps = slamch( 'P' )
      sfmin = slamch( 'S' )
      smlnum = sfmin / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         CALL slaset( 'F', minmn, 1, zero, zero, s, minmn )
         rank = 0
         GO TO 70
      END IF
*
*     Scale B if max element outside range [SMLNUM,BIGNUM]
*
      bnrm = clange( 'M', m, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, bnrm, smlnum, m, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, bnrm, bignum, m, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
*     Overdetermined case
*
      IF( m.GE.n ) THEN
*
*        Path 1 - overdetermined or exactly determined
*
         mm = m
         IF( m.GE.mnthr ) THEN
*
*           Path 1a - overdetermined, with many more rows than columns
*
            mm = n
            itau = 1
            iwork = itau + n
*
*           Compute A=Q*R
*           (CWorkspace: need 2*N, prefer N+N*NB)
*           (RWorkspace: none)
*
            CALL cgeqrf( m, n, a, lda, work( itau ), work( iwork ),
     $                   lwork-iwork+1, info )
*
*           Multiply B by transpose(Q)
*           (CWorkspace: need N+NRHS, prefer N+NRHS*NB)
*           (RWorkspace: none)
*
            CALL cunmqr( 'L', 'C', m, nrhs, n, a, lda, work( itau ),
     $                   b,
     $                   ldb, work( iwork ), lwork-iwork+1, info )
*
*           Zero out below R
*
            IF( n.GT.1 )
     $         CALL claset( 'L', n-1, n-1, czero, czero, a( 2, 1 ),
     $                      lda )
         END IF
*
         ie = 1
         itauq = 1
         itaup = itauq + n
         iwork = itaup + n
*
*        Bidiagonalize R in A
*        (CWorkspace: need 2*N+MM, prefer 2*N+(MM+N)*NB)
*        (RWorkspace: need N)
*
         CALL cgebrd( mm, n, a, lda, s, rwork( ie ), work( itauq ),
     $                work( itaup ), work( iwork ), lwork-iwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of R
*        (CWorkspace: need 2*N+NRHS, prefer 2*N+NRHS*NB)
*        (RWorkspace: none)
*
         CALL cunmbr( 'Q', 'L', 'C', mm, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( iwork ), lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors of R in A
*        (CWorkspace: need 3*N-1, prefer 2*N+(N-1)*NB)
*        (RWorkspace: none)
*
         CALL cungbr( 'P', n, n, n, a, lda, work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         irwork = ie + n
*
*        Perform bidiagonal QR iteration
*          multiply B by transpose of left singular vectors
*          compute right singular vectors in A
*        (CWorkspace: none)
*        (RWorkspace: need BDSPAC)
*
         CALL cbdsqr( 'U', n, n, 0, nrhs, s, rwork( ie ), a, lda,
     $                dum,
     $                1, b, ldb, rwork( irwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 10 i = 1, n
            IF( s( i ).GT.thr ) THEN
               CALL csrscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL claset( 'F', 1, nrhs, czero, czero, b( i, 1 ),
     $                      ldb )
            END IF
   10    CONTINUE
*
*        Multiply B by right singular vectors
*        (CWorkspace: need N, prefer N*NRHS)
*        (RWorkspace: none)
*
         IF( lwork.GE.ldb*nrhs .AND. nrhs.GT.1 ) THEN
            CALL cgemm( 'C', 'N', n, nrhs, n, cone, a, lda, b, ldb,
     $                  czero, work, ldb )
            CALL clacpy( 'G', n, nrhs, work, ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = lwork / n
            DO 20 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL cgemm( 'C', 'N', n, bl, n, cone, a, lda, b( 1,
     $                     i ),
     $                     ldb, czero, work, n )
               CALL clacpy( 'G', n, bl, work, n, b( 1, i ), ldb )
   20       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL cgemv( 'C', n, n, cone, a, lda, b, 1, czero, work,
     $                  1 )
            CALL ccopy( n, work, 1, b, 1 )
         END IF
*
      ELSE IF( n.GE.mnthr .AND. lwork.GE.3*m+m*m+max( m, nrhs, n-2*m ) )
     $          THEN
*
*        Underdetermined case, M much less than N
*
*        Path 2a - underdetermined, with many more columns than rows
*        and sufficient workspace for an efficient algorithm
*
         ldwork = m
         IF( lwork.GE.3*m+m*lda+max( m, nrhs, n-2*m ) )
     $      ldwork = lda
         itau = 1
         iwork = m + 1
*
*        Compute A=L*Q
*        (CWorkspace: need 2*M, prefer M+M*NB)
*        (RWorkspace: none)
*
         CALL cgelqf( m, n, a, lda, work( itau ), work( iwork ),
     $                lwork-iwork+1, info )
         il = iwork
*
*        Copy L to WORK(IL), zeroing out above it
*
         CALL clacpy( 'L', m, m, a, lda, work( il ), ldwork )
         CALL claset( 'U', m-1, m-1, czero, czero, work( il+ldwork ),
     $                ldwork )
         ie = 1
         itauq = il + ldwork*m
         itaup = itauq + m
         iwork = itaup + m
*
*        Bidiagonalize L in WORK(IL)
*        (CWorkspace: need M*M+4*M, prefer M*M+3*M+2*M*NB)
*        (RWorkspace: need M)
*
         CALL cgebrd( m, m, work( il ), ldwork, s, rwork( ie ),
     $                work( itauq ), work( itaup ), work( iwork ),
     $                lwork-iwork+1, info )
*
*        Multiply B by transpose of left bidiagonalizing vectors of L
*        (CWorkspace: need M*M+3*M+NRHS, prefer M*M+3*M+NRHS*NB)
*        (RWorkspace: none)
*
         CALL cunmbr( 'Q', 'L', 'C', m, nrhs, m, work( il ), ldwork,
     $                work( itauq ), b, ldb, work( iwork ),
     $                lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors of R in WORK(IL)
*        (CWorkspace: need M*M+4*M-1, prefer M*M+3*M+(M-1)*NB)
*        (RWorkspace: none)
*
         CALL cungbr( 'P', m, m, m, work( il ), ldwork,
     $                work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         irwork = ie + m
*
*        Perform bidiagonal QR iteration, computing right singular
*        vectors of L in WORK(IL) and multiplying B by transpose of
*        left singular vectors
*        (CWorkspace: need M*M)
*        (RWorkspace: need BDSPAC)
*
         CALL cbdsqr( 'U', m, m, 0, nrhs, s, rwork( ie ), work( il ),
     $                ldwork, a, lda, b, ldb, rwork( irwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 30 i = 1, m
            IF( s( i ).GT.thr ) THEN
               CALL csrscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL claset( 'F', 1, nrhs, czero, czero, b( i, 1 ),
     $                      ldb )
            END IF
   30    CONTINUE
         iwork = il + m*ldwork
*
*        Multiply B by right singular vectors of L in WORK(IL)
*        (CWorkspace: need M*M+2*M, prefer M*M+M+M*NRHS)
*        (RWorkspace: none)
*
         IF( lwork.GE.ldb*nrhs+iwork-1 .AND. nrhs.GT.1 ) THEN
            CALL cgemm( 'C', 'N', m, nrhs, m, cone, work( il ),
     $                  ldwork,
     $                  b, ldb, czero, work( iwork ), ldb )
            CALL clacpy( 'G', m, nrhs, work( iwork ), ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = ( lwork-iwork+1 ) / m
            DO 40 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL cgemm( 'C', 'N', m, bl, m, cone, work( il ),
     $                     ldwork,
     $                     b( 1, i ), ldb, czero, work( iwork ), m )
               CALL clacpy( 'G', m, bl, work( iwork ), m, b( 1, i ),
     $                      ldb )
   40       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL cgemv( 'C', m, m, cone, work( il ), ldwork, b( 1,
     $                  1 ), 1, czero, work( iwork ), 1 )
            CALL ccopy( m, work( iwork ), 1, b( 1, 1 ), 1 )
         END IF
*
*        Zero out below first M rows of B
*
         CALL claset( 'F', n-m, nrhs, czero, czero, b( m+1, 1 ),
     $                ldb )
         iwork = itau + m
*
*        Multiply transpose(Q) by B
*        (CWorkspace: need M+NRHS, prefer M+NHRS*NB)
*        (RWorkspace: none)
*
         CALL cunmlq( 'L', 'C', n, nrhs, m, a, lda, work( itau ), b,
     $                ldb, work( iwork ), lwork-iwork+1, info )
*
      ELSE
*
*        Path 2 - remaining underdetermined cases
*
         ie = 1
         itauq = 1
         itaup = itauq + m
         iwork = itaup + m
*
*        Bidiagonalize A
*        (CWorkspace: need 3*M, prefer 2*M+(M+N)*NB)
*        (RWorkspace: need N)
*
         CALL cgebrd( m, n, a, lda, s, rwork( ie ), work( itauq ),
     $                work( itaup ), work( iwork ), lwork-iwork+1,
     $                info )
*
*        Multiply B by transpose of left bidiagonalizing vectors
*        (CWorkspace: need 2*M+NRHS, prefer 2*M+NRHS*NB)
*        (RWorkspace: none)
*
         CALL cunmbr( 'Q', 'L', 'C', m, nrhs, n, a, lda,
     $                work( itauq ),
     $                b, ldb, work( iwork ), lwork-iwork+1, info )
*
*        Generate right bidiagonalizing vectors in A
*        (CWorkspace: need 3*M, prefer 2*M+M*NB)
*        (RWorkspace: none)
*
         CALL cungbr( 'P', m, n, m, a, lda, work( itaup ),
     $                work( iwork ), lwork-iwork+1, info )
         irwork = ie + m
*
*        Perform bidiagonal QR iteration,
*           computing right singular vectors of A in A and
*           multiplying B by transpose of left singular vectors
*        (CWorkspace: none)
*        (RWorkspace: need BDSPAC)
*
         CALL cbdsqr( 'L', m, n, 0, nrhs, s, rwork( ie ), a, lda,
     $                dum,
     $                1, b, ldb, rwork( irwork ), info )
         IF( info.NE.0 )
     $      GO TO 70
*
*        Multiply B by reciprocals of singular values
*
         thr = max( rcond*s( 1 ), sfmin )
         IF( rcond.LT.zero )
     $      thr = max( eps*s( 1 ), sfmin )
         rank = 0
         DO 50 i = 1, m
            IF( s( i ).GT.thr ) THEN
               CALL csrscl( nrhs, s( i ), b( i, 1 ), ldb )
               rank = rank + 1
            ELSE
               CALL claset( 'F', 1, nrhs, czero, czero, b( i, 1 ),
     $                      ldb )
            END IF
   50    CONTINUE
*
*        Multiply B by right singular vectors of A
*        (CWorkspace: need N, prefer N*NRHS)
*        (RWorkspace: none)
*
         IF( lwork.GE.ldb*nrhs .AND. nrhs.GT.1 ) THEN
            CALL cgemm( 'C', 'N', n, nrhs, m, cone, a, lda, b, ldb,
     $                  czero, work, ldb )
            CALL clacpy( 'G', n, nrhs, work, ldb, b, ldb )
         ELSE IF( nrhs.GT.1 ) THEN
            chunk = lwork / n
            DO 60 i = 1, nrhs, chunk
               bl = min( nrhs-i+1, chunk )
               CALL cgemm( 'C', 'N', n, bl, m, cone, a, lda, b( 1,
     $                     i ),
     $                     ldb, czero, work, n )
               CALL clacpy( 'F', n, bl, work, n, b( 1, i ), ldb )
   60       CONTINUE
         ELSE IF( nrhs.EQ.1 ) THEN
            CALL cgemv( 'C', m, n, cone, a, lda, b, 1, czero, work,
     $                  1 )
            CALL ccopy( n, work, 1, b, 1 )
         END IF
      END IF
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, anrm, smlnum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, smlnum, anrm, minmn, 1, s, minmn,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, anrm, bignum, n, nrhs, b, ldb,
     $                info )
         CALL slascl( 'G', 0, 0, bignum, anrm, minmn, 1, s, minmn,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, smlnum, bnrm, n, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, bignum, bnrm, n, nrhs, b, ldb,
     $                info )
      END IF
   70 CONTINUE
      work( 1 ) = sroundup_lwork(maxwrk)
      RETURN
*
*     End of CGELSS
*

Here is the call graph for this function:

Here is the caller graph for this function: