dlqt05()

subroutine dlqt05	(	integer	m,
		integer	n,
		integer	l,
		integer	nb,
		double precision, dimension(6)	result
	)

DLQT05

Purpose:

 DQRT05 tests DTPLQT and DTPMLQT.

Parameters

[in]	M	M is INTEGER Number of rows in lower part of the test matrix.
[in]	N	N is INTEGER Number of columns in test matrix.
[in]	L	L is INTEGER The number of rows of the upper trapezoidal part the lower test matrix. 0 <= L <= M.
[in]	NB	NB is INTEGER Block size of test matrix. NB <= N.
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (6) Results of each of the six tests below. RESULT(1) = | A - Q R | RESULT(2) = | I - Q^H Q | RESULT(3) = | Q C - Q C | RESULT(4) = | Q^H C - Q^H C | RESULT(5) = | C Q - C Q | RESULT(6) = | C Q^H - C Q^H |

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 79 of file dlqt05.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER LWORK, M, N, L, NB, LDT
*     .. Return values ..
      DOUBLE PRECISION RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      DOUBLE PRECISION, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), RWORK(:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
*
*     .. Parameters ..
      DOUBLE PRECISION ONE, ZERO
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, N2, NP1,i
      DOUBLE PRECISION   ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
      LOGICAL  LSAME
      EXTERNAL dlamch, dlange, dlansy, lsame
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = dlamch( 'Epsilon' )
      k = m
      n2 = m+n
      IF( n.GT.0 ) THEN
         np1 = m+1
      ELSE
         np1 = 1
      END IF
      lwork = n2*n2*nb
*
*     Dynamically allocate all arrays
*
      ALLOCATE(a(m,n2),af(m,n2),q(n2,n2),r(n2,n2),rwork(n2),
     $           work(lwork),t(nb,m),c(n2,m),cf(n2,m),
     $           d(m,n2),df(m,n2) )
*
*     Put random stuff into A
*
      ldt=nb
      CALL dlaset( 'Full', m, n2, zero, zero, a, m )
      CALL dlaset( 'Full', nb, m, zero, zero, t, nb )
      DO j=1,m
         CALL dlarnv( 2, iseed, m-j+1, a( j, j ) )
      END DO
      IF( n.GT.0 ) THEN
         DO j=1,n-l
            CALL dlarnv( 2, iseed, m, a( 1, min(n+m,m+1) + j - 1 ) )
         END DO
      END IF
      IF( l.GT.0 ) THEN
         DO j=1,l
            CALL dlarnv( 2, iseed, m-j+1, a( j, min(n+m,n+m-l+1)
     $          + j - 1 ) )
         END DO
      END IF
*
*     Copy the matrix A to the array AF.
*
      CALL dlacpy( 'Full', m, n2, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL dtplqt( m,n,l,nb,af,m,af(1,np1),m,t,ldt,work,info)
*
*     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
*
      CALL dlaset( 'Full', n2, n2, zero, one, q, n2 )
      CALL dgemlqt( 'L', 'N', n2, n2, k, nb, af, m, t, ldt, q, n2,
     $              work, info )
*
*     Copy L
*
      CALL dlaset( 'Full', n2, n2, zero, zero, r, n2 )
      CALL dlacpy( 'Lower', m, n2, af, m, r, n2 )
*
*     Compute |L - A*Q*T| / |A| and store in RESULT(1)
*
      CALL dgemm( 'N', 'T', m, n2, n2, -one,  a, m, q, n2, one, r, n2)
      anorm = dlange( '1', m, n2, a, m, rwork )
      resid = dlange( '1', m, n2, r, n2, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*anorm*max(1,n2))
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q*Q'| and store in RESULT(2)
*
      CALL dlaset( 'Full', n2, n2, zero, one, r, n2 )
      CALL dsyrk( 'U', 'N', n2, n2, -one, q, n2, one, r, n2 )
      resid = dlansy( '1', 'Upper', n2, r, n2, rwork )
      result( 2 ) = resid / (eps*max(1,n2))
*
*     Generate random m-by-n matrix C and a copy CF
*
      CALL dlaset( 'Full', n2, m, zero, one, c, n2 )
      DO j=1,m
         CALL dlarnv( 2, iseed, n2, c( 1, j ) )
      END DO
      cnorm = dlange( '1', n2, m, c, n2, rwork)
      CALL dlacpy( 'Full', n2, m, c, n2, cf, n2 )
*
*     Apply Q to C as Q*C
*
      CALL dtpmlqt( 'L','N', n,m,k,l,nb,af(1, np1),m,t,ldt,cf,n2,
     $               cf(np1,1),n2,work,info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL dgemm( 'N', 'N', n2, m, n2, -one, q, n2, c, n2, one, cf, n2 )
      resid = dlange( '1', n2, m, cf, n2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,n2)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
 
*
*     Copy C into CF again
*
      CALL dlacpy( 'Full', n2, m, c, n2, cf, n2 )
*
*     Apply Q to C as QT*C
*
      CALL dtpmlqt( 'L','T',n,m,k,l,nb,af(1,np1),m,t,ldt,cf,n2,
     $              cf(np1,1),n2,work,info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL dgemm('T','N',n2,m,n2,-one,q,n2,c,n2,one,cf,n2)
      resid = dlange( '1', n2, m, cf, n2, rwork )
 
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,n2)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random m-by-n matrix D and a copy DF
*
      DO j=1,n2
         CALL dlarnv( 2, iseed, m, d( 1, j ) )
      END DO
      dnorm = dlange( '1', m, n2, d, m, rwork)
      CALL dlacpy( 'Full', m, n2, d, m, df, m )
*
*     Apply Q to D as D*Q
*
      CALL dtpmlqt('R','N',m,n,k,l,nb,af(1,np1),m,t,ldt,df,m,
     $             df(1,np1),m,work,info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL dgemm('N','N',m,n2,n2,-one,d,m,q,n2,one,df,m)
      resid = dlange('1',m, n2,df,m,rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,n2)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL dlacpy('Full',m,n2,d,m,df,m )
*
*     Apply Q to D as D*QT
*
      CALL dtpmlqt('R','T',m,n,k,l,nb,af(1,np1),m,t,ldt,df,m,
     $             df(1,np1),m,work,info)
 
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL dgemm( 'N', 'T', m, n2, n2, -one, d, m, q, n2, one, df, m )
      resid = dlange( '1', m, n2, df, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,n2)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
      RETURN

Here is the call graph for this function:

Here is the caller graph for this function: