clarhs()

subroutine clarhs	(	character*3	path,
		character	xtype,
		character	uplo,
		character	trans,
		integer	m,
		integer	n,
		integer	kl,
		integer	ku,
		integer	nrhs,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		complex, dimension( ldb, * )	b,
		integer	ldb,
		integer, dimension( 4 )	iseed,
		integer	info )

CLARHS

Purpose:

!>
!> CLARHS chooses a set of NRHS random solution vectors and sets
!> up the right hand sides for the linear system
!>    op(A) * X = B,
!> where op(A) = A, A**T or A**H, depending on TRANS.
!> 

Parameters

[in]	PATH	!> PATH is CHARACTER*3 !> The type of the complex matrix A. PATH may be given in any !> combination of upper and lower case. Valid paths include !> xGE: General m x n matrix !> xGB: General banded matrix !> xPO: Hermitian positive definite, 2-D storage !> xPP: Hermitian positive definite packed !> xPB: Hermitian positive definite banded !> xHE: Hermitian indefinite, 2-D storage !> xHP: Hermitian indefinite packed !> xHB: Hermitian indefinite banded !> xSY: Symmetric indefinite, 2-D storage !> xSP: Symmetric indefinite packed !> xSB: Symmetric indefinite banded !> xTR: Triangular !> xTP: Triangular packed !> xTB: Triangular banded !> xQR: General m x n matrix !> xLQ: General m x n matrix !> xQL: General m x n matrix !> xRQ: General m x n matrix !> where the leading character indicates the precision. !>
[in]	XTYPE	!> XTYPE is CHARACTER*1 !> Specifies how the exact solution X will be determined: !> = 'N': New solution; generate a random X. !> = 'C': Computed; use value of X on entry. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> Used only if A is symmetric or triangular; specifies whether !> the upper or lower triangular part of the matrix A is stored. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Used only if A is nonsymmetric; specifies the operation !> applied to the matrix A. !> = 'N': B := A * X (No transpose) !> = 'T': B := A**T * X (Transpose) !> = 'C': B := A**H * X (Conjugate transpose) !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix A. N >= 0. !>
[in]	KL	!> KL is INTEGER !> Used only if A is a band matrix; specifies the number of !> subdiagonals of A if A is a general band matrix or if A is !> symmetric or triangular and UPLO = 'L'; specifies the number !> of superdiagonals of A if A is symmetric or triangular and !> UPLO = 'U'. 0 <= KL <= M-1. !>
[in]	KU	!> KU is INTEGER !> Used only if A is a general band matrix or if A is !> triangular. !> !> If PATH = xGB, specifies the number of superdiagonals of A, !> and 0 <= KU <= N-1. !> !> If PATH = xTR, xTP, or xTB, specifies whether or not the !> matrix has unit diagonal: !> = 1: matrix has non-unit diagonal (default) !> = 2: matrix has unit diagonal !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand side vectors in the system A*X = B. !>
[in]	A	!> A is COMPLEX array, dimension (LDA,N) !> The test matrix whose type is given by PATH. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. !> If PATH = xGB, LDA >= KL+KU+1. !> If PATH = xPB, xSB, xHB, or xTB, LDA >= KL+1. !> Otherwise, LDA >= max(1,M). !>
[in,out]	X	!> X is or output) COMPLEX array, dimension (LDX,NRHS) !> On entry, if XTYPE = 'C' (for 'Computed'), then X contains !> the exact solution to the system of linear equations. !> On exit, if XTYPE = 'N' (for 'New'), then X is initialized !> with random values. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. If TRANS = 'N', !> LDX >= max(1,N); if TRANS = 'T', LDX >= max(1,M). !>
[out]	B	!> B is COMPLEX array, dimension (LDB,NRHS) !> The right hand side vector(s) for the system of equations, !> computed from B = op(A) * X, where op(A) is determined by !> TRANS. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. If TRANS = 'N', !> LDB >= max(1,M); if TRANS = 'T', LDB >= max(1,N). !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> The seed vector for the random number generator (used in !> CLATMS). Modified on exit. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 206 of file clarhs.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            INFO, KL, KU, LDA, LDB, LDX, M, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      COMPLEX            A( LDA, * ), B( LDB, * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE, ZERO
      parameter( one = ( 1.0e+0, 0.0e+0 ),
     $                   zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            BAND, GEN, NOTRAN, QRS, SYM, TRAN, TRI
      CHARACTER          C1, DIAG
      CHARACTER*2        C2
      INTEGER            J, MB, NX
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, LSAMEN
      EXTERNAL           lsame, lsamen
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgbmv, cgemm, chbmv, chemm, chpmv, clacpy,
     $                   clarnv, csbmv, cspmv, csymm, ctbmv, ctpmv,
     $                   ctrmm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      c1 = path( 1: 1 )
      c2 = path( 2: 3 )
      tran = lsame( trans, 'T' ) .OR. lsame( trans, 'C' )
      notran = .NOT.tran
      gen = lsame( path( 2: 2 ), 'G' )
      qrs = lsame( path( 2: 2 ), 'Q' ) .OR. lsame( path( 3: 3 ), 'Q' )
      sym = lsame( path( 2: 2 ), 'P' ) .OR.
     $      lsame( path( 2: 2 ), 'S' ) .OR. lsame( path( 2: 2 ), 'H' )
      tri = lsame( path( 2: 2 ), 'T' )
      band = lsame( path( 3: 3 ), 'B' )
      IF( .NOT.lsame( c1, 'Complex precision' ) ) THEN
         info = -1
      ELSE IF( .NOT.( lsame( xtype, 'N' ) .OR. lsame( xtype, 'C' ) ) )
     $          THEN
         info = -2
      ELSE IF( ( sym .OR. tri ) .AND. .NOT.
     $         ( lsame( uplo, 'U' ) .OR. lsame( uplo, 'L' ) ) ) THEN
         info = -3
      ELSE IF( ( gen.OR.qrs ) .AND.
     $   .NOT.( tran .OR. lsame( trans, 'N' ) ) ) THEN
         info = -4
      ELSE IF( m.LT.0 ) THEN
         info = -5
      ELSE IF( n.LT.0 ) THEN
         info = -6
      ELSE IF( band .AND. kl.LT.0 ) THEN
         info = -7
      ELSE IF( band .AND. ku.LT.0 ) THEN
         info = -8
      ELSE IF( nrhs.LT.0 ) THEN
         info = -9
      ELSE IF( ( .NOT.band .AND. lda.LT.max( 1, m ) ) .OR.
     $         ( band .AND. ( sym .OR. tri ) .AND. lda.LT.kl+1 ) .OR.
     $         ( band .AND. gen .AND. lda.LT.kl+ku+1 ) ) THEN
         info = -11
      ELSE IF( ( notran .AND. ldx.LT.max( 1, n ) ) .OR.
     $         ( tran .AND. ldx.LT.max( 1, m ) ) ) THEN
         info = -13
      ELSE IF( ( notran .AND. ldb.LT.max( 1, m ) ) .OR.
     $         ( tran .AND. ldb.LT.max( 1, n ) ) ) THEN
         info = -15
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLARHS', -info )
         RETURN
      END IF
*
*     Initialize X to NRHS random vectors unless XTYPE = 'C'.
*
      IF( tran ) THEN
         nx = m
         mb = n
      ELSE
         nx = n
         mb = m
      END IF
      IF( .NOT.lsame( xtype, 'C' ) ) THEN
         DO 10 j = 1, nrhs
            CALL clarnv( 2, iseed, n, x( 1, j ) )
   10    CONTINUE
      END IF
*
*     Multiply X by op(A) using an appropriate
*     matrix multiply routine.
*
      IF( lsamen( 2, c2, 'GE' ) .OR. lsamen( 2, c2, 'QR' ) .OR.
     $    lsamen( 2, c2, 'LQ' ) .OR. lsamen( 2, c2, 'QL' ) .OR.
     $    lsamen( 2, c2, 'RQ' ) ) THEN
*
*        General matrix
*
         CALL cgemm( trans, 'N', mb, nrhs, nx, one, a, lda, x, ldx,
     $               zero, b, ldb )
*
      ELSE IF( lsamen( 2, c2, 'PO' ) .OR. lsamen( 2, c2, 'HE' ) ) THEN
*
*        Hermitian matrix, 2-D storage
*
         CALL chemm( 'Left', uplo, n, nrhs, one, a, lda, x, ldx, zero,
     $               b, ldb )
*
      ELSE IF( lsamen( 2, c2, 'SY' ) ) THEN
*
*        Symmetric matrix, 2-D storage
*
         CALL csymm( 'Left', uplo, n, nrhs, one, a, lda, x, ldx, zero,
     $               b, ldb )
*
      ELSE IF( lsamen( 2, c2, 'GB' ) ) THEN
*
*        General matrix, band storage
*
         DO 20 j = 1, nrhs
            CALL cgbmv( trans, m, n, kl, ku, one, a, lda, x( 1, j ), 1,
     $                  zero, b( 1, j ), 1 )
   20    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'PB' ) .OR. lsamen( 2, c2, 'HB' ) ) THEN
*
*        Hermitian matrix, band storage
*
         DO 30 j = 1, nrhs
            CALL chbmv( uplo, n, kl, one, a, lda, x( 1, j ), 1, zero,
     $                  b( 1, j ), 1 )
   30    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'SB' ) ) THEN
*
*        Symmetric matrix, band storage
*
         DO 40 j = 1, nrhs
            CALL csbmv( uplo, n, kl, one, a, lda, x( 1, j ), 1, zero,
     $                  b( 1, j ), 1 )
   40    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'PP' ) .OR. lsamen( 2, c2, 'HP' ) ) THEN
*
*        Hermitian matrix, packed storage
*
         DO 50 j = 1, nrhs
            CALL chpmv( uplo, n, one, a, x( 1, j ), 1, zero, b( 1, j ),
     $                  1 )
   50    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'SP' ) ) THEN
*
*        Symmetric matrix, packed storage
*
         DO 60 j = 1, nrhs
            CALL cspmv( uplo, n, one, a, x( 1, j ), 1, zero, b( 1, j ),
     $                  1 )
   60    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'TR' ) ) THEN
*
*        Triangular matrix.  Note that for triangular matrices,
*           KU = 1 => non-unit triangular
*           KU = 2 => unit triangular
*
         CALL clacpy( 'Full', n, nrhs, x, ldx, b, ldb )
         IF( ku.EQ.2 ) THEN
            diag = 'U'
         ELSE
            diag = 'N'
         END IF
         CALL ctrmm( 'Left', uplo, trans, diag, n, nrhs, one, a, lda, b,
     $               ldb )
*
      ELSE IF( lsamen( 2, c2, 'TP' ) ) THEN
*
*        Triangular matrix, packed storage
*
         CALL clacpy( 'Full', n, nrhs, x, ldx, b, ldb )
         IF( ku.EQ.2 ) THEN
            diag = 'U'
         ELSE
            diag = 'N'
         END IF
         DO 70 j = 1, nrhs
            CALL ctpmv( uplo, trans, diag, n, a, b( 1, j ), 1 )
   70    CONTINUE
*
      ELSE IF( lsamen( 2, c2, 'TB' ) ) THEN
*
*        Triangular matrix, banded storage
*
         CALL clacpy( 'Full', n, nrhs, x, ldx, b, ldb )
         IF( ku.EQ.2 ) THEN
            diag = 'U'
         ELSE
            diag = 'N'
         END IF
         DO 80 j = 1, nrhs
            CALL ctbmv( uplo, trans, diag, n, kl, a, lda, b( 1, j ), 1 )
   80    CONTINUE
*
      ELSE
*
*        If none of the above, set INFO = -1 and return
*
         info = -1
         CALL xerbla( 'CLARHS', -info )
      END IF
*
      RETURN
*
*     End of CLARHS
*

Here is the call graph for this function:

Here is the caller graph for this function: