cchkpo()

subroutine cchkpo	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		real	thresh,
		logical	tsterr,
		integer	nmax,
		complex, dimension( * )	a,
		complex, dimension( * )	afac,
		complex, dimension( * )	ainv,
		complex, dimension( * )	b,
		complex, dimension( * )	x,
		complex, dimension( * )	xact,
		complex, dimension( * )	work,
		real, dimension( * )	rwork,
		integer	nout )

CCHKPO

Purpose:

!>
!> CCHKPO tests CPOTRF, -TRI, -TRS, -RFS, and -CON
!> 

Parameters

[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> The matrix types to be used for testing. Matrices of type j !> (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = !> .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used. !>
[in]	NN	!> NN is INTEGER !> The number of values of N contained in the vector NVAL. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NN) !> The values of the matrix dimension N. !>
[in]	NNB	!> NNB is INTEGER !> The number of values of NB contained in the vector NBVAL. !>
[in]	NBVAL	!> NBVAL is INTEGER array, dimension (NNB) !> The values of the blocksize NB. !>
[in]	NNS	!> NNS is INTEGER !> The number of values of NRHS contained in the vector NSVAL. !>
[in]	NSVAL	!> NSVAL is INTEGER array, dimension (NNS) !> The values of the number of right hand sides NRHS. !>
[in]	THRESH	!> THRESH is REAL !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. !>
[in]	TSTERR	!> TSTERR is LOGICAL !> Flag that indicates whether error exits are to be tested. !>
[in]	NMAX	!> NMAX is INTEGER !> The maximum value permitted for N, used in dimensioning the !> work arrays. !>
[out]	A	!> A is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	AFAC	!> AFAC is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	AINV	!> AINV is COMPLEX array, dimension (NMAX*NMAX) !>
[out]	B	!> B is COMPLEX array, dimension (NMAX*NSMAX) !> where NSMAX is the largest entry in NSVAL. !>
[out]	X	!> X is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	XACT	!> XACT is COMPLEX array, dimension (NMAX*NSMAX) !>
[out]	WORK	!> WORK is COMPLEX array, dimension !> (NMAX*max(3,NSMAX)) !>
[out]	RWORK	!> RWORK is REAL array, dimension !> (NMAX+2*NSMAX) !>
[in]	NOUT	!> NOUT is INTEGER !> The unit number for output. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 165 of file cchkpo.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NBVAL( * ), NSVAL( * ), NVAL( * )
      REAL               RWORK( * )
      COMPLEX            A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
      INTEGER            NTYPES
      parameter( ntypes = 9 )
      INTEGER            NTESTS
      parameter( ntests = 8 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IMAT, IN, INB, INFO, IOFF, IRHS, IUPLO,
     $                   IZERO, K, KL, KU, LDA, MODE, N, NB, NERRS,
     $                   NFAIL, NIMAT, NRHS, NRUN
      REAL               ANORM, CNDNUM, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Functions ..
      REAL               CLANHE, SGET06
      EXTERNAL           clanhe, sget06
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, cerrpo, cget04, clacpy,
     $                   claipd, clarhs, clatb4, clatms, cpocon, cporfs,
     $                   cpot01, cpot02, cpot03, cpot05, cpotrf, cpotri,
     $                   cpotrs, xlaenv
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'PO'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL cerrpo( path, nout )
      infot = 0
*
*     Do for each value of N in NVAL
*
      DO 120 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
         DO 110 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 110
*
*           Skip types 3, 4, or 5 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.5
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 110
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 100 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Set up parameters with CLATB4 and generate a test matrix
*              with CLATMS.
*
               CALL clatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                      CNDNUM, DIST )
*
               srnamt = 'CLATMS'
               CALL clatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                      CNDNUM, ANORM, KL, KU, UPLO, A, LDA, WORK,
     $                      INFO )
*
*              Check error code from CLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'CLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
*
*              For types 3-5, zero one row and column of the matrix to
*              test that INFO is returned correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
                  ioff = ( izero-1 )*lda
*
*                 Set row and column IZERO of A to 0.
*
                  IF( iuplo.EQ.1 ) THEN
                     DO 20 i = 1, izero - 1
                        a( ioff+i ) = czero
   20                CONTINUE
                     ioff = ioff + izero
                     DO 30 i = izero, n
                        a( ioff ) = czero
                        ioff = ioff + lda
   30                CONTINUE
                  ELSE
                     ioff = izero
                     DO 40 i = 1, izero - 1
                        a( ioff ) = czero
                        ioff = ioff + lda
   40                CONTINUE
                     ioff = ioff - izero
                     DO 50 i = izero, n
                        a( ioff+i ) = czero
   50                CONTINUE
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              Set the imaginary part of the diagonals.
*
               CALL claipd( n, a, lda+1, 0 )
*
*              Do for each value of NB in NBVAL
*
               DO 90 inb = 1, nnb
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Compute the L*L' or U'*U factorization of the matrix.
*
                  CALL clacpy( uplo, n, n, a, lda, afac, lda )
                  srnamt = 'CPOTRF'
                  CALL cpotrf( uplo, n, afac, lda, info )
*
*                 Check error code from CPOTRF.
*
                  IF( info.NE.izero ) THEN
                     CALL alaerh( path, 'CPOTRF', info, izero, uplo, n,
     $                            n, -1, -1, nb, imat, nfail, nerrs,
     $                            nout )
                     GO TO 90
                  END IF
*
*                 Skip the tests if INFO is not 0.
*
                  IF( info.NE.0 )
     $               GO TO 90
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL clacpy( uplo, n, n, afac, lda, ainv, lda )
                  CALL cpot01( uplo, n, a, lda, ainv, lda, rwork,
     $                         result( 1 ) )
*
*+    TEST 2
*                 Form the inverse and compute the residual.
*
                  CALL clacpy( uplo, n, n, afac, lda, ainv, lda )
                  srnamt = 'CPOTRI'
                  CALL cpotri( uplo, n, ainv, lda, info )
*
*                 Check error code from CPOTRI.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CPOTRI', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL cpot03( uplo, n, a, lda, ainv, lda, work, lda,
     $                         rwork, rcondc, result( 2 ) )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 60 k = 1, 2
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
   60             CONTINUE
                  nrun = nrun + 2
*
*                 Skip the rest of the tests unless this is the first
*                 blocksize.
*
                  IF( inb.NE.1 )
     $               GO TO 90
*
                  DO 80 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 3
*                 Solve and compute residual for A * X = B .
*
                     srnamt = 'CLARHS'
                     CALL clarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     CALL clacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'CPOTRS'
                     CALL cpotrs( uplo, n, nrhs, afac, lda, x, lda,
     $                            info )
*
*                 Check error code from CPOTRS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CPOTRS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL clacpy( 'Full', n, nrhs, b, lda, work, lda )
                     CALL cpot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 3 ) )
*
*+    TEST 4
*                 Check solution from generated exact solution.
*
                     CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 4 ) )
*
*+    TESTS 5, 6, and 7
*                 Use iterative refinement to improve the solution.
*
                     srnamt = 'CPORFS'
                     CALL cporfs( uplo, n, nrhs, a, lda, afac, lda, b,
     $                            lda, x, lda, rwork, rwork( nrhs+1 ),
     $                            work, rwork( 2*nrhs+1 ), info )
*
*                 Check error code from CPORFS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'CPORFS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL cget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 5 ) )
                     CALL cpot05( uplo, n, nrhs, a, lda, b, lda, x, lda,
     $                            xact, lda, rwork, rwork( nrhs+1 ),
     $                            result( 6 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 70 k = 3, 7
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                        imat, k, result( k )
                           nfail = nfail + 1
                        END IF
   70                CONTINUE
                     nrun = nrun + 5
   80             CONTINUE
*
*+    TEST 8
*                 Get an estimate of RCOND = 1/CNDNUM.
*
                  anorm = clanhe( '1', uplo, n, a, lda, rwork )
                  srnamt = 'CPOCON'
                  CALL cpocon( uplo, n, afac, lda, anorm, rcond, work,
     $                         rwork, info )
*
*                 Check error code from CPOCON.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'CPOCON', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  result( 8 ) = sget06( rcond, rcondc )
*
*                 Print the test ratio if it is .GE. THRESH.
*
                  IF( result( 8 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 )uplo, n, imat, 8,
     $                  result( 8 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
   90          CONTINUE
  100       CONTINUE
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of CCHKPO
*

Here is the call graph for this function:

Here is the caller graph for this function: