dgemlqt()

subroutine dgemlqt	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		integer	mb,
		double precision, dimension( ldv, * )	v,
		integer	ldv,
		double precision, dimension( ldt, * )	t,
		integer	ldt,
		double precision, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( * )	work,
		integer	info
	)

DGEMLQT

Download DGEMLQT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DGEMLQT overwrites the general real M-by-N matrix C with

                 SIDE = 'L'     SIDE = 'R'
 TRANS = 'N':      Q C            C Q
 TRANS = 'T':   Q**T C            C Q**T

 where Q is a real orthogonal matrix defined as the product of K
 elementary reflectors:

       Q = H(1) H(2) . . . H(K) = I - V T V**T

 generated using the compact WY representation as returned by DGELQT.

 Q is of order M if SIDE = 'L' and of order N  if SIDE = 'R'.

Parameters

[in]	SIDE	SIDE is CHARACTER*1 = 'L': apply Q or Q**T from the Left; = 'R': apply Q or Q**T from the Right.
[in]	TRANS	TRANS is CHARACTER*1 = 'N': No transpose, apply Q; = 'C': Transpose, apply Q**T.
[in]	M	M is INTEGER The number of rows of the matrix C. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix C. N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. If SIDE = 'L', M >= K >= 0; if SIDE = 'R', N >= K >= 0.
[in]	MB	MB is INTEGER The block size used for the storage of T. K >= MB >= 1. This must be the same value of MB used to generate T in DGELQT.
[in]	V	V is DOUBLE PRECISION array, dimension (LDV,M) if SIDE = 'L', (LDV,N) if SIDE = 'R' The i-th row must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by DGELQT in the first K rows of its array argument A.
[in]	LDV	LDV is INTEGER The leading dimension of the array V. LDV >= max(1,K).
[in]	T	T is DOUBLE PRECISION array, dimension (LDT,K) The upper triangular factors of the block reflectors as returned by DGELQT, stored as a MB-by-K matrix.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= MB.
[in,out]	C	C is DOUBLE PRECISION array, dimension (LDC,N) On entry, the M-by-N matrix C. On exit, C is overwritten by Q C, Q**T C, C Q**T or C Q.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).
[out]	WORK	WORK is DOUBLE PRECISION array. The dimension of WORK is N*MB if SIDE = 'L', or M*MB if SIDE = 'R'.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 166 of file dgemlqt.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER SIDE, TRANS
      INTEGER   INFO, K, LDV, LDC, M, N, MB, LDT
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION V( LDV, * ), C( LDC, * ), T( LDT, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN
      INTEGER            I, IB, LDWORK, KF, Q
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, dlarfb
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     .. Test the input arguments ..
*
      info   = 0
      left   = lsame( side,  'L' )
      right  = lsame( side,  'R' )
      tran   = lsame( trans, 'T' )
      notran = lsame( trans, 'N' )
*
      IF( left ) THEN
         ldwork = max( 1, n )
         q = m
      ELSE IF ( right ) THEN
         ldwork = max( 1, m )
         q = n
      END IF
      IF( .NOT.left .AND. .NOT.right ) THEN
         info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
         info = -2
      ELSE IF( m.LT.0 ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( k.LT.0 .OR. k.GT.q ) THEN
         info = -5
      ELSE IF( mb.LT.1 .OR. (mb.GT.k .AND. k.GT.0)) THEN
         info = -6
      ELSE IF( ldv.LT.max( 1, k ) ) THEN
          info = -8
      ELSE IF( ldt.LT.mb ) THEN
         info = -10
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
         info = -12
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEMLQT', -info )
         RETURN
      END IF
*
*     .. Quick return if possible ..
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) RETURN
*
      IF( left .AND. notran ) THEN
*
         DO i = 1, k, mb
            ib = min( mb, k-i+1 )
            CALL dlarfb( 'L', 'T', 'F', 'R', m-i+1, n, ib,
     $                   v( i, i ), ldv, t( 1, i ), ldt,
     $                   c( i, 1 ), ldc, work, ldwork )
         END DO
*
      ELSE IF( right .AND. tran ) THEN
*
         DO i = 1, k, mb
            ib = min( mb, k-i+1 )
            CALL dlarfb( 'R', 'N', 'F', 'R', m, n-i+1, ib,
     $                   v( i, i ), ldv, t( 1, i ), ldt,
     $                   c( 1, i ), ldc, work, ldwork )
         END DO
*
      ELSE IF( left .AND. tran ) THEN
*
         kf = ((k-1)/mb)*mb+1
         DO i = kf, 1, -mb
            ib = min( mb, k-i+1 )
            CALL dlarfb( 'L', 'N', 'F', 'R', m-i+1, n, ib,
     $                   v( i, i ), ldv, t( 1, i ), ldt,
     $                   c( i, 1 ), ldc, work, ldwork )
         END DO
*
      ELSE IF( right .AND. notran ) THEN
*
         kf = ((k-1)/mb)*mb+1
         DO i = kf, 1, -mb
            ib = min( mb, k-i+1 )
            CALL dlarfb( 'R', 'T', 'F', 'R', m, n-i+1, ib,
     $                   v( i, i ), ldv, t( 1, i ), ldt,
     $                   c( 1, i ), ldc, work, ldwork )
         END DO
*
      END IF
*
      RETURN
*
*     End of DGEMLQT
*

Here is the call graph for this function:

Here is the caller graph for this function: