dchkhs.f

Go to the documentation of this file.

*> \brief \b DCHKHS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DCHKHS( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                          NOUNIT, A, LDA, H, T1, T2, U, LDU, Z, UZ, WR1,
*                          WI1, WR2, WI2, WR3, WI3, EVECTL, EVECTR, EVECTY,
*                          EVECTX, UU, TAU, WORK, NWORK, IWORK, SELECT,
*                          RESULT, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDU, NOUNIT, NSIZES, NTYPES, NWORK
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * ), SELECT( * )
*       INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
*       DOUBLE PRECISION   A( LDA, * ), EVECTL( LDU, * ),
*      $                   EVECTR( LDU, * ), EVECTX( LDU, * ),
*      $                   EVECTY( LDU, * ), H( LDA, * ), RESULT( 16 ),
*      $                   T1( LDA, * ), T2( LDA, * ), TAU( * ),
*      $                   U( LDU, * ), UU( LDU, * ), UZ( LDU, * ),
*      $                   WI1( * ), WI2( * ), WI3( * ), WORK( * ),
*      $                   WR1( * ), WR2( * ), WR3( * ), Z( LDU, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    DCHKHS  checks the nonsymmetric eigenvalue problem routines.
*>
*>            DGEHRD factors A as  U H U' , where ' means transpose,
*>            H is hessenberg, and U is an orthogonal matrix.
*>
*>            DORGHR generates the orthogonal matrix U.
*>
*>            DORMHR multiplies a matrix by the orthogonal matrix U.
*>
*>            DHSEQR factors H as  Z T Z' , where Z is orthogonal and
*>            T is "quasi-triangular", and the eigenvalue vector W.
*>
*>            DTREVC computes the left and right eigenvector matrices
*>            L and R for T. L is lower quasi-triangular, and R is
*>            upper quasi-triangular.
*>
*>            DHSEIN computes the left and right eigenvector matrices
*>            Y and X for H, using inverse iteration.
*>
*>            DTREVC3 computes left and right eigenvector matrices
*>            from a Schur matrix T and backtransforms them with Z
*>            to eigenvector matrices L and R for A. L and R are
*>            GE matrices.
*>
*>    When DCHKHS is called, a number of matrix "sizes" ("n's") and a
*>    number of matrix "types" are specified.  For each size ("n")
*>    and each type of matrix, one matrix will be generated and used
*>    to test the nonsymmetric eigenroutines.  For each matrix, 16
*>    tests will be performed:
*>
*>    (1)     | A - U H U**T | / ( |A| n ulp )
*>
*>    (2)     | I - UU**T | / ( n ulp )
*>
*>    (3)     | H - Z T Z**T | / ( |H| n ulp )
*>
*>    (4)     | I - ZZ**T | / ( n ulp )
*>
*>    (5)     | A - UZ H (UZ)**T | / ( |A| n ulp )
*>
*>    (6)     | I - UZ (UZ)**T | / ( n ulp )
*>
*>    (7)     | T(Z computed) - T(Z not computed) | / ( |T| ulp )
*>
*>    (8)     | W(Z computed) - W(Z not computed) | / ( |W| ulp )
*>
*>    (9)     | TR - RW | / ( |T| |R| ulp )
*>
*>    (10)    | L**H T - W**H L | / ( |T| |L| ulp )
*>
*>    (11)    | HX - XW | / ( |H| |X| ulp )
*>
*>    (12)    | Y**H H - W**H Y | / ( |H| |Y| ulp )
*>
*>    (13)    | AX - XW | / ( |A| |X| ulp )
*>
*>    (14)    | Y**H A - W**H Y | / ( |A| |Y| ulp )
*>
*>    (15)    | AR - RW | / ( |A| |R| ulp )
*>
*>    (16)    | LA - WL | / ( |A| |L| ulp )
*>
*>    The "sizes" are specified by an array NN(1:NSIZES); the value of
*>    each element NN(j) specifies one size.
*>    The "types" are specified by a logical array DOTYPE( 1:NTYPES );
*>    if DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*>    Currently, the list of possible types is:
*>
*>    (1)  The zero matrix.
*>    (2)  The identity matrix.
*>    (3)  A (transposed) Jordan block, with 1's on the diagonal.
*>
*>    (4)  A diagonal matrix with evenly spaced entries
*>         1, ..., ULP  and random signs.
*>         (ULP = (first number larger than 1) - 1 )
*>    (5)  A diagonal matrix with geometrically spaced entries
*>         1, ..., ULP  and random signs.
*>    (6)  A diagonal matrix with "clustered" entries 1, ULP, ..., ULP
*>         and random signs.
*>
*>    (7)  Same as (4), but multiplied by SQRT( overflow threshold )
*>    (8)  Same as (4), but multiplied by SQRT( underflow threshold )
*>
*>    (9)  A matrix of the form  U' T U, where U is orthogonal and
*>         T has evenly spaced entries 1, ..., ULP with random signs
*>         on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (10) A matrix of the form  U' T U, where U is orthogonal and
*>         T has geometrically spaced entries 1, ..., ULP with random
*>         signs on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (11) A matrix of the form  U' T U, where U is orthogonal and
*>         T has "clustered" entries 1, ULP,..., ULP with random
*>         signs on the diagonal and random O(1) entries in the upper
*>         triangle.
*>
*>    (12) A matrix of the form  U' T U, where U is orthogonal and
*>         T has real or complex conjugate paired eigenvalues randomly
*>         chosen from ( ULP, 1 ) and random O(1) entries in the upper
*>         triangle.
*>
*>    (13) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has evenly spaced entries 1, ..., ULP
*>         with random signs on the diagonal and random O(1) entries
*>         in the upper triangle.
*>
*>    (14) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has geometrically spaced entries
*>         1, ..., ULP with random signs on the diagonal and random
*>         O(1) entries in the upper triangle.
*>
*>    (15) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has "clustered" entries 1, ULP,..., ULP
*>         with random signs on the diagonal and random O(1) entries
*>         in the upper triangle.
*>
*>    (16) A matrix of the form  X' T X, where X has condition
*>         SQRT( ULP ) and T has real or complex conjugate paired
*>         eigenvalues randomly chosen from ( ULP, 1 ) and random
*>         O(1) entries in the upper triangle.
*>
*>    (17) Same as (16), but multiplied by SQRT( overflow threshold )
*>    (18) Same as (16), but multiplied by SQRT( underflow threshold )
*>
*>    (19) Nonsymmetric matrix with random entries chosen from (-1,1).
*>    (20) Same as (19), but multiplied by SQRT( overflow threshold )
*>    (21) Same as (19), but multiplied by SQRT( underflow threshold )
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \verbatim
*>  NSIZES - INTEGER
*>           The number of sizes of matrices to use.  If it is zero,
*>           DCHKHS does nothing.  It must be at least zero.
*>           Not modified.
*>
*>  NN     - INTEGER array, dimension (NSIZES)
*>           An array containing the sizes to be used for the matrices.
*>           Zero values will be skipped.  The values must be at least
*>           zero.
*>           Not modified.
*>
*>  NTYPES - INTEGER
*>           The number of elements in DOTYPE.   If it is zero, DCHKHS
*>           does nothing.  It must be at least zero.  If it is MAXTYP+1
*>           and NSIZES is 1, then an additional type, MAXTYP+1 is
*>           defined, which is to use whatever matrix is in A.  This
*>           is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>           DOTYPE(MAXTYP+1) is .TRUE. .
*>           Not modified.
*>
*>  DOTYPE - LOGICAL array, dimension (NTYPES)
*>           If DOTYPE(j) is .TRUE., then for each size in NN a
*>           matrix of that size and of type j will be generated.
*>           If NTYPES is smaller than the maximum number of types
*>           defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>           MAXTYP will not be generated.  If NTYPES is larger
*>           than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>           will be ignored.
*>           Not modified.
*>
*>  ISEED  - INTEGER array, dimension (4)
*>           On entry ISEED specifies the seed of the random number
*>           generator. The array elements should be between 0 and 4095;
*>           if not they will be reduced mod 4096.  Also, ISEED(4) must
*>           be odd.  The random number generator uses a linear
*>           congruential sequence limited to small integers, and so
*>           should produce machine independent random numbers. The
*>           values of ISEED are changed on exit, and can be used in the
*>           next call to DCHKHS to continue the same random number
*>           sequence.
*>           Modified.
*>
*>  THRESH - DOUBLE PRECISION
*>           A test will count as "failed" if the "error", computed as
*>           described above, exceeds THRESH.  Note that the error
*>           is scaled to be O(1), so THRESH should be a reasonably
*>           small multiple of 1, e.g., 10 or 100.  In particular,
*>           it should not depend on the precision (single vs. double)
*>           or the size of the matrix.  It must be at least zero.
*>           Not modified.
*>
*>  NOUNIT - INTEGER
*>           The FORTRAN unit number for printing out error messages
*>           (e.g., if a routine returns IINFO not equal to 0.)
*>           Not modified.
*>
*>  A      - DOUBLE PRECISION array, dimension (LDA,max(NN))
*>           Used to hold the matrix whose eigenvalues are to be
*>           computed.  On exit, A contains the last matrix actually
*>           used.
*>           Modified.
*>
*>  LDA    - INTEGER
*>           The leading dimension of A, H, T1 and T2.  It must be at
*>           least 1 and at least max( NN ).
*>           Not modified.
*>
*>  H      - DOUBLE PRECISION array, dimension (LDA,max(NN))
*>           The upper hessenberg matrix computed by DGEHRD.  On exit,
*>           H contains the Hessenberg form of the matrix in A.
*>           Modified.
*>
*>  T1     - DOUBLE PRECISION array, dimension (LDA,max(NN))
*>           The Schur (="quasi-triangular") matrix computed by DHSEQR
*>           if Z is computed.  On exit, T1 contains the Schur form of
*>           the matrix in A.
*>           Modified.
*>
*>  T2     - DOUBLE PRECISION array, dimension (LDA,max(NN))
*>           The Schur matrix computed by DHSEQR when Z is not computed.
*>           This should be identical to T1.
*>           Modified.
*>
*>  LDU    - INTEGER
*>           The leading dimension of U, Z, UZ and UU.  It must be at
*>           least 1 and at least max( NN ).
*>           Not modified.
*>
*>  U      - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The orthogonal matrix computed by DGEHRD.
*>           Modified.
*>
*>  Z      - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The orthogonal matrix computed by DHSEQR.
*>           Modified.
*>
*>  UZ     - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The product of U times Z.
*>           Modified.
*>
*>  WR1    - DOUBLE PRECISION array, dimension (max(NN))
*>  WI1    - DOUBLE PRECISION array, dimension (max(NN))
*>           The real and imaginary parts of the eigenvalues of A,
*>           as computed when Z is computed.
*>           On exit, WR1 + WI1*i are the eigenvalues of the matrix in A.
*>           Modified.
*>
*>  WR2    - DOUBLE PRECISION array, dimension (max(NN))
*>  WI2    - DOUBLE PRECISION array, dimension (max(NN))
*>           The real and imaginary parts of the eigenvalues of A,
*>           as computed when T is computed but not Z.
*>           On exit, WR2 + WI2*i are the eigenvalues of the matrix in A.
*>           Modified.
*>
*>  WR3    - DOUBLE PRECISION array, dimension (max(NN))
*>  WI3    - DOUBLE PRECISION array, dimension (max(NN))
*>           Like WR1, WI1, these arrays contain the eigenvalues of A,
*>           but those computed when DHSEQR only computes the
*>           eigenvalues, i.e., not the Schur vectors and no more of the
*>           Schur form than is necessary for computing the
*>           eigenvalues.
*>           Modified.
*>
*>  EVECTL - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The (upper triangular) left eigenvector matrix for the
*>           matrix in T1.  For complex conjugate pairs, the real part
*>           is stored in one row and the imaginary part in the next.
*>           Modified.
*>
*>  EVEZTR - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The (upper triangular) right eigenvector matrix for the
*>           matrix in T1.  For complex conjugate pairs, the real part
*>           is stored in one column and the imaginary part in the next.
*>           Modified.
*>
*>  EVECTY - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The left eigenvector matrix for the
*>           matrix in H.  For complex conjugate pairs, the real part
*>           is stored in one row and the imaginary part in the next.
*>           Modified.
*>
*>  EVECTX - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           The right eigenvector matrix for the
*>           matrix in H.  For complex conjugate pairs, the real part
*>           is stored in one column and the imaginary part in the next.
*>           Modified.
*>
*>  UU     - DOUBLE PRECISION array, dimension (LDU,max(NN))
*>           Details of the orthogonal matrix computed by DGEHRD.
*>           Modified.
*>
*>  TAU    - DOUBLE PRECISION array, dimension(max(NN))
*>           Further details of the orthogonal matrix computed by DGEHRD.
*>           Modified.
*>
*>  WORK   - DOUBLE PRECISION array, dimension (NWORK)
*>           Workspace.
*>           Modified.
*>
*>  NWORK  - INTEGER
*>           The number of entries in WORK.  NWORK >= 4*NN(j)*NN(j) + 2.
*>
*>  IWORK  - INTEGER array, dimension (max(NN))
*>           Workspace.
*>           Modified.
*>
*>  SELECT - LOGICAL array, dimension (max(NN))
*>           Workspace.
*>           Modified.
*>
*>  RESULT - DOUBLE PRECISION array, dimension (16)
*>           The values computed by the fourteen tests described above.
*>           The values are currently limited to 1/ulp, to avoid
*>           overflow.
*>           Modified.
*>
*>  INFO   - INTEGER
*>           If 0, then everything ran OK.
*>            -1: NSIZES < 0
*>            -2: Some NN(j) < 0
*>            -3: NTYPES < 0
*>            -6: THRESH < 0
*>            -9: LDA < 1 or LDA < NMAX, where NMAX is max( NN(j) ).
*>           -14: LDU < 1 or LDU < NMAX.
*>           -28: NWORK too small.
*>           If  DLATMR, SLATMS, or SLATME returns an error code, the
*>               absolute value of it is returned.
*>           If 1, then DHSEQR could not find all the shifts.
*>           If 2, then the EISPACK code (for small blocks) failed.
*>           If >2, then 30*N iterations were not enough to find an
*>               eigenvalue or to decompose the problem.
*>           Modified.
*>
*>-----------------------------------------------------------------------
*>
*>     Some Local Variables and Parameters:
*>     ---- ----- --------- --- ----------
*>
*>     ZERO, ONE       Real 0 and 1.
*>     MAXTYP          The number of types defined.
*>     MTEST           The number of tests defined: care must be taken
*>                     that (1) the size of RESULT, (2) the number of
*>                     tests actually performed, and (3) MTEST agree.
*>     NTEST           The number of tests performed on this matrix
*>                     so far.  This should be less than MTEST, and
*>                     equal to it by the last test.  It will be less
*>                     if any of the routines being tested indicates
*>                     that it could not compute the matrices that
*>                     would be tested.
*>     NMAX            Largest value in NN.
*>     NMATS           The number of matrices generated so far.
*>     NERRS           The number of tests which have exceeded THRESH
*>                     so far (computed by DLAFTS).
*>     COND, CONDS,
*>     IMODE           Values to be passed to the matrix generators.
*>     ANORM           Norm of A; passed to matrix generators.
*>
*>     OVFL, UNFL      Overflow and underflow thresholds.
*>     ULP, ULPINV     Finest relative precision and its inverse.
*>     RTOVFL, RTUNFL,
*>     RTULP, RTULPI   Square roots of the previous 4 values.
*>
*>             The following four arrays decode JTYPE:
*>     KTYPE(j)        The general type (1-10) for type "j".
*>     KMODE(j)        The MODE value to be passed to the matrix
*>                     generator for type "j".
*>     KMAGN(j)        The order of magnitude ( O(1),
*>                     O(overflow^(1/2) ), O(underflow^(1/2) )
*>     KCONDS(j)       Selects whether CONDS is to be 1 or
*>                     1/sqrt(ulp).  (0 means irrelevant.)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dchkhs( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                   NOUNIT, A, LDA, H, T1, T2, U, LDU, Z, UZ, WR1,
     $                   WI1, WR2, WI2, WR3, WI3, EVECTL, EVECTR,
     $                   EVECTY, EVECTX, UU, TAU, WORK, NWORK, IWORK,
     $                   SELECT, RESULT, INFO )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDU, NOUNIT, NSIZES, NTYPES, NWORK
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * ), SELECT( * )
      INTEGER            ISEED( 4 ), IWORK( * ), NN( * )
      DOUBLE PRECISION   A( LDA, * ), EVECTL( LDU, * ),
     $                   EVECTR( LDU, * ), EVECTX( LDU, * ),
     $                   evecty( ldu, * ), h( lda, * ), result( 16 ),
     $                   t1( lda, * ), t2( lda, * ), tau( * ),
     $                   u( ldu, * ), uu( ldu, * ), uz( ldu, * ),
     $                   wi1( * ), wi2( * ), wi3( * ), work( * ),
     $                   wr1( * ), wr2( * ), wr3( * ), z( ldu, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      PARAMETER          ( ZERO = 0.0d0, one = 1.0d0 )
      INTEGER            MAXTYP
      PARAMETER          ( MAXTYP = 21 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN, MATCH
      INTEGER            I, IHI, IINFO, ILO, IMODE, IN, ITYPE, J, JCOL,
     $                   JJ, JSIZE, JTYPE, K, MTYPES, N, N1, NERRS,
     $                   NMATS, NMAX, NSELC, NSELR, NTEST, NTESTT
      DOUBLE PRECISION   ANINV, ANORM, COND, CONDS, OVFL, RTOVFL, RTULP,
     $                   rtulpi, rtunfl, temp1, temp2, ulp, ulpinv, unfl
*     ..
*     .. Local Arrays ..
      CHARACTER          ADUMMA( 1 )
      INTEGER            IDUMMA( 1 ), IOLDSD( 4 ), KCONDS( MAXTYP ),
     $                   KMAGN( MAXTYP ), KMODE( MAXTYP ),
     $                   KTYPE( MAXTYP )
      DOUBLE PRECISION   DUMMA( 6 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dgehrd, dgemm, dget10, dget22, dhsein,
     $                   dhseqr, dhst01, dlacpy, dlafts, dlaset, dlasum,
     $                   dlatme, dlatmr, dlatms, dorghr, dormhr, dtrevc,
     $                   dtrevc3, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min, sqrt
*     ..
*     .. Data statements ..
      DATA               ktype / 1, 2, 3, 5*4, 4*6, 6*6, 3*9 /
      DATA               kmagn / 3*1, 1, 1, 1, 2, 3, 4*1, 1, 1, 1, 1, 2,
     $                   3, 1, 2, 3 /
      DATA               kmode / 3*0, 4, 3, 1, 4, 4, 4, 3, 1, 5, 4, 3,
     $                   1, 5, 5, 5, 4, 3, 1 /
      DATA               kconds / 3*0, 5*0, 4*1, 6*2, 3*0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      ntestt = 0
      info = 0
*
      badnn = .false.
      nmax = 0
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldu.LE.1 .OR. ldu.LT.nmax ) THEN
         info = -14
      ELSE IF( 4*nmax*nmax+2.GT.nwork ) THEN
         info = -28
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DCHKHS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
*     More important constants
*
      unfl = dlamch( 'Safe minimum' )
      ovfl = dlamch( 'Overflow' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
      ulpinv = one / ulp
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
      rtulp = sqrt( ulp )
      rtulpi = one / rtulp
*
*     Loop over sizes, types
*
      nerrs = 0
      nmats = 0
*
      DO 270 jsize = 1, nsizes
         n = nn( jsize )
         IF( n.EQ.0 )
     $      GO TO 270
         n1 = max( 1, n )
         aninv = one / dble( n1 )
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 260 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 260
            nmats = nmats + 1
            ntest = 0
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Initialize RESULT
*
            DO 30 j = 1, 16
               result( j ) = zero
   30       CONTINUE
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KCONDS  KMODE        KTYPE
*       =1  O(1)   1       clustered 1  zero
*       =2  large  large   clustered 2  identity
*       =3  small          exponential  Jordan
*       =4                 arithmetic   diagonal, (w/ eigenvalues)
*       =5                 random log   symmetric, w/ eigenvalues
*       =6                 random       general, w/ eigenvalues
*       =7                              random diagonal
*       =8                              random symmetric
*       =9                              random general
*       =10                             random triangular
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 100
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 40, 50, 60 )kmagn( jtype )
*
   40       CONTINUE
            anorm = one
            GO TO 70
*
   50       CONTINUE
            anorm = ( rtovfl*ulp )*aninv
            GO TO 70
*
   60       CONTINUE
            anorm = rtunfl*n*ulpinv
            GO TO 70
*
   70       CONTINUE
*
            CALL dlaset( 'Full', lda, n, zero, zero, a, lda )
            iinfo = 0
            cond = ulpinv
*
*           Special Matrices
*
            IF( itype.EQ.1 ) THEN
*
*              Zero
*
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 80 jcol = 1, n
                  a( jcol, jcol ) = anorm
   80          CONTINUE
*
            ELSE IF( itype.EQ.3 ) THEN
*
*              Jordan Block
*
               DO 90 jcol = 1, n
                  a( jcol, jcol ) = anorm
                  IF( jcol.GT.1 )
     $               a( jcol, jcol-1 ) = one
   90          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL dlatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, 0, 0, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL dlatms( n, n, 'S', iseed, 'S', work, imode, cond,
     $                      anorm, n, n, 'N', a, lda, work( n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              General, eigenvalues specified
*
               IF( kconds( jtype ).EQ.1 ) THEN
                  conds = one
               ELSE IF( kconds( jtype ).EQ.2 ) THEN
                  conds = rtulpi
               ELSE
                  conds = zero
               END IF
*
               adumma( 1 ) = ' '
               CALL dlatme( n, 'S', iseed, work, imode, cond, one,
     $                      adumma, 'T', 'T', 'T', work( n+1 ), 4,
     $                      conds, n, n, anorm, a, lda, work( 2*n+1 ),
     $                      iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random eigenvalues
*
               CALL dlatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random eigenvalues
*
               CALL dlatmr( n, n, 'S', iseed, 'S', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              General, random eigenvalues
*
               CALL dlatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Triangular, random eigenvalues
*
               CALL dlatmr( n, n, 'S', iseed, 'N', work, 6, one, one,
     $                      'T', 'N', work( n+1 ), 1, one,
     $                      work( 2*n+1 ), 1, one, 'N', idumma, n, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE
*
               iinfo = 1
            END IF
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
  100       CONTINUE
*
*           Call DGEHRD to compute H and U, do tests.
*
            CALL dlacpy( ' ', n, n, a, lda, h, lda )
*
            ntest = 1
*
            ilo = 1
            ihi = n
*
            CALL dgehrd( n, ilo, ihi, h, lda, work, work( n+1 ),
     $                   nwork-n, iinfo )
*
            IF( iinfo.NE.0 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'DGEHRD', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
            DO 120 j = 1, n - 1
               uu( j+1, j ) = zero
               DO 110 i = j + 2, n
                  u( i, j ) = h( i, j )
                  uu( i, j ) = h( i, j )
                  h( i, j ) = zero
  110          CONTINUE
  120       CONTINUE
            CALL dcopy( n-1, work, 1, tau, 1 )
            CALL dorghr( n, ilo, ihi, u, ldu, work, work( n+1 ),
     $                   nwork-n, iinfo )
            ntest = 2
*
            CALL dhst01( n, ilo, ihi, a, lda, h, lda, u, ldu, work,
     $                   nwork, result( 1 ) )
*
*           Call DHSEQR to compute T1, T2 and Z, do tests.
*
*           Eigenvalues only (WR3,WI3)
*
            CALL dlacpy( ' ', n, n, h, lda, t2, lda )
            ntest = 3
            result( 3 ) = ulpinv
*
            CALL dhseqr( 'E', 'N', n, ilo, ihi, t2, lda, wr3, wi3, uz,
     $                   ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DHSEQR(E)', iinfo, n, jtype,
     $            ioldsd
               IF( iinfo.LE.n+2 ) THEN
                  info = abs( iinfo )
                  GO TO 250
               END IF
            END IF
*
*           Eigenvalues (WR2,WI2) and Full Schur Form (T2)
*
            CALL dlacpy( ' ', n, n, h, lda, t2, lda )
*
            CALL dhseqr( 'S', 'N', n, ilo, ihi, t2, lda, wr2, wi2, uz,
     $                   ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 .AND. iinfo.LE.n+2 ) THEN
               WRITE( nounit, fmt = 9999 )'DHSEQR(S)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Eigenvalues (WR1,WI1), Schur Form (T1), and Schur vectors
*           (UZ)
*
            CALL dlacpy( ' ', n, n, h, lda, t1, lda )
            CALL dlacpy( ' ', n, n, u, ldu, uz, ldu )
*
            CALL dhseqr( 'S', 'V', n, ilo, ihi, t1, lda, wr1, wi1, uz,
     $                   ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 .AND. iinfo.LE.n+2 ) THEN
               WRITE( nounit, fmt = 9999 )'DHSEQR(V)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Compute Z = U' UZ
*
            CALL dgemm( 'T', 'N', n, n, n, one, u, ldu, uz, ldu, zero,
     $                  z, ldu )
            ntest = 8
*
*           Do Tests 3: | H - Z T Z' | / ( |H| n ulp )
*                and 4: | I - Z Z' | / ( n ulp )
*
            CALL dhst01( n, ilo, ihi, h, lda, t1, lda, z, ldu, work,
     $                   nwork, result( 3 ) )
*
*           Do Tests 5: | A - UZ T (UZ)' | / ( |A| n ulp )
*                and 6: | I - UZ (UZ)' | / ( n ulp )
*
            CALL dhst01( n, ilo, ihi, a, lda, t1, lda, uz, ldu, work,
     $                   nwork, result( 5 ) )
*
*           Do Test 7: | T2 - T1 | / ( |T| n ulp )
*
            CALL dget10( n, n, t2, lda, t1, lda, work, result( 7 ) )
*
*           Do Test 8: | W2 - W1 | / ( max(|W1|,|W2|) ulp )
*
            temp1 = zero
            temp2 = zero
            DO 130 j = 1, n
               temp1 = max( temp1, abs( wr1( j ) )+abs( wi1( j ) ),
     $                 abs( wr2( j ) )+abs( wi2( j ) ) )
               temp2 = max( temp2, abs( wr1( j )-wr2( j ) )+
     &                 abs( wi1( j )-wi2( j ) ) )
  130       CONTINUE
*
            result( 8 ) = temp2 / max( unfl, ulp*max( temp1, temp2 ) )
*
*           Compute the Left and Right Eigenvectors of T
*
*           Compute the Right eigenvector Matrix:
*
            ntest = 9
            result( 9 ) = ulpinv
*
*           Select last max(N/4,1) real, max(N/4,1) complex eigenvectors
*
            nselc = 0
            nselr = 0
            j = n
  140       CONTINUE
            IF( wi1( j ).EQ.zero ) THEN
               IF( nselr.LT.max( n / 4, 1 ) ) THEN
                  nselr = nselr + 1
                  SELECT( j ) = .true.
               ELSE
                  SELECT( j ) = .false.
               END IF
               j = j - 1
            ELSE
               IF( nselc.LT.max( n / 4, 1 ) ) THEN
                  nselc = nselc + 1
                  SELECT( j ) = .true.
                  SELECT( j-1 ) = .false.
               ELSE
                  SELECT( j ) = .false.
                  SELECT( j-1 ) = .false.
               END IF
               j = j - 2
            END IF
            IF( j.GT.0 )
     $         GO TO 140
*
            CALL dtrevc( 'Right', 'All', SELECT, n, t1, lda, dumma, ldu,
     $                   evectr, ldu, n, in, work, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC(R,A)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Test 9:  | TR - RW | / ( |T| |R| ulp )
*
            CALL dget22( 'N', 'N', 'N', n, t1, lda, evectr, ldu, wr1,
     $                   wi1, work, dumma( 1 ) )
            result( 9 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'DTREVC',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           Compute selected right eigenvectors and confirm that
*           they agree with previous right eigenvectors
*
            CALL dtrevc( 'Right', 'Some', SELECT, n, t1, lda, dumma,
     $                   ldu, evectl, ldu, n, in, work, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC(R,S)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
            k = 1
            match = .true.
            DO 170 j = 1, n
               IF( SELECT( j ) .AND. wi1( j ).EQ.zero ) THEN
                  DO 150 jj = 1, n
                     IF( evectr( jj, j ).NE.evectl( jj, k ) ) THEN
                        match = .false.
                        GO TO 180
                     END IF
  150             CONTINUE
                  k = k + 1
               ELSE IF( SELECT( j ) .AND. wi1( j ).NE.zero ) THEN
                  DO 160 jj = 1, n
                     IF( evectr( jj, j ).NE.evectl( jj, k ) .OR.
     $                   evectr( jj, j+1 ).NE.evectl( jj, k+1 ) ) THEN
                        match = .false.
                        GO TO 180
                     END IF
  160             CONTINUE
                  k = k + 2
               END IF
  170       CONTINUE
  180       CONTINUE
            IF( .NOT.match )
     $         WRITE( nounit, fmt = 9997 )'Right', 'DTREVC', n, jtype,
     $         ioldsd
*
*           Compute the Left eigenvector Matrix:
*
            ntest = 10
            result( 10 ) = ulpinv
            CALL dtrevc( 'Left', 'All', SELECT, n, t1, lda, evectl, ldu,
     $                   dumma, ldu, n, in, work, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC(L,A)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Test 10:  | LT - WL | / ( |T| |L| ulp )
*
            CALL dget22( 'Trans', 'N', 'Conj', n, t1, lda, evectl, ldu,
     $                   wr1, wi1, work, dumma( 3 ) )
            result( 10 ) = dumma( 3 )
            IF( dumma( 4 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'DTREVC', dumma( 4 ),
     $            n, jtype, ioldsd
            END IF
*
*           Compute selected left eigenvectors and confirm that
*           they agree with previous left eigenvectors
*
            CALL dtrevc( 'Left', 'Some', SELECT, n, t1, lda, evectr,
     $                   ldu, dumma, ldu, n, in, work, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC(L,S)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
            k = 1
            match = .true.
            DO 210 j = 1, n
               IF( SELECT( j ) .AND. wi1( j ).EQ.zero ) THEN
                  DO 190 jj = 1, n
                     IF( evectl( jj, j ).NE.evectr( jj, k ) ) THEN
                        match = .false.
                        GO TO 220
                     END IF
  190             CONTINUE
                  k = k + 1
               ELSE IF( SELECT( j ) .AND. wi1( j ).NE.zero ) THEN
                  DO 200 jj = 1, n
                     IF( evectl( jj, j ).NE.evectr( jj, k ) .OR.
     $                   evectl( jj, j+1 ).NE.evectr( jj, k+1 ) ) THEN
                        match = .false.
                        GO TO 220
                     END IF
  200             CONTINUE
                  k = k + 2
               END IF
  210       CONTINUE
  220       CONTINUE
            IF( .NOT.match )
     $         WRITE( nounit, fmt = 9997 )'Left', 'DTREVC', n, jtype,
     $         ioldsd
*
*           Call DHSEIN for Right eigenvectors of H, do test 11
*
            ntest = 11
            result( 11 ) = ulpinv
            DO 230 j = 1, n
               SELECT( j ) = .true.
  230       CONTINUE
*
            CALL dhsein( 'Right', 'Qr', 'Ninitv', SELECT, n, h, lda,
     $                   wr3, wi3, dumma, ldu, evectx, ldu, n1, in,
     $                   work, iwork, iwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DHSEIN(R)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            GO TO 250
            ELSE
*
*              Test 11:  | HX - XW | / ( |H| |X| ulp )
*
*                        (from inverse iteration)
*
               CALL dget22( 'N', 'N', 'N', n, h, lda, evectx, ldu, wr3,
     $                      wi3, work, dumma( 1 ) )
               IF( dumma( 1 ).LT.ulpinv )
     $            result( 11 ) = dumma( 1 )*aninv
               IF( dumma( 2 ).GT.thresh ) THEN
                  WRITE( nounit, fmt = 9998 )'Right', 'DHSEIN',
     $               dumma( 2 ), n, jtype, ioldsd
               END IF
            END IF
*
*           Call DHSEIN for Left eigenvectors of H, do test 12
*
            ntest = 12
            result( 12 ) = ulpinv
            DO 240 j = 1, n
               SELECT( j ) = .true.
  240       CONTINUE
*
            CALL dhsein( 'Left', 'Qr', 'Ninitv', SELECT, n, h, lda, wr3,
     $                   wi3, evecty, ldu, dumma, ldu, n1, in, work,
     $                   iwork, iwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DHSEIN(L)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            GO TO 250
            ELSE
*
*              Test 12:  | YH - WY | / ( |H| |Y| ulp )
*
*                        (from inverse iteration)
*
               CALL dget22( 'C', 'N', 'C', n, h, lda, evecty, ldu, wr3,
     $                      wi3, work, dumma( 3 ) )
               IF( dumma( 3 ).LT.ulpinv )
     $            result( 12 ) = dumma( 3 )*aninv
               IF( dumma( 4 ).GT.thresh ) THEN
                  WRITE( nounit, fmt = 9998 )'Left', 'DHSEIN',
     $               dumma( 4 ), n, jtype, ioldsd
               END IF
            END IF
*
*           Call DORMHR for Right eigenvectors of A, do test 13
*
            ntest = 13
            result( 13 ) = ulpinv
*
            CALL dormhr( 'Left', 'No transpose', n, n, ilo, ihi, uu,
     $                   ldu, tau, evectx, ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DORMHR(R)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            GO TO 250
            ELSE
*
*              Test 13:  | AX - XW | / ( |A| |X| ulp )
*
*                        (from inverse iteration)
*
               CALL dget22( 'N', 'N', 'N', n, a, lda, evectx, ldu, wr3,
     $                      wi3, work, dumma( 1 ) )
               IF( dumma( 1 ).LT.ulpinv )
     $            result( 13 ) = dumma( 1 )*aninv
            END IF
*
*           Call DORMHR for Left eigenvectors of A, do test 14
*
            ntest = 14
            result( 14 ) = ulpinv
*
            CALL dormhr( 'Left', 'No transpose', n, n, ilo, ihi, uu,
     $                   ldu, tau, evecty, ldu, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DORMHR(L)', iinfo, n, jtype,
     $            ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 )
     $            GO TO 250
            ELSE
*
*              Test 14:  | YA - WY | / ( |A| |Y| ulp )
*
*                        (from inverse iteration)
*
               CALL dget22( 'C', 'N', 'C', n, a, lda, evecty, ldu, wr3,
     $                      wi3, work, dumma( 3 ) )
               IF( dumma( 3 ).LT.ulpinv )
     $            result( 14 ) = dumma( 3 )*aninv
            END IF
*
*           Compute Left and Right Eigenvectors of A
*
*           Compute a Right eigenvector matrix:
*
            ntest = 15
            result( 15 ) = ulpinv
*
            CALL dlacpy( ' ', n, n, uz, ldu, evectr, ldu )
*
            CALL dtrevc3( 'Right', 'Back', SELECT, n, t1, lda, dumma,
     $                    ldu, evectr, ldu, n, in, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC3(R,B)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Test 15:  | AR - RW | / ( |A| |R| ulp )
*
*                     (from Schur decomposition)
*
            CALL dget22( 'N', 'N', 'N', n, a, lda, evectr, ldu, wr1,
     $                   wi1, work, dumma( 1 ) )
            result( 15 ) = dumma( 1 )
            IF( dumma( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'DTREVC3',
     $            dumma( 2 ), n, jtype, ioldsd
            END IF
*
*           Compute a Left eigenvector matrix:
*
            ntest = 16
            result( 16 ) = ulpinv
*
            CALL dlacpy( ' ', n, n, uz, ldu, evectl, ldu )
*
            CALL dtrevc3( 'Left', 'Back', SELECT, n, t1, lda, evectl,
     $                    ldu, dumma, ldu, n, in, work, nwork, iinfo )
            IF( iinfo.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'DTREVC3(L,B)', iinfo, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               GO TO 250
            END IF
*
*           Test 16:  | LA - WL | / ( |A| |L| ulp )
*
*                     (from Schur decomposition)
*
            CALL dget22( 'Trans', 'N', 'Conj', n, a, lda, evectl, ldu,
     $                   wr1, wi1, work, dumma( 3 ) )
            result( 16 ) = dumma( 3 )
            IF( dumma( 4 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'DTREVC3', dumma( 4 ),
     $            n, jtype, ioldsd
            END IF
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  250       CONTINUE
*
            ntestt = ntestt + ntest
            CALL dlafts( 'DHS', n, n, jtype, ntest, result, ioldsd,
     $                   thresh, nounit, nerrs )
*
  260    CONTINUE
  270 CONTINUE
*
*     Summary
*
      CALL dlasum( 'DHS', nounit, nerrs, ntestt )
*
      RETURN
*
 9999 FORMAT( ' DCHKHS: ', a, ' returned INFO=', i6, '.', / 9x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
 9998 FORMAT( ' DCHKHS: ', a, ' Eigenvectors from ', a, ' incorrectly ',
     $      'normalized.', / ' Bits of error=', 0p, g10.3, ',', 9x,
     $      'N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5,
     $      ')' )
 9997 FORMAT( ' DCHKHS: Selected ', a, ' Eigenvectors from ', a,
     $      ' do not match other eigenvectors ', 9x, 'N=', i6,
     $      ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
*     End of DCHKHS
*
      END