LAPACK 3.11.0 LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
cpot03.f
Go to the documentation of this file.
1*> \brief \b CPOT03
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8* Definition:
9* ===========
10*
11* SUBROUTINE CPOT03( UPLO, N, A, LDA, AINV, LDAINV, WORK, LDWORK,
12* RWORK, RCOND, RESID )
13*
14* .. Scalar Arguments ..
15* CHARACTER UPLO
16* INTEGER LDA, LDAINV, LDWORK, N
17* REAL RCOND, RESID
18* ..
19* .. Array Arguments ..
20* REAL RWORK( * )
21* COMPLEX A( LDA, * ), AINV( LDAINV, * ),
22* \$ WORK( LDWORK, * )
23* ..
24*
25*
26*> \par Purpose:
27* =============
28*>
29*> \verbatim
30*>
31*> CPOT03 computes the residual for a Hermitian matrix times its
32*> inverse:
33*> norm( I - A*AINV ) / ( N * norm(A) * norm(AINV) * EPS ),
34*> where EPS is the machine epsilon.
35*> \endverbatim
36*
37* Arguments:
38* ==========
39*
40*> \param[in] UPLO
41*> \verbatim
42*> UPLO is CHARACTER*1
43*> Specifies whether the upper or lower triangular part of the
44*> Hermitian matrix A is stored:
45*> = 'U': Upper triangular
46*> = 'L': Lower triangular
47*> \endverbatim
48*>
49*> \param[in] N
50*> \verbatim
51*> N is INTEGER
52*> The number of rows and columns of the matrix A. N >= 0.
53*> \endverbatim
54*>
55*> \param[in] A
56*> \verbatim
57*> A is COMPLEX array, dimension (LDA,N)
58*> The original Hermitian matrix A.
59*> \endverbatim
60*>
61*> \param[in] LDA
62*> \verbatim
63*> LDA is INTEGER
64*> The leading dimension of the array A. LDA >= max(1,N)
65*> \endverbatim
66*>
67*> \param[in,out] AINV
68*> \verbatim
69*> AINV is COMPLEX array, dimension (LDAINV,N)
70*> On entry, the inverse of the matrix A, stored as a Hermitian
71*> matrix in the same format as A.
72*> In this version, AINV is expanded into a full matrix and
73*> multiplied by A, so the opposing triangle of AINV will be
74*> changed; i.e., if the upper triangular part of AINV is
75*> stored, the lower triangular part will be used as work space.
76*> \endverbatim
77*>
78*> \param[in] LDAINV
79*> \verbatim
80*> LDAINV is INTEGER
81*> The leading dimension of the array AINV. LDAINV >= max(1,N).
82*> \endverbatim
83*>
84*> \param[out] WORK
85*> \verbatim
86*> WORK is COMPLEX array, dimension (LDWORK,N)
87*> \endverbatim
88*>
89*> \param[in] LDWORK
90*> \verbatim
91*> LDWORK is INTEGER
92*> The leading dimension of the array WORK. LDWORK >= max(1,N).
93*> \endverbatim
94*>
95*> \param[out] RWORK
96*> \verbatim
97*> RWORK is REAL array, dimension (N)
98*> \endverbatim
99*>
100*> \param[out] RCOND
101*> \verbatim
102*> RCOND is REAL
103*> The reciprocal of the condition number of A, computed as
104*> ( 1/norm(A) ) / norm(AINV).
105*> \endverbatim
106*>
107*> \param[out] RESID
108*> \verbatim
109*> RESID is REAL
110*> norm(I - A*AINV) / ( N * norm(A) * norm(AINV) * EPS )
111*> \endverbatim
112*
113* Authors:
114* ========
115*
116*> \author Univ. of Tennessee
117*> \author Univ. of California Berkeley
118*> \author Univ. of Colorado Denver
119*> \author NAG Ltd.
120*
121*> \ingroup complex_lin
122*
123* =====================================================================
124 SUBROUTINE cpot03( UPLO, N, A, LDA, AINV, LDAINV, WORK, LDWORK,
125 \$ RWORK, RCOND, RESID )
126*
127* -- LAPACK test routine --
128* -- LAPACK is a software package provided by Univ. of Tennessee, --
129* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130*
131* .. Scalar Arguments ..
132 CHARACTER UPLO
133 INTEGER LDA, LDAINV, LDWORK, N
134 REAL RCOND, RESID
135* ..
136* .. Array Arguments ..
137 REAL RWORK( * )
138 COMPLEX A( LDA, * ), AINV( LDAINV, * ),
139 \$ work( ldwork, * )
140* ..
141*
142* =====================================================================
143*
144* .. Parameters ..
145 REAL ZERO, ONE
146 parameter( zero = 0.0e+0, one = 1.0e+0 )
147 COMPLEX CZERO, CONE
148 parameter( czero = ( 0.0e+0, 0.0e+0 ),
149 \$ cone = ( 1.0e+0, 0.0e+0 ) )
150* ..
151* .. Local Scalars ..
152 INTEGER I, J
153 REAL AINVNM, ANORM, EPS
154* ..
155* .. External Functions ..
156 LOGICAL LSAME
157 REAL CLANGE, CLANHE, SLAMCH
158 EXTERNAL lsame, clange, clanhe, slamch
159* ..
160* .. External Subroutines ..
161 EXTERNAL chemm
162* ..
163* .. Intrinsic Functions ..
164 INTRINSIC conjg, real
165* ..
166* .. Executable Statements ..
167*
168* Quick exit if N = 0.
169*
170 IF( n.LE.0 ) THEN
171 rcond = one
172 resid = zero
173 RETURN
174 END IF
175*
176* Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
177*
178 eps = slamch( 'Epsilon' )
179 anorm = clanhe( '1', uplo, n, a, lda, rwork )
180 ainvnm = clanhe( '1', uplo, n, ainv, ldainv, rwork )
181 IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
182 rcond = zero
183 resid = one / eps
184 RETURN
185 END IF
186 rcond = ( one/anorm ) / ainvnm
187*
188* Expand AINV into a full matrix and call CHEMM to multiply
189* AINV on the left by A.
190*
191 IF( lsame( uplo, 'U' ) ) THEN
192 DO 20 j = 1, n
193 DO 10 i = 1, j - 1
194 ainv( j, i ) = conjg( ainv( i, j ) )
195 10 CONTINUE
196 20 CONTINUE
197 ELSE
198 DO 40 j = 1, n
199 DO 30 i = j + 1, n
200 ainv( j, i ) = conjg( ainv( i, j ) )
201 30 CONTINUE
202 40 CONTINUE
203 END IF
204 CALL chemm( 'Left', uplo, n, n, -cone, a, lda, ainv, ldainv,
205 \$ czero, work, ldwork )
206*
207* Add the identity matrix to WORK .
208*
209 DO 50 i = 1, n
210 work( i, i ) = work( i, i ) + cone
211 50 CONTINUE
212*
213* Compute norm(I - A*AINV) / (N * norm(A) * norm(AINV) * EPS)
214*
215 resid = clange( '1', n, n, work, ldwork, rwork )
216*
217 resid = ( ( resid*rcond )/eps ) / real( n )
218*
219 RETURN
220*
221* End of CPOT03
222*
223 END
subroutine chemm(SIDE, UPLO, M, N, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
CHEMM
Definition: chemm.f:191
subroutine cpot03(UPLO, N, A, LDA, AINV, LDAINV, WORK, LDWORK, RWORK, RCOND, RESID)
CPOT03
Definition: cpot03.f:126