sggsvd3()

subroutine sggsvd3	(	character	jobu,
		character	jobv,
		character	jobq,
		integer	m,
		integer	n,
		integer	p,
		integer	k,
		integer	l,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( * )	alpha,
		real, dimension( * )	beta,
		real, dimension( ldu, * )	u,
		integer	ldu,
		real, dimension( ldv, * )	v,
		integer	ldv,
		real, dimension( ldq, * )	q,
		integer	ldq,
		real, dimension( * )	work,
		integer	lwork,
		integer, dimension( * )	iwork,
		integer	info )

SGGSVD3 computes the singular value decomposition (SVD) for OTHER matrices

Download SGGSVD3 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SGGSVD3 computes the generalized singular value decomposition (GSVD)
!> of an M-by-N real matrix A and P-by-N real matrix B:
!>
!>       U**T*A*Q = D1*( 0 R ),    V**T*B*Q = D2*( 0 R )
!>
!> where U, V and Q are orthogonal matrices.
!> Let K+L = the effective numerical rank of the matrix (A**T,B**T)**T,
!> then R is a K+L-by-K+L nonsingular upper triangular matrix, D1 and
!> D2 are M-by-(K+L) and P-by-(K+L)  matrices and of the
!> following structures, respectively:
!>
!> If M-K-L >= 0,
!>
!>                     K  L
!>        D1 =     K ( I  0 )
!>                 L ( 0  C )
!>             M-K-L ( 0  0 )
!>
!>                   K  L
!>        D2 =   L ( 0  S )
!>             P-L ( 0  0 )
!>
!>                 N-K-L  K    L
!>   ( 0 R ) = K (  0   R11  R12 )
!>             L (  0    0   R22 )
!>
!> where
!>
!>   C = diag( ALPHA(K+1), ... , ALPHA(K+L) ),
!>   S = diag( BETA(K+1),  ... , BETA(K+L) ),
!>   C**2 + S**2 = I.
!>
!>   R is stored in A(1:K+L,N-K-L+1:N) on exit.
!>
!> If M-K-L < 0,
!>
!>                   K M-K K+L-M
!>        D1 =   K ( I  0    0   )
!>             M-K ( 0  C    0   )
!>
!>                     K M-K K+L-M
!>        D2 =   M-K ( 0  S    0  )
!>             K+L-M ( 0  0    I  )
!>               P-L ( 0  0    0  )
!>
!>                    N-K-L  K   M-K  K+L-M
!>   ( 0 R ) =     K ( 0    R11  R12  R13  )
!>               M-K ( 0     0   R22  R23  )
!>             K+L-M ( 0     0    0   R33  )
!>
!> where
!>
!>   C = diag( ALPHA(K+1), ... , ALPHA(M) ),
!>   S = diag( BETA(K+1),  ... , BETA(M) ),
!>   C**2 + S**2 = I.
!>
!>   (R11 R12 R13 ) is stored in A(1:M, N-K-L+1:N), and R33 is stored
!>   ( 0  R22 R23 )
!>   in B(M-K+1:L,N+M-K-L+1:N) on exit.
!>
!> The routine computes C, S, R, and optionally the orthogonal
!> transformation matrices U, V and Q.
!>
!> In particular, if B is an N-by-N nonsingular matrix, then the GSVD of
!> A and B implicitly gives the SVD of A*inv(B):
!>                      A*inv(B) = U*(D1*inv(D2))*V**T.
!> If ( A**T,B**T)**T  has orthonormal columns, then the GSVD of A and B is
!> also equal to the CS decomposition of A and B. Furthermore, the GSVD
!> can be used to derive the solution of the eigenvalue problem:
!>                      A**T*A x = lambda* B**T*B x.
!> In some literature, the GSVD of A and B is presented in the form
!>                  U**T*A*X = ( 0 D1 ),   V**T*B*X = ( 0 D2 )
!> where U and V are orthogonal and X is nonsingular, D1 and D2 are
!> ``diagonal''.  The former GSVD form can be converted to the latter
!> form by taking the nonsingular matrix X as
!>
!>                      X = Q*( I   0    )
!>                            ( 0 inv(R) ).
!> 

Parameters

[in]	JOBU	!> JOBU is CHARACTER*1 !> = 'U': Orthogonal matrix U is computed; !> = 'N': U is not computed. !>
[in]	JOBV	!> JOBV is CHARACTER*1 !> = 'V': Orthogonal matrix V is computed; !> = 'N': V is not computed. !>
[in]	JOBQ	!> JOBQ is CHARACTER*1 !> = 'Q': Orthogonal matrix Q is computed; !> = 'N': Q is not computed. !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrices A and B. N >= 0. !>
[in]	P	!> P is INTEGER !> The number of rows of the matrix B. P >= 0. !>
[out]	K	!> K is INTEGER !>
[out]	L	!> L is INTEGER !> !> On exit, K and L specify the dimension of the subblocks !> described in Purpose. !> K + L = effective numerical rank of (A**T,B**T)**T. !>
[in,out]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the M-by-N matrix A. !> On exit, A contains the triangular matrix R, or part of R. !> See Purpose for details. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,M). !>
[in,out]	B	!> B is REAL array, dimension (LDB,N) !> On entry, the P-by-N matrix B. !> On exit, B contains the triangular matrix R if M-K-L < 0. !> See Purpose for details. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,P). !>
[out]	ALPHA	!> ALPHA is REAL array, dimension (N) !>
[out]	BETA	!> BETA is REAL array, dimension (N) !> !> On exit, ALPHA and BETA contain the generalized singular !> value pairs of A and B; !> ALPHA(1:K) = 1, !> BETA(1:K) = 0, !> and if M-K-L >= 0, !> ALPHA(K+1:K+L) = C, !> BETA(K+1:K+L) = S, !> or if M-K-L < 0, !> ALPHA(K+1:M)=C, ALPHA(M+1:K+L)=0 !> BETA(K+1:M) =S, BETA(M+1:K+L) =1 !> and !> ALPHA(K+L+1:N) = 0 !> BETA(K+L+1:N) = 0 !>
[out]	U	!> U is REAL array, dimension (LDU,M) !> If JOBU = 'U', U contains the M-by-M orthogonal matrix U. !> If JOBU = 'N', U is not referenced. !>
[in]	LDU	!> LDU is INTEGER !> The leading dimension of the array U. LDU >= max(1,M) if !> JOBU = 'U'; LDU >= 1 otherwise. !>
[out]	V	!> V is REAL array, dimension (LDV,P) !> If JOBV = 'V', V contains the P-by-P orthogonal matrix V. !> If JOBV = 'N', V is not referenced. !>
[in]	LDV	!> LDV is INTEGER !> The leading dimension of the array V. LDV >= max(1,P) if !> JOBV = 'V'; LDV >= 1 otherwise. !>
[out]	Q	!> Q is REAL array, dimension (LDQ,N) !> If JOBQ = 'Q', Q contains the N-by-N orthogonal matrix Q. !> If JOBQ = 'N', Q is not referenced. !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,N) if !> JOBQ = 'Q'; LDQ >= 1 otherwise. !>
[out]	WORK	!> WORK is REAL array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= 1. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	IWORK	!> IWORK is INTEGER array, dimension (N) !> On exit, IWORK stores the sorting information. More !> precisely, the following loop will sort ALPHA !> for I = K+1, min(M,K+L) !> swap ALPHA(I) and ALPHA(IWORK(I)) !> endfor !> such that ALPHA(1) >= ALPHA(2) >= ... >= ALPHA(N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = 1, the Jacobi-type procedure failed to !> converge. For further details, see subroutine STGSJA. !>

Internal Parameters:

!>  TOLA    REAL
!>  TOLB    REAL
!>          TOLA and TOLB are the thresholds to determine the effective
!>          rank of (A**T,B**T)**T. Generally, they are set to
!>                   TOLA = MAX(M,N)*norm(A)*MACHEPS,
!>                   TOLB = MAX(P,N)*norm(B)*MACHEPS.
!>          The size of TOLA and TOLB may affect the size of backward
!>          errors of the decomposition.
!> 

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Further Details:

SGGSVD3 replaces the deprecated subroutine SGGSVD.

Definition at line 344 of file sggsvd3.f.

*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBQ, JOBU, JOBV
      INTEGER            INFO, K, L, LDA, LDB, LDQ, LDU, LDV, M, N, P,
     $                   LWORK
*     ..
*     .. Array Arguments ..
      INTEGER            IWORK( * )
      REAL               A( LDA, * ), ALPHA( * ), B( LDB, * ),
     $                   BETA( * ), Q( LDQ, * ), U( LDU, * ),
     $                   V( LDV, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            WANTQ, WANTU, WANTV, LQUERY
      INTEGER            I, IBND, ISUB, J, NCYCLE, LWKOPT
      REAL               ANORM, BNORM, SMAX, TEMP, TOLA, TOLB, ULP, UNFL
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE, SROUNDUP_LWORK
      EXTERNAL           lsame, slamch, slange,
     $                   sroundup_lwork
*     ..
*     .. External Subroutines ..
      EXTERNAL           scopy, sggsvp3, stgsja, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Decode and test the input parameters
*
      wantu = lsame( jobu, 'U' )
      wantv = lsame( jobv, 'V' )
      wantq = lsame( jobq, 'Q' )
      lquery = ( lwork.EQ.-1 )
      lwkopt = 1
*
*     Test the input arguments
*
      info = 0
      IF( .NOT.( wantu .OR. lsame( jobu, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( wantv .OR. lsame( jobv, 'N' ) ) ) THEN
         info = -2
      ELSE IF( .NOT.( wantq .OR. lsame( jobq, 'N' ) ) ) THEN
         info = -3
      ELSE IF( m.LT.0 ) THEN
         info = -4
      ELSE IF( n.LT.0 ) THEN
         info = -5
      ELSE IF( p.LT.0 ) THEN
         info = -6
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -10
      ELSE IF( ldb.LT.max( 1, p ) ) THEN
         info = -12
      ELSE IF( ldu.LT.1 .OR. ( wantu .AND. ldu.LT.m ) ) THEN
         info = -16
      ELSE IF( ldv.LT.1 .OR. ( wantv .AND. ldv.LT.p ) ) THEN
         info = -18
      ELSE IF( ldq.LT.1 .OR. ( wantq .AND. ldq.LT.n ) ) THEN
         info = -20
      ELSE IF( lwork.LT.1 .AND. .NOT.lquery ) THEN
         info = -24
      END IF
*
*     Compute workspace
*
      IF( info.EQ.0 ) THEN
         CALL sggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb,
     $                 tola,
     $                 tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, work,
     $                 work, -1, info )
         lwkopt = n + int( work( 1 ) )
         lwkopt = max( 2*n, lwkopt )
         lwkopt = max( 1, lwkopt )
         work( 1 ) = sroundup_lwork( lwkopt )
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGGSVD3', -info )
         RETURN
      END IF
      IF( lquery ) THEN
         RETURN
      ENDIF
*
*     Compute the Frobenius norm of matrices A and B
*
      anorm = slange( '1', m, n, a, lda, work )
      bnorm = slange( '1', p, n, b, ldb, work )
*
*     Get machine precision and set up threshold for determining
*     the effective numerical rank of the matrices A and B.
*
      ulp = slamch( 'Precision' )
      unfl = slamch( 'Safe Minimum' )
      tola = real( max( m, n ) )*max( anorm, unfl )*ulp
      tolb = real( max( p, n ) )*max( bnorm, unfl )*ulp
*
*     Preprocessing
*
      CALL sggsvp3( jobu, jobv, jobq, m, p, n, a, lda, b, ldb, tola,
     $              tolb, k, l, u, ldu, v, ldv, q, ldq, iwork, work,
     $              work( n+1 ), lwork-n, info )
*
*     Compute the GSVD of two upper "triangular" matrices
*
      CALL stgsja( jobu, jobv, jobq, m, p, n, k, l, a, lda, b, ldb,
     $             tola, tolb, alpha, beta, u, ldu, v, ldv, q, ldq,
     $             work, ncycle, info )
*
*     Sort the singular values and store the pivot indices in IWORK
*     Copy ALPHA to WORK, then sort ALPHA in WORK
*
      CALL scopy( n, alpha, 1, work, 1 )
      ibnd = min( l, m-k )
      DO 20 i = 1, ibnd
*
*        Scan for largest ALPHA(K+I)
*
         isub = i
         smax = work( k+i )
         DO 10 j = i + 1, ibnd
            temp = work( k+j )
            IF( temp.GT.smax ) THEN
               isub = j
               smax = temp
            END IF
   10    CONTINUE
         IF( isub.NE.i ) THEN
            work( k+isub ) = work( k+i )
            work( k+i ) = smax
            iwork( k+i ) = k + isub
         ELSE
            iwork( k+i ) = k + i
         END IF
   20 CONTINUE
*
      work( 1 ) = sroundup_lwork( lwkopt )
      RETURN
*
*     End of SGGSVD3
*

Here is the call graph for this function:

Here is the caller graph for this function: