schkgt.f

Go to the documentation of this file.

*> \brief \b SCHKGT
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKGT( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          A, AF, B, X, XACT, WORK, RWORK, IWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NN, NNS, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
*       REAL               A( * ), AF( * ), B( * ), RWORK( * ), WORK( * ),
*      $                   X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKGT tests SGTTRF, -TRS, -RFS, and -CON
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (NMAX*4)
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is REAL array, dimension (NMAX*4)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension
*>                      (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (2*NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE schkgt( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   A, AF, B, X, XACT, WORK, RWORK, IWORK, NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
      REAL               A( * ), AF( * ), B( * ), RWORK( * ), WORK( * ),
     $                   x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter( ntypes = 12 )
      INTEGER            NTESTS
      parameter( ntests = 7 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, NORM, TRANS, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IMAT, IN, INFO, IRHS, ITRAN, IX, IZERO, J,
     $                   k, kl, koff, ku, lda, m, mode, n, nerrs, nfail,
     $                   nimat, nrhs, nrun
      REAL               AINVNM, ANORM, COND, RCOND, RCONDC, RCONDI,
     $                   rcondo
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( 3 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS ), Z( 3 )
*     ..
*     .. External Functions ..
      REAL               SASUM, SGET06, SLANGT
      EXTERNAL           sasum, sget06, slangt
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, scopy, serrge, sget04,
     $                   sgtcon, sgtrfs, sgtt01, sgtt02, sgtt05, sgttrf,
     $                   sgttrs, slacpy, slagtm, slarnv, slatb4, slatms,
     $                   sscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 / , transs / 'N', 'T',
     $                   'C' /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'GT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrge( path, nout )
      infot = 0
*
      DO 110 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         m = max( n-1, 0 )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 100 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 100
*
*           Set up parameters with SLATB4.
*
            CALL slatb4( path, imat, n, n, TYPE, kl, ku, anorm, mode,
     $                   cond, dist )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Types 1-6:  generate matrices of known condition number.
*
               koff = max( 2-ku, 3-max( 1, n ) )
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, rwork, mode, cond,
     $                      anorm, kl, ku, 'Z', af( koff ), 3, work,
     $                      info )
*
*              Check the error code from SLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 100
               END IF
               izero = 0
*
               IF( n.GT.1 ) THEN
                  CALL scopy( n-1, af( 4 ), 3, a, 1 )
                  CALL scopy( n-1, af( 3 ), 3, a( n+m+1 ), 1 )
               END IF
               CALL scopy( n, af( 2 ), 3, a( m+1 ), 1 )
            ELSE
*
*              Types 7-12:  generate tridiagonal matrices with
*              unknown condition numbers.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Generate a matrix with elements from [-1,1].
*
                  CALL slarnv( 2, iseed, n+2*m, a )
                  IF( anorm.NE.one )
     $               CALL sscal( n+2*m, anorm, a, 1 )
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     a( n ) = z( 2 )
                     IF( n.GT.1 )
     $                  a( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     a( 3*n-2 ) = z( 1 )
                     a( 2*n-1 ) = z( 2 )
                  ELSE
                     a( 2*n-2+izero ) = z( 1 )
                     a( n-1+izero ) = z( 2 )
                     a( izero ) = z( 3 )
                  END IF
               END IF
*
*              If IMAT > 7, set one column of the matrix to 0.
*
               IF( .NOT.zerot ) THEN
                  izero = 0
               ELSE IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = a( n )
                  a( n ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = a( 1 )
                     a( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  z( 1 ) = a( 3*n-2 )
                  z( 2 ) = a( 2*n-1 )
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               ELSE
                  izero = ( n+1 ) / 2
                  DO 20 i = izero, n - 1
                     a( 2*n-2+i ) = zero
                     a( n-1+i ) = zero
                     a( i ) = zero
   20             CONTINUE
                  a( 3*n-2 ) = zero
                  a( 2*n-1 ) = zero
               END IF
            END IF
*
*+    TEST 1
*           Factor A as L*U and compute the ratio
*              norm(L*U - A) / (n * norm(A) * EPS )
*
            CALL scopy( n+2*m, a, 1, af, 1 )
            srnamt = 'SGTTRF'
            CALL sgttrf( n, af, af( m+1 ), af( n+m+1 ), af( n+2*m+1 ),
     $                   iwork, info )
*
*           Check error code from SGTTRF.
*
            IF( info.NE.izero )
     $         CALL alaerh( path, 'SGTTRF', info, izero, ' ', n, n, 1,
     $                      1, -1, imat, nfail, nerrs, nout )
            trfcon = info.NE.0
*
            CALL sgtt01( n, a, a( m+1 ), a( n+m+1 ), af, af( m+1 ),
     $                   af( n+m+1 ), af( n+2*m+1 ), iwork, work, lda,
     $                   rwork, result( 1 ) )
*
*           Print the test ratio if it is .GE. THRESH.
*
            IF( result( 1 ).GE.thresh ) THEN
               IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $            CALL alahd( nout, path )
               WRITE( nout, fmt = 9999 )n, imat, 1, result( 1 )
               nfail = nfail + 1
            END IF
            nrun = nrun + 1
*
            DO 50 itran = 1, 2
               trans = transs( itran )
               IF( itran.EQ.1 ) THEN
                  norm = 'O'
               ELSE
                  norm = 'I'
               END IF
               anorm = slangt( norm, n, a, a( m+1 ), a( n+m+1 ) )
*
               IF( .NOT.trfcon ) THEN
*
*                 Use SGTTRS to solve for one column at a time of inv(A)
*                 or inv(A^T), computing the maximum column sum as we
*                 go.
*
                  ainvnm = zero
                  DO 40 i = 1, n
                     DO 30 j = 1, n
                        x( j ) = zero
   30                CONTINUE
                     x( i ) = one
                     CALL sgttrs( trans, n, 1, af, af( m+1 ),
     $                            af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                            lda, info )
                     ainvnm = max( ainvnm, sasum( n, x, 1 ) )
   40             CONTINUE
*
*                 Compute RCONDC = 1 / (norm(A) * norm(inv(A))
*
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondc = one
                  ELSE
                     rcondc = ( one / anorm ) / ainvnm
                  END IF
                  IF( itran.EQ.1 ) THEN
                     rcondo = rcondc
                  ELSE
                     rcondi = rcondc
                  END IF
               ELSE
                  rcondc = zero
               END IF
*
*+    TEST 7
*              Estimate the reciprocal of the condition number of the
*              matrix.
*
               srnamt = 'SGTCON'
               CALL sgtcon( norm, n, af, af( m+1 ), af( n+m+1 ),
     $                      af( n+2*m+1 ), iwork, anorm, rcond, work,
     $                      iwork( n+1 ), info )
*
*              Check error code from SGTCON.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'SGTCON', info, 0, norm, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
               result( 7 ) = sget06( rcond, rcondc )
*
*              Print the test ratio if it is .GE. THRESH.
*
               IF( result( 7 ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  WRITE( nout, fmt = 9997 )norm, n, imat, 7,
     $               result( 7 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
   50       CONTINUE
*
*           Skip the remaining tests if the matrix is singular.
*
            IF( trfcon )
     $         GO TO 100
*
            DO 90 irhs = 1, nns
               nrhs = nsval( irhs )
*
*              Generate NRHS random solution vectors.
*
               ix = 1
               DO 60 j = 1, nrhs
                  CALL slarnv( 2, iseed, n, xact( ix ) )
                  ix = ix + lda
   60          CONTINUE
*
               DO 80 itran = 1, 3
                  trans = transs( itran )
                  IF( itran.EQ.1 ) THEN
                     rcondc = rcondo
                  ELSE
                     rcondc = rcondi
                  END IF
*
*                 Set the right hand side.
*
                  CALL slagtm( trans, n, nrhs, one, a, a( m+1 ),
     $                         a( n+m+1 ), xact, lda, zero, b, lda )
*
*+    TEST 2
*                 Solve op(A) * X = B and compute the residual.
*
                  CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
                  srnamt = 'SGTTRS'
                  CALL sgttrs( trans, n, nrhs, af, af( m+1 ),
     $                         af( n+m+1 ), af( n+2*m+1 ), iwork, x,
     $                         lda, info )
*
*                 Check error code from SGTTRS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'SGTTRS', info, 0, trans, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
                  CALL sgtt02( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         x, lda, work, lda, result( 2 ) )
*
*+    TEST 3
*                 Check solution from generated exact solution.
*
                  CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 3 ) )
*
*+    TESTS 4, 5, and 6
*                 Use iterative refinement to improve the solution.
*
                  srnamt = 'SGTRFS'
                  CALL sgtrfs( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         af, af( m+1 ), af( n+m+1 ),
     $                         af( n+2*m+1 ), iwork, b, lda, x, lda,
     $                         rwork, rwork( nrhs+1 ), work,
     $                         iwork( n+1 ), info )
*
*                 Check error code from SGTRFS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'SGTRFS', info, 0, trans, n, n,
     $                            -1, -1, nrhs, imat, nfail, nerrs,
     $                            nout )
*
                  CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 4 ) )
                  CALL sgtt05( trans, n, nrhs, a, a( m+1 ), a( n+m+1 ),
     $                         b, lda, x, lda, xact, lda, rwork,
     $                         rwork( nrhs+1 ), result( 5 ) )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 70 k = 2, 6
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 )trans, n, nrhs, imat,
     $                     k, result( k )
                        nfail = nfail + 1
                     END IF
   70             CONTINUE
                  nrun = nrun + 5
   80          CONTINUE
   90       CONTINUE
*
  100    CONTINUE
  110 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 12x, 'N =', i5, ',', 10x, ' type ', i2, ', test(', i2,
     $      ') = ', g12.5 )
 9998 FORMAT( ' TRANS=''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') = ', g12.5 )
 9997 FORMAT( ' NORM =''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') = ', g12.5 )
      RETURN
*
*     End of SCHKGT
*
      END