zla_syamv.f

Go to the documentation of this file.

*> \brief \b ZLA_SYAMV computes a matrix-vector product using a symmetric indefinite matrix to calculate error bounds.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download ZLA_SYAMV + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zla_syamv.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zla_syamv.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zla_syamv.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZLA_SYAMV( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
*                             INCY )
*
*       .. Scalar Arguments ..
*       DOUBLE PRECISION   ALPHA, BETA
*       INTEGER            INCX, INCY, LDA, N
*       INTEGER            UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX*16         A( LDA, * ), X( * )
*       DOUBLE PRECISION   Y( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZLA_SYAMV  performs the matrix-vector operation
*>
*>         y := alpha*abs(A)*abs(x) + beta*abs(y),
*>
*> where alpha and beta are scalars, x and y are vectors and A is an
*> n by n symmetric matrix.
*>
*> This function is primarily used in calculating error bounds.
*> To protect against underflow during evaluation, components in
*> the resulting vector are perturbed away from zero by (N+1)
*> times the underflow threshold.  To prevent unnecessarily large
*> errors for block-structure embedded in general matrices,
*> "symbolically" zero components are not perturbed.  A zero
*> entry is considered "symbolic" if all multiplications involved
*> in computing that entry have at least one zero multiplicand.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is INTEGER
*>           On entry, UPLO specifies whether the upper or lower
*>           triangular part of the array A is to be referenced as
*>           follows:
*>
*>              UPLO = BLAS_UPPER   Only the upper triangular part of A
*>                                  is to be referenced.
*>
*>              UPLO = BLAS_LOWER   Only the lower triangular part of A
*>                                  is to be referenced.
*>
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           On entry, N specifies the number of columns of the matrix A.
*>           N must be at least zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] ALPHA
*> \verbatim
*>          ALPHA is DOUBLE PRECISION .
*>           On entry, ALPHA specifies the scalar alpha.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension ( LDA, n ).
*>           Before entry, the leading m by n part of the array A must
*>           contain the matrix of coefficients.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>           On entry, LDA specifies the first dimension of A as declared
*>           in the calling (sub) program. LDA must be at least
*>           max( 1, n ).
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension at least
*>           ( 1 + ( n - 1 )*abs( INCX ) )
*>           Before entry, the incremented array X must contain the
*>           vector x.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] INCX
*> \verbatim
*>          INCX is INTEGER
*>           On entry, INCX specifies the increment for the elements of
*>           X. INCX must not be zero.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in] BETA
*> \verbatim
*>          BETA is DOUBLE PRECISION .
*>           On entry, BETA specifies the scalar beta. When BETA is
*>           supplied as zero then Y need not be set on input.
*>           Unchanged on exit.
*> \endverbatim
*>
*> \param[in,out] Y
*> \verbatim
*>          Y is DOUBLE PRECISION array, dimension
*>           ( 1 + ( n - 1 )*abs( INCY ) )
*>           Before entry with BETA non-zero, the incremented array Y
*>           must contain the vector y. On exit, Y is overwritten by the
*>           updated vector y.
*> \endverbatim
*>
*> \param[in] INCY
*> \verbatim
*>          INCY is INTEGER
*>           On entry, INCY specifies the increment for the elements of
*>           Y. INCY must not be zero.
*>           Unchanged on exit.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup la_heamv
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  Level 2 Blas routine.
*>
*>  -- Written on 22-October-1986.
*>     Jack Dongarra, Argonne National Lab.
*>     Jeremy Du Croz, Nag Central Office.
*>     Sven Hammarling, Nag Central Office.
*>     Richard Hanson, Sandia National Labs.
*>  -- Modified for the absolute-value product, April 2006
*>     Jason Riedy, UC Berkeley
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE zla_syamv( UPLO, N, ALPHA, A, LDA, X, INCX, BETA, Y,
     $                      INCY )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      DOUBLE PRECISION   ALPHA, BETA
      INTEGER            INCX, INCY, LDA, N
      INTEGER            UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), X( * )
      DOUBLE PRECISION   Y( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            SYMB_ZERO
      DOUBLE PRECISION   TEMP, SAFE1
      INTEGER            I, INFO, IY, J, JX, KX, KY
      COMPLEX*16         ZDUM
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, dlamch
      DOUBLE PRECISION   DLAMCH
*     ..
*     .. External Functions ..
      EXTERNAL           ilauplo
      INTEGER            ILAUPLO
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, abs, sign, real, dimag
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF     ( uplo.NE.ilauplo( 'U' ) .AND.
     $         uplo.NE.ilauplo( 'L' ) )THEN
         info = 1
      ELSE IF( n.LT.0 )THEN
         info = 2
      ELSE IF( lda.LT.max( 1, n ) )THEN
         info = 5
      ELSE IF( incx.EQ.0 )THEN
         info = 7
      ELSE IF( incy.EQ.0 )THEN
         info = 10
      END IF
      IF( info.NE.0 )THEN
         CALL xerbla( 'ZLA_SYAMV', info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( ( n.EQ.0 ).OR.( ( alpha.EQ.zero ).AND.( beta.EQ.one ) ) )
     $   RETURN
*
*     Set up the start points in  X  and  Y.
*
      IF( incx.GT.0 )THEN
         kx = 1
      ELSE
         kx = 1 - ( n - 1 )*incx
      END IF
      IF( incy.GT.0 )THEN
         ky = 1
      ELSE
         ky = 1 - ( n - 1 )*incy
      END IF
*
*     Set SAFE1 essentially to be the underflow threshold times the
*     number of additions in each row.
*
      safe1 = dlamch( 'Safe minimum' )
      safe1 = (n+1)*safe1
*
*     Form  y := alpha*abs(A)*abs(x) + beta*abs(y).
*
*     The O(N^2) SYMB_ZERO tests could be replaced by O(N) queries to
*     the inexact flag.  Still doesn't help change the iteration order
*     to per-column.
*
      iy = ky
      IF ( incx.EQ.1 ) THEN
         IF ( uplo .EQ. ilauplo( 'U' ) ) THEN
            DO i = 1, n
               IF ( beta .EQ. zero ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. zero ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. zero ) THEN
                  DO j = 1, i
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
                  DO j = i+1, n
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
               END IF
 
               IF ( .NOT.symb_zero )
     $              y( iy ) = y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         ELSE
            DO i = 1, n
               IF ( beta .EQ. zero ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. zero ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               IF ( alpha .NE. zero ) THEN
                  DO j = 1, i
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
                  DO j = i+1, n
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( j ) )*temp
                  END DO
               END IF
 
               IF ( .NOT.symb_zero )
     $              y( iy ) = y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         END IF
      ELSE
         IF ( uplo .EQ. ilauplo( 'U' ) ) THEN
            DO i = 1, n
               IF ( beta .EQ. zero ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. zero ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               jx = kx
               IF ( alpha .NE. zero ) THEN
                  DO j = 1, i
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
                  DO j = i+1, n
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
               END IF
 
               IF ( .NOT.symb_zero )
     $              y( iy ) = y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         ELSE
            DO i = 1, n
               IF ( beta .EQ. zero ) THEN
                  symb_zero = .true.
                  y( iy ) = 0.0d+0
               ELSE IF ( y( iy ) .EQ. zero ) THEN
                  symb_zero = .true.
               ELSE
                  symb_zero = .false.
                  y( iy ) = beta * abs( y( iy ) )
               END IF
               jx = kx
               IF ( alpha .NE. zero ) THEN
                  DO j = 1, i
                     temp = cabs1( a( i, j ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
                  DO j = i+1, n
                     temp = cabs1( a( j, i ) )
                     symb_zero = symb_zero .AND.
     $                    ( x( j ) .EQ. zero .OR. temp .EQ. zero )
 
                     y( iy ) = y( iy ) + alpha*cabs1( x( jx ) )*temp
                     jx = jx + incx
                  END DO
               END IF
 
               IF ( .NOT.symb_zero )
     $              y( iy ) = y( iy ) + sign( safe1, y( iy ) )
 
               iy = iy + incy
            END DO
         END IF
 
      END IF
*
      RETURN
*
*     End of ZLA_SYAMV
*
      END