LAPACK 3.12.0 LAPACK: Linear Algebra PACKage
Searching...
No Matches
cungbr.f
Go to the documentation of this file.
1*> \brief \b CUNGBR
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cungbr.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cungbr.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cungbr.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE CUNGBR( VECT, M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
22*
23* .. Scalar Arguments ..
24* CHARACTER VECT
25* INTEGER INFO, K, LDA, LWORK, M, N
26* ..
27* .. Array Arguments ..
28* COMPLEX A( LDA, * ), TAU( * ), WORK( * )
29* ..
30*
31*
32*> \par Purpose:
33* =============
34*>
35*> \verbatim
36*>
37*> CUNGBR generates one of the complex unitary matrices Q or P**H
38*> determined by CGEBRD when reducing a complex matrix A to bidiagonal
39*> form: A = Q * B * P**H. Q and P**H are defined as products of
40*> elementary reflectors H(i) or G(i) respectively.
41*>
42*> If VECT = 'Q', A is assumed to have been an M-by-K matrix, and Q
43*> is of order M:
44*> if m >= k, Q = H(1) H(2) . . . H(k) and CUNGBR returns the first n
45*> columns of Q, where m >= n >= k;
46*> if m < k, Q = H(1) H(2) . . . H(m-1) and CUNGBR returns Q as an
47*> M-by-M matrix.
48*>
49*> If VECT = 'P', A is assumed to have been a K-by-N matrix, and P**H
50*> is of order N:
51*> if k < n, P**H = G(k) . . . G(2) G(1) and CUNGBR returns the first m
52*> rows of P**H, where n >= m >= k;
53*> if k >= n, P**H = G(n-1) . . . G(2) G(1) and CUNGBR returns P**H as
54*> an N-by-N matrix.
55*> \endverbatim
56*
57* Arguments:
58* ==========
59*
60*> \param[in] VECT
61*> \verbatim
62*> VECT is CHARACTER*1
63*> Specifies whether the matrix Q or the matrix P**H is
64*> required, as defined in the transformation applied by CGEBRD:
65*> = 'Q': generate Q;
66*> = 'P': generate P**H.
67*> \endverbatim
68*>
69*> \param[in] M
70*> \verbatim
71*> M is INTEGER
72*> The number of rows of the matrix Q or P**H to be returned.
73*> M >= 0.
74*> \endverbatim
75*>
76*> \param[in] N
77*> \verbatim
78*> N is INTEGER
79*> The number of columns of the matrix Q or P**H to be returned.
80*> N >= 0.
81*> If VECT = 'Q', M >= N >= min(M,K);
82*> if VECT = 'P', N >= M >= min(N,K).
83*> \endverbatim
84*>
85*> \param[in] K
86*> \verbatim
87*> K is INTEGER
88*> If VECT = 'Q', the number of columns in the original M-by-K
89*> matrix reduced by CGEBRD.
90*> If VECT = 'P', the number of rows in the original K-by-N
91*> matrix reduced by CGEBRD.
92*> K >= 0.
93*> \endverbatim
94*>
95*> \param[in,out] A
96*> \verbatim
97*> A is COMPLEX array, dimension (LDA,N)
98*> On entry, the vectors which define the elementary reflectors,
99*> as returned by CGEBRD.
100*> On exit, the M-by-N matrix Q or P**H.
101*> \endverbatim
102*>
103*> \param[in] LDA
104*> \verbatim
105*> LDA is INTEGER
106*> The leading dimension of the array A. LDA >= M.
107*> \endverbatim
108*>
109*> \param[in] TAU
110*> \verbatim
111*> TAU is COMPLEX array, dimension
112*> (min(M,K)) if VECT = 'Q'
113*> (min(N,K)) if VECT = 'P'
114*> TAU(i) must contain the scalar factor of the elementary
115*> reflector H(i) or G(i), which determines Q or P**H, as
116*> returned by CGEBRD in its array argument TAUQ or TAUP.
117*> \endverbatim
118*>
119*> \param[out] WORK
120*> \verbatim
121*> WORK is COMPLEX array, dimension (MAX(1,LWORK))
122*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
123*> \endverbatim
124*>
125*> \param[in] LWORK
126*> \verbatim
127*> LWORK is INTEGER
128*> The dimension of the array WORK. LWORK >= max(1,min(M,N)).
129*> For optimum performance LWORK >= min(M,N)*NB, where NB
130*> is the optimal blocksize.
131*>
132*> If LWORK = -1, then a workspace query is assumed; the routine
133*> only calculates the optimal size of the WORK array, returns
134*> this value as the first entry of the WORK array, and no error
135*> message related to LWORK is issued by XERBLA.
136*> \endverbatim
137*>
138*> \param[out] INFO
139*> \verbatim
140*> INFO is INTEGER
141*> = 0: successful exit
142*> < 0: if INFO = -i, the i-th argument had an illegal value
143*> \endverbatim
144*
145* Authors:
146* ========
147*
148*> \author Univ. of Tennessee
149*> \author Univ. of California Berkeley
150*> \author Univ. of Colorado Denver
151*> \author NAG Ltd.
152*
153*> \ingroup ungbr
154*
155* =====================================================================
156 SUBROUTINE cungbr( VECT, M, N, K, A, LDA, TAU, WORK, LWORK, INFO )
157*
158* -- LAPACK computational routine --
159* -- LAPACK is a software package provided by Univ. of Tennessee, --
160* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
161*
162* .. Scalar Arguments ..
163 CHARACTER VECT
164 INTEGER INFO, K, LDA, LWORK, M, N
165* ..
166* .. Array Arguments ..
167 COMPLEX A( LDA, * ), TAU( * ), WORK( * )
168* ..
169*
170* =====================================================================
171*
172* .. Parameters ..
173 COMPLEX ZERO, ONE
174 parameter( zero = ( 0.0e+0, 0.0e+0 ),
175 \$ one = ( 1.0e+0, 0.0e+0 ) )
176* ..
177* .. Local Scalars ..
178 LOGICAL LQUERY, WANTQ
179 INTEGER I, IINFO, J, LWKOPT, MN
180* ..
181* .. External Functions ..
182 LOGICAL LSAME
183 REAL SROUNDUP_LWORK
184 EXTERNAL lsame, sroundup_lwork
185* ..
186* .. External Subroutines ..
187 EXTERNAL cunglq, cungqr, xerbla
188* ..
189* .. Intrinsic Functions ..
190 INTRINSIC max, min
191* ..
192* .. Executable Statements ..
193*
194* Test the input arguments
195*
196 info = 0
197 wantq = lsame( vect, 'Q' )
198 mn = min( m, n )
199 lquery = ( lwork.EQ.-1 )
200 IF( .NOT.wantq .AND. .NOT.lsame( vect, 'P' ) ) THEN
201 info = -1
202 ELSE IF( m.LT.0 ) THEN
203 info = -2
204 ELSE IF( n.LT.0 .OR. ( wantq .AND. ( n.GT.m .OR. n.LT.min( m,
205 \$ k ) ) ) .OR. ( .NOT.wantq .AND. ( m.GT.n .OR. m.LT.
206 \$ min( n, k ) ) ) ) THEN
207 info = -3
208 ELSE IF( k.LT.0 ) THEN
209 info = -4
210 ELSE IF( lda.LT.max( 1, m ) ) THEN
211 info = -6
212 ELSE IF( lwork.LT.max( 1, mn ) .AND. .NOT.lquery ) THEN
213 info = -9
214 END IF
215*
216 IF( info.EQ.0 ) THEN
217 work( 1 ) = 1
218 IF( wantq ) THEN
219 IF( m.GE.k ) THEN
220 CALL cungqr( m, n, k, a, lda, tau, work, -1, iinfo )
221 ELSE
222 IF( m.GT.1 ) THEN
223 CALL cungqr( m-1, m-1, m-1, a, lda, tau, work, -1,
224 \$ iinfo )
225 END IF
226 END IF
227 ELSE
228 IF( k.LT.n ) THEN
229 CALL cunglq( m, n, k, a, lda, tau, work, -1, iinfo )
230 ELSE
231 IF( n.GT.1 ) THEN
232 CALL cunglq( n-1, n-1, n-1, a, lda, tau, work, -1,
233 \$ iinfo )
234 END IF
235 END IF
236 END IF
237 lwkopt = int( work( 1 ) )
238 lwkopt = max(lwkopt, mn)
239 END IF
240*
241 IF( info.NE.0 ) THEN
242 CALL xerbla( 'CUNGBR', -info )
243 RETURN
244 ELSE IF( lquery ) THEN
245 work( 1 ) = sroundup_lwork(lwkopt)
246 RETURN
247 END IF
248*
249* Quick return if possible
250*
251 IF( m.EQ.0 .OR. n.EQ.0 ) THEN
252 work( 1 ) = 1
253 RETURN
254 END IF
255*
256 IF( wantq ) THEN
257*
258* Form Q, determined by a call to CGEBRD to reduce an m-by-k
259* matrix
260*
261 IF( m.GE.k ) THEN
262*
263* If m >= k, assume m >= n >= k
264*
265 CALL cungqr( m, n, k, a, lda, tau, work, lwork, iinfo )
266*
267 ELSE
268*
269* If m < k, assume m = n
270*
271* Shift the vectors which define the elementary reflectors one
272* column to the right, and set the first row and column of Q
273* to those of the unit matrix
274*
275 DO 20 j = m, 2, -1
276 a( 1, j ) = zero
277 DO 10 i = j + 1, m
278 a( i, j ) = a( i, j-1 )
279 10 CONTINUE
280 20 CONTINUE
281 a( 1, 1 ) = one
282 DO 30 i = 2, m
283 a( i, 1 ) = zero
284 30 CONTINUE
285 IF( m.GT.1 ) THEN
286*
287* Form Q(2:m,2:m)
288*
289 CALL cungqr( m-1, m-1, m-1, a( 2, 2 ), lda, tau, work,
290 \$ lwork, iinfo )
291 END IF
292 END IF
293 ELSE
294*
295* Form P**H, determined by a call to CGEBRD to reduce a k-by-n
296* matrix
297*
298 IF( k.LT.n ) THEN
299*
300* If k < n, assume k <= m <= n
301*
302 CALL cunglq( m, n, k, a, lda, tau, work, lwork, iinfo )
303*
304 ELSE
305*
306* If k >= n, assume m = n
307*
308* Shift the vectors which define the elementary reflectors one
309* row downward, and set the first row and column of P**H to
310* those of the unit matrix
311*
312 a( 1, 1 ) = one
313 DO 40 i = 2, n
314 a( i, 1 ) = zero
315 40 CONTINUE
316 DO 60 j = 2, n
317 DO 50 i = j - 1, 2, -1
318 a( i, j ) = a( i-1, j )
319 50 CONTINUE
320 a( 1, j ) = zero
321 60 CONTINUE
322 IF( n.GT.1 ) THEN
323*
324* Form P**H(2:n,2:n)
325*
326 CALL cunglq( n-1, n-1, n-1, a( 2, 2 ), lda, tau, work,
327 \$ lwork, iinfo )
328 END IF
329 END IF
330 END IF
331 work( 1 ) = sroundup_lwork(lwkopt)
332 RETURN
333*
334* End of CUNGBR
335*
336 END
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine cungbr(vect, m, n, k, a, lda, tau, work, lwork, info)
CUNGBR
Definition cungbr.f:157
subroutine cunglq(m, n, k, a, lda, tau, work, lwork, info)
CUNGLQ
Definition cunglq.f:127
subroutine cungqr(m, n, k, a, lda, tau, work, lwork, info)
CUNGQR
Definition cungqr.f:128