dqlt01()

subroutine dqlt01	(	integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		double precision, dimension( lda, * )	af,
		double precision, dimension( lda, * )	q,
		double precision, dimension( lda, * )	l,
		integer	lda,
		double precision, dimension( * )	tau,
		double precision, dimension( lwork )	work,
		integer	lwork,
		double precision, dimension( * )	rwork,
		double precision, dimension( * )	result )

DQLT01

Purpose:

!>
!> DQLT01 tests DGEQLF, which computes the QL factorization of an m-by-n
!> matrix A, and partially tests DORGQL which forms the m-by-m
!> orthogonal matrix Q.
!>
!> DQLT01 compares L with Q'*A, and checks that Q is orthogonal.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The m-by-n matrix A. !>
[out]	AF	!> AF is DOUBLE PRECISION array, dimension (LDA,N) !> Details of the QL factorization of A, as returned by DGEQLF. !> See DGEQLF for further details. !>
[out]	Q	!> Q is DOUBLE PRECISION array, dimension (LDA,M) !> The m-by-m orthogonal matrix Q. !>
[out]	L	!> L is DOUBLE PRECISION array, dimension (LDA,max(M,N)) !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the arrays A, AF, Q and R. !> LDA >= max(M,N). !>
[out]	TAU	!> TAU is DOUBLE PRECISION array, dimension (min(M,N)) !> The scalar factors of the elementary reflectors, as returned !> by DGEQLF. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. !>
[out]	RWORK	!> RWORK is DOUBLE PRECISION array, dimension (M) !>
[out]	RESULT	!> RESULT is DOUBLE PRECISION array, dimension (2) !> The test ratios: !> RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) !> RESULT(2) = norm( I - Q'*Q ) / ( M * EPS ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file dqlt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   ROGUE
      parameter( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dgeqlf, dlacpy, dlaset, dorgql, dsyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = dlamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL dlacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'DGEQLF'
      CALL dgeqlf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL dlaset( 'Full', m, m, rogue, rogue, q, lda )
      IF( m.GE.n ) THEN
         IF( n.LT.m .AND. n.GT.0 )
     $      CALL dlacpy( 'Full', m-n, n, af, lda, q( 1, m-n+1 ), lda )
         IF( n.GT.1 )
     $      CALL dlacpy( 'Upper', n-1, n-1, af( m-n+1, 2 ), lda,
     $                   q( m-n+1, m-n+2 ), lda )
      ELSE
         IF( m.GT.1 )
     $      CALL dlacpy( 'Upper', m-1, m-1, af( 1, n-m+2 ), lda,
     $                   q( 1, 2 ), lda )
      END IF
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'DORGQL'
      CALL dorgql( m, m, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL dlaset( 'Full', m, n, zero, zero, l, lda )
      IF( m.GE.n ) THEN
         IF( n.GT.0 )
     $      CALL dlacpy( 'Lower', n, n, af( m-n+1, 1 ), lda,
     $                   l( m-n+1, 1 ), lda )
      ELSE
         IF( n.GT.m .AND. m.GT.0 )
     $      CALL dlacpy( 'Full', m, n-m, af, lda, l, lda )
         IF( m.GT.0 )
     $      CALL dlacpy( 'Lower', m, m, af( 1, n-m+1 ), lda,
     $                   l( 1, n-m+1 ), lda )
      END IF
*
*     Compute L - Q'*A
*
      CALL dgemm( 'Transpose', 'No transpose', m, n, m, -one, q, lda, a,
     $            lda, one, l, lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = dlange( '1', m, n, a, lda, rwork )
      resid = dlange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL dlaset( 'Full', m, m, zero, one, l, lda )
      CALL dsyrk( 'Upper', 'Transpose', m, m, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = dlansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of DQLT01
*

Here is the call graph for this function:

Here is the caller graph for this function: