zqrt05()

subroutine zqrt05	(	integer	m,
		integer	n,
		integer	l,
		integer	nb,
		double precision, dimension(6)	result
	)

ZQRT05

Purpose:

 ZQRT05 tests ZTPQRT and ZTPMQRT.

Parameters

[in]	M	M is INTEGER Number of rows in lower part of the test matrix.
[in]	N	N is INTEGER Number of columns in test matrix.
[in]	L	L is INTEGER The number of rows of the upper trapezoidal part the lower test matrix. 0 <= L <= M.
[in]	NB	NB is INTEGER Block size of test matrix. NB <= N.
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (6) Results of each of the six tests below. RESULT(1) = | A - Q R | RESULT(2) = | I - Q^H Q | RESULT(3) = | Q C - Q C | RESULT(4) = | Q^H C - Q^H C | RESULT(5) = | C Q - C Q | RESULT(6) = | C Q^H - C Q^H |

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 79 of file zqrt05.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER LWORK, M, N, L, NB, LDT
*     .. Return values ..
      DOUBLE PRECISION RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      COMPLEX*16, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
      DOUBLE PRECISION, ALLOCATABLE :: RWORK(:)
*
*     .. Parameters ..
      DOUBLE PRECISION ZERO
      COMPLEX*16 ONE, CZERO
      parameter( zero = 0.0, one = (1.0,0.0), czero=(0.0,0.0) )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, M2, NP1
      DOUBLE PRECISION ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DLAMCH
      DOUBLE PRECISION ZLANGE, ZLANSY
      LOGICAL  LSAME
      EXTERNAL dlamch, zlange, zlansy, lsame
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = dlamch( 'Epsilon' )
      k = n
      m2 = m+n
      IF( m.GT.0 ) THEN
         np1 = n+1
      ELSE
         np1 = 1
      END IF
      lwork = m2*m2*nb
*
*     Dynamically allocate all arrays
*
      ALLOCATE(a(m2,n),af(m2,n),q(m2,m2),r(m2,m2),rwork(m2),
     $           work(lwork),t(nb,n),c(m2,n),cf(m2,n),
     $           d(n,m2),df(n,m2) )
*
*     Put random stuff into A
*
      ldt=nb
      CALL zlaset( 'Full', m2, n, czero, czero, a, m2 )
      CALL zlaset( 'Full', nb, n, czero, czero, t, nb )
      DO j=1,n
         CALL zlarnv( 2, iseed, j, a( 1, j ) )
      END DO
      IF( m.GT.0 ) THEN
         DO j=1,n
            CALL zlarnv( 2, iseed, m-l, a( min(n+m,n+1), j ) )
         END DO
      END IF
      IF( l.GT.0 ) THEN
         DO j=1,n
            CALL zlarnv( 2, iseed, min(j,l), a( min(n+m,n+m-l+1), j ) )
         END DO
      END IF
*
*     Copy the matrix A to the array AF.
*
      CALL zlacpy( 'Full', m2, n, a, m2, af, m2 )
*
*     Factor the matrix A in the array AF.
*
      CALL ztpqrt( m,n,l,nb,af,m2,af(np1,1),m2,t,ldt,work,info)
*
*     Generate the (M+N)-by-(M+N) matrix Q by applying H to I
*
      CALL zlaset( 'Full', m2, m2, czero, one, q, m2 )
      CALL zgemqrt( 'R', 'N', m2, m2, k, nb, af, m2, t, ldt, q, m2,
     $              work, info )
*
*     Copy R
*
      CALL zlaset( 'Full', m2, n, czero, czero, r, m2 )
      CALL zlacpy( 'Upper', m2, n, af, m2, r, m2 )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL zgemm( 'C', 'N', m2, n, m2, -one, q, m2, a, m2, one, r, m2 )
      anorm = zlange( '1', m2, n, a, m2, rwork )
      resid = zlange( '1', m2, n, r, m2, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*anorm*max(1,m2))
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL zlaset( 'Full', m2, m2, czero, one, r, m2 )
      CALL zherk( 'U', 'C', m2, m2, dreal(-one), q, m2, dreal(one),
     $            r, m2 )
      resid = zlansy( '1', 'Upper', m2, r, m2, rwork )
      result( 2 ) = resid / (eps*max(1,m2))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL zlarnv( 2, iseed, m2, c( 1, j ) )
      END DO
      cnorm = zlange( '1', m2, n, c, m2, rwork)
      CALL zlacpy( 'Full', m2, n, c, m2, cf, m2 )
*
*     Apply Q to C as Q*C
*
      CALL ztpmqrt( 'L','N', m,n,k,l,nb,af(np1,1),m2,t,ldt,cf,m2,
     $               cf(np1,1),m2,work,info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL zgemm( 'N', 'N', m2, n, m2, -one, q, m2, c, m2, one, cf, m2 )
      resid = zlange( '1', m2, n, cf, m2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m2)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL zlacpy( 'Full', m2, n, c, m2, cf, m2 )
*
*     Apply Q to C as QT*C
*
      CALL ztpmqrt( 'L','C',m,n,k,l,nb,af(np1,1),m2,t,ldt,cf,m2,
     $              cf(np1,1),m2,work,info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL zgemm('C','N',m2,n,m2,-one,q,m2,c,m2,one,cf,m2)
      resid = zlange( '1', m2, n, cf, m2, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m2)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m2
         CALL zlarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = zlange( '1', n, m2, d, n, rwork)
      CALL zlacpy( 'Full', n, m2, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      CALL ztpmqrt('R','N',n,m,n,l,nb,af(np1,1),m2,t,ldt,df,n,
     $             df(1,np1),n,work,info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL zgemm('N','N',n,m2,m2,-one,d,n,q,m2,one,df,n)
      resid = zlange('1',n, m2,df,n,rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL zlacpy('Full',n,m2,d,n,df,n )
*
*     Apply Q to D as D*QT
*
      CALL ztpmqrt('R','C',n,m,n,l,nb,af(np1,1),m2,t,ldt,df,n,
     $             df(1,np1),n,work,info)
 
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL zgemm( 'N', 'C', n, m2, m2, -one, d, n, q, m2, one, df, n )
      resid = zlange( '1', n, m2, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m2)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
      RETURN

Here is the call graph for this function:

Here is the caller graph for this function: