dgemlq()

subroutine dgemlq	(	character	side,
		character	trans,
		integer	m,
		integer	n,
		integer	k,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	t,
		integer	tsize,
		double precision, dimension( ldc, * )	c,
		integer	ldc,
		double precision, dimension( * )	work,
		integer	lwork,
		integer	info )

DGEMLQ

Purpose:

!>
!>     DGEMLQ overwrites the general real M-by-N matrix C with
!>
!>                    SIDE = 'L'     SIDE = 'R'
!>    TRANS = 'N':      Q * C          C * Q
!>    TRANS = 'T':      Q**T * C       C * Q**T
!>    where Q is a real orthogonal matrix defined as the product
!>    of blocked elementary reflectors computed by short wide LQ
!>    factorization (DGELQ)
!>
!> 

Parameters

[in]	SIDE	!> SIDE is CHARACTER*1 !> = 'L': apply Q or Q**T from the Left; !> = 'R': apply Q or Q**T from the Right. !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> = 'N': No transpose, apply Q; !> = 'T': Transpose, apply Q**T. !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. M >=0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix C. N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines !> the matrix Q. !> If SIDE = 'L', M >= K >= 0; !> if SIDE = 'R', N >= K >= 0. !> !>
[in]	A	!> A is DOUBLE PRECISION array, dimension !> (LDA,M) if SIDE = 'L', !> (LDA,N) if SIDE = 'R' !> Part of the data structure to represent Q as returned by DGELQ. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,K). !>
[in]	T	!> T is DOUBLE PRECISION array, dimension (MAX(5,TSIZE)). !> Part of the data structure to represent Q as returned by DGELQ. !>
[in]	TSIZE	!> TSIZE is INTEGER !> The dimension of the array T. TSIZE >= 5. !>
[in,out]	C	!> C is DOUBLE PRECISION array, dimension (LDC,N) !> On entry, the M-by-N matrix C. !> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q. !>
[in]	LDC	!> LDC is INTEGER !> The leading dimension of the array C. LDC >= max(1,M). !>
[out]	WORK	!> (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the minimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= 1. !> If LWORK = -1, then a workspace query is assumed. The routine !> only calculates the size of the WORK array, returns this !> value as WORK(1), and no error message related to WORK !> is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details

!>
!> These details are particular for this LAPACK implementation. Users should not
!> take them for granted. These details may change in the future, and are not likely
!> true for another LAPACK implementation. These details are relevant if one wants
!> to try to understand the code. They are not part of the interface.
!>
!> In this version,
!>
!>          T(2): row block size (MB)
!>          T(3): column block size (NB)
!>          T(6:TSIZE): data structure needed for Q, computed by
!>                           DLASWLQ or DGELQT
!>
!>  Depending on the matrix dimensions M and N, and row and column
!>  block sizes MB and NB returned by ILAENV, DGELQ will use either
!>  DLASWLQ (if the matrix is wide-and-short) or DGELQT to compute
!>  the LQ factorization.
!>  This version of DGEMLQ will use either DLAMSWLQ or DGEMLQT to
!>  multiply matrix Q by another matrix.
!>  Further Details in DLAMSWLQ or DGEMLQT.
!> 

Definition at line 172 of file dgemlq.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, LDA, M, N, K, TSIZE, LWORK, LDC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), T( * ), C( LDC, * ), WORK( * )
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFT, RIGHT, TRAN, NOTRAN, LQUERY
      INTEGER            MB, NB, LW, NBLCKS, MN, MINMNK, LWMIN
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlamswlq, dgemlqt, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          int, max, min, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      lquery  = ( lwork.EQ.-1 )
      notran  = lsame( trans, 'N' )
      tran    = lsame( trans, 'T' )
      left    = lsame( side, 'L' )
      right   = lsame( side, 'R' )
*
      mb = int( t( 2 ) )
      nb = int( t( 3 ) )
      IF( left ) THEN
        lw = n * mb
        mn = m
      ELSE
        lw = m * mb
        mn = n
      END IF
*
      minmnk = min( m, n, k )
      IF( minmnk.EQ.0 ) THEN
         lwmin = 1
      ELSE
         lwmin = max( 1, lw )
      END IF
*
      IF( ( nb.GT.k ) .AND. ( mn.GT.k ) ) THEN
        IF( mod( mn - k, nb - k ) .EQ. 0 ) THEN
          nblcks = ( mn - k ) / ( nb - k )
        ELSE
          nblcks = ( mn - k ) / ( nb - k ) + 1
        END IF
      ELSE
        nblcks = 1
      END IF
*
      info = 0
      IF( .NOT.left .AND. .NOT.right ) THEN
        info = -1
      ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
        info = -2
      ELSE IF( m.LT.0 ) THEN
        info = -3
      ELSE IF( n.LT.0 ) THEN
        info = -4
      ELSE IF( k.LT.0 .OR. k.GT.mn ) THEN
        info = -5
      ELSE IF( lda.LT.max( 1, k ) ) THEN
        info = -7
      ELSE IF( tsize.LT.5 ) THEN
        info = -9
      ELSE IF( ldc.LT.max( 1, m ) ) THEN
        info = -11
      ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
        info = -13
      END IF
*
      IF( info.EQ.0 ) THEN
        work( 1 ) = lwmin
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'DGEMLQ', -info )
        RETURN
      ELSE IF( lquery ) THEN
        RETURN
      END IF
*
*     Quick return if possible
*
      IF( minmnk.EQ.0 ) THEN
        RETURN
      END IF
*
      IF( ( left .AND. m.LE.k ) .OR. ( right .AND. n.LE.k )
     $     .OR. ( nb.LE.k ) .OR. ( nb.GE.max( m, n, k ) ) ) THEN
        CALL dgemlqt( side, trans, m, n, k, mb, a, lda,
     $                t( 6 ), mb, c, ldc, work, info )
      ELSE
        CALL dlamswlq( side, trans, m, n, k, mb, nb, a, lda, t( 6 ),
     $                 mb, c, ldc, work, lwork, info )
      END IF
*
      work( 1 ) = lwmin
*
      RETURN
*
*     End of DGEMLQ
*

Here is the call graph for this function:

Here is the caller graph for this function: