LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
sgeequb.f
Go to the documentation of this file.
1 *> \brief \b SGEEQUB
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download SGEEQUB + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sgeequb.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sgeequb.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sgeequb.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE SGEEQUB( M, N, A, LDA, R, C, ROWCND, COLCND, AMAX,
22 * INFO )
23 *
24 * .. Scalar Arguments ..
25 * INTEGER INFO, LDA, M, N
26 * REAL AMAX, COLCND, ROWCND
27 * ..
28 * .. Array Arguments ..
29 * REAL A( LDA, * ), C( * ), R( * )
30 * ..
31 *
32 *
33 *> \par Purpose:
34 * =============
35 *>
36 *> \verbatim
37 *>
38 *> SGEEQUB computes row and column scalings intended to equilibrate an
39 *> M-by-N matrix A and reduce its condition number. R returns the row
40 *> scale factors and C the column scale factors, chosen to try to make
41 *> the largest element in each row and column of the matrix B with
42 *> elements B(i,j)=R(i)*A(i,j)*C(j) have an absolute value of at most
43 *> the radix.
44 *>
45 *> R(i) and C(j) are restricted to be a power of the radix between
46 *> SMLNUM = smallest safe number and BIGNUM = largest safe number. Use
47 *> of these scaling factors is not guaranteed to reduce the condition
48 *> number of A but works well in practice.
49 *>
50 *> This routine differs from SGEEQU by restricting the scaling factors
51 *> to a power of the radix. Barring over- and underflow, scaling by
52 *> these factors introduces no additional rounding errors. However, the
53 *> scaled entries' magnitudes are no longer approximately 1 but lie
54 *> between sqrt(radix) and 1/sqrt(radix).
55 *> \endverbatim
56 *
57 * Arguments:
58 * ==========
59 *
60 *> \param[in] M
61 *> \verbatim
62 *> M is INTEGER
63 *> The number of rows of the matrix A. M >= 0.
64 *> \endverbatim
65 *>
66 *> \param[in] N
67 *> \verbatim
68 *> N is INTEGER
69 *> The number of columns of the matrix A. N >= 0.
70 *> \endverbatim
71 *>
72 *> \param[in] A
73 *> \verbatim
74 *> A is REAL array, dimension (LDA,N)
75 *> The M-by-N matrix whose equilibration factors are
76 *> to be computed.
77 *> \endverbatim
78 *>
79 *> \param[in] LDA
80 *> \verbatim
81 *> LDA is INTEGER
82 *> The leading dimension of the array A. LDA >= max(1,M).
83 *> \endverbatim
84 *>
85 *> \param[out] R
86 *> \verbatim
87 *> R is REAL array, dimension (M)
88 *> If INFO = 0 or INFO > M, R contains the row scale factors
89 *> for A.
90 *> \endverbatim
91 *>
92 *> \param[out] C
93 *> \verbatim
94 *> C is REAL array, dimension (N)
95 *> If INFO = 0, C contains the column scale factors for A.
96 *> \endverbatim
97 *>
98 *> \param[out] ROWCND
99 *> \verbatim
100 *> ROWCND is REAL
101 *> If INFO = 0 or INFO > M, ROWCND contains the ratio of the
102 *> smallest R(i) to the largest R(i). If ROWCND >= 0.1 and
103 *> AMAX is neither too large nor too small, it is not worth
104 *> scaling by R.
105 *> \endverbatim
106 *>
107 *> \param[out] COLCND
108 *> \verbatim
109 *> COLCND is REAL
110 *> If INFO = 0, COLCND contains the ratio of the smallest
111 *> C(i) to the largest C(i). If COLCND >= 0.1, it is not
112 *> worth scaling by C.
113 *> \endverbatim
114 *>
115 *> \param[out] AMAX
116 *> \verbatim
117 *> AMAX is REAL
118 *> Absolute value of largest matrix element. If AMAX is very
119 *> close to overflow or very close to underflow, the matrix
120 *> should be scaled.
121 *> \endverbatim
122 *>
123 *> \param[out] INFO
124 *> \verbatim
125 *> INFO is INTEGER
126 *> = 0: successful exit
127 *> < 0: if INFO = -i, the i-th argument had an illegal value
128 *> > 0: if INFO = i, and i is
129 *> <= M: the i-th row of A is exactly zero
130 *> > M: the (i-M)-th column of A is exactly zero
131 *> \endverbatim
132 *
133 * Authors:
134 * ========
135 *
136 *> \author Univ. of Tennessee
137 *> \author Univ. of California Berkeley
138 *> \author Univ. of Colorado Denver
139 *> \author NAG Ltd.
140 *
141 *> \ingroup realGEcomputational
142 *
143 * =====================================================================
144  SUBROUTINE sgeequb( M, N, A, LDA, R, C, ROWCND, COLCND, AMAX,
145  $ INFO )
146 *
147 * -- LAPACK computational routine --
148 * -- LAPACK is a software package provided by Univ. of Tennessee, --
149 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
150 *
151 * .. Scalar Arguments ..
152  INTEGER INFO, LDA, M, N
153  REAL AMAX, COLCND, ROWCND
154 * ..
155 * .. Array Arguments ..
156  REAL A( LDA, * ), C( * ), R( * )
157 * ..
158 *
159 * =====================================================================
160 *
161 * .. Parameters ..
162  REAL ONE, ZERO
163  parameter( one = 1.0e+0, zero = 0.0e+0 )
164 * ..
165 * .. Local Scalars ..
166  INTEGER I, J
167  REAL BIGNUM, RCMAX, RCMIN, SMLNUM, RADIX, LOGRDX
168 * ..
169 * .. External Functions ..
170  REAL SLAMCH
171  EXTERNAL slamch
172 * ..
173 * .. External Subroutines ..
174  EXTERNAL xerbla
175 * ..
176 * .. Intrinsic Functions ..
177  INTRINSIC abs, max, min, log
178 * ..
179 * .. Executable Statements ..
180 *
181 * Test the input parameters.
182 *
183  info = 0
184  IF( m.LT.0 ) THEN
185  info = -1
186  ELSE IF( n.LT.0 ) THEN
187  info = -2
188  ELSE IF( lda.LT.max( 1, m ) ) THEN
189  info = -4
190  END IF
191  IF( info.NE.0 ) THEN
192  CALL xerbla( 'SGEEQUB', -info )
193  RETURN
194  END IF
195 *
196 * Quick return if possible.
197 *
198  IF( m.EQ.0 .OR. n.EQ.0 ) THEN
199  rowcnd = one
200  colcnd = one
201  amax = zero
202  RETURN
203  END IF
204 *
205 * Get machine constants. Assume SMLNUM is a power of the radix.
206 *
207  smlnum = slamch( 'S' )
208  bignum = one / smlnum
209  radix = slamch( 'B' )
210  logrdx = log( radix )
211 *
212 * Compute row scale factors.
213 *
214  DO 10 i = 1, m
215  r( i ) = zero
216  10 CONTINUE
217 *
218 * Find the maximum element in each row.
219 *
220  DO 30 j = 1, n
221  DO 20 i = 1, m
222  r( i ) = max( r( i ), abs( a( i, j ) ) )
223  20 CONTINUE
224  30 CONTINUE
225  DO i = 1, m
226  IF( r( i ).GT.zero ) THEN
227  r( i ) = radix**int( log( r( i ) ) / logrdx )
228  END IF
229  END DO
230 *
231 * Find the maximum and minimum scale factors.
232 *
233  rcmin = bignum
234  rcmax = zero
235  DO 40 i = 1, m
236  rcmax = max( rcmax, r( i ) )
237  rcmin = min( rcmin, r( i ) )
238  40 CONTINUE
239  amax = rcmax
240 *
241  IF( rcmin.EQ.zero ) THEN
242 *
243 * Find the first zero scale factor and return an error code.
244 *
245  DO 50 i = 1, m
246  IF( r( i ).EQ.zero ) THEN
247  info = i
248  RETURN
249  END IF
250  50 CONTINUE
251  ELSE
252 *
253 * Invert the scale factors.
254 *
255  DO 60 i = 1, m
256  r( i ) = one / min( max( r( i ), smlnum ), bignum )
257  60 CONTINUE
258 *
259 * Compute ROWCND = min(R(I)) / max(R(I)).
260 *
261  rowcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
262  END IF
263 *
264 * Compute column scale factors
265 *
266  DO 70 j = 1, n
267  c( j ) = zero
268  70 CONTINUE
269 *
270 * Find the maximum element in each column,
271 * assuming the row scaling computed above.
272 *
273  DO 90 j = 1, n
274  DO 80 i = 1, m
275  c( j ) = max( c( j ), abs( a( i, j ) )*r( i ) )
276  80 CONTINUE
277  IF( c( j ).GT.zero ) THEN
278  c( j ) = radix**int( log( c( j ) ) / logrdx )
279  END IF
280  90 CONTINUE
281 *
282 * Find the maximum and minimum scale factors.
283 *
284  rcmin = bignum
285  rcmax = zero
286  DO 100 j = 1, n
287  rcmin = min( rcmin, c( j ) )
288  rcmax = max( rcmax, c( j ) )
289  100 CONTINUE
290 *
291  IF( rcmin.EQ.zero ) THEN
292 *
293 * Find the first zero scale factor and return an error code.
294 *
295  DO 110 j = 1, n
296  IF( c( j ).EQ.zero ) THEN
297  info = m + j
298  RETURN
299  END IF
300  110 CONTINUE
301  ELSE
302 *
303 * Invert the scale factors.
304 *
305  DO 120 j = 1, n
306  c( j ) = one / min( max( c( j ), smlnum ), bignum )
307  120 CONTINUE
308 *
309 * Compute COLCND = min(C(J)) / max(C(J)).
310 *
311  colcnd = max( rcmin, smlnum ) / min( rcmax, bignum )
312  END IF
313 *
314  RETURN
315 *
316 * End of SGEEQUB
317 *
318  END
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine sgeequb(M, N, A, LDA, R, C, ROWCND, COLCND, AMAX, INFO)
SGEEQUB
Definition: sgeequb.f:146