slarnv()

subroutine slarnv	(	integer	idist,
		integer, dimension( 4 )	iseed,
		integer	n,
		real, dimension( * )	x )

SLARNV returns a vector of random numbers from a uniform or normal distribution.

Download SLARNV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SLARNV returns a vector of n random real numbers from a uniform or
!> normal distribution.
!> 

Parameters

[in]	IDIST	!> IDIST is INTEGER !> Specifies the distribution of the random numbers: !> = 1: uniform (0,1) !> = 2: uniform (-1,1) !> = 3: normal (0,1) !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry, the seed of the random number generator; the array !> elements must be between 0 and 4095, and ISEED(4) must be !> odd. !> On exit, the seed is updated. !>
[in]	N	!> N is INTEGER !> The number of random numbers to be generated. !>
[out]	X	!> X is REAL array, dimension (N) !> The generated random numbers. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  This routine calls the auxiliary routine SLARUV to generate random
!>  real numbers from a uniform (0,1) distribution, in batches of up to
!>  128 using vectorisable code. The Box-Muller method is used to
!>  transform numbers from a uniform to a normal distribution.
!> 

Definition at line 94 of file slarnv.f.

*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            IDIST, N
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      REAL               X( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TWO
      parameter( one = 1.0e+0, two = 2.0e+0 )
      INTEGER            LV
      parameter( lv = 128 )
      REAL               TWOPI
      parameter( twopi = 6.28318530717958647692528676655900576839e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IL, IL2, IV
*     ..
*     .. Local Arrays ..
      REAL               U( LV )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cos, log, min, sqrt
*     ..
*     .. External Subroutines ..
      EXTERNAL           slaruv
*     ..
*     .. Executable Statements ..
*
      DO 40 iv = 1, n, lv / 2
         il = min( lv / 2, n-iv+1 )
         IF( idist.EQ.3 ) THEN
            il2 = 2*il
         ELSE
            il2 = il
         END IF
*
*        Call SLARUV to generate IL2 numbers from a uniform (0,1)
*        distribution (IL2 <= LV)
*
         CALL slaruv( iseed, il2, u )
*
         IF( idist.EQ.1 ) THEN
*
*           Copy generated numbers
*
            DO 10 i = 1, il
               x( iv+i-1 ) = u( i )
   10       CONTINUE
         ELSE IF( idist.EQ.2 ) THEN
*
*           Convert generated numbers to uniform (-1,1) distribution
*
            DO 20 i = 1, il
               x( iv+i-1 ) = two*u( i ) - one
   20       CONTINUE
         ELSE IF( idist.EQ.3 ) THEN
*
*           Convert generated numbers to normal (0,1) distribution
*
            DO 30 i = 1, il
               x( iv+i-1 ) = sqrt( -two*log( u( 2*i-1 ) ) )*
     $                       cos( twopi*u( 2*i ) )
   30       CONTINUE
         END IF
   40 CONTINUE
      RETURN
*
*     End of SLARNV
*

Here is the call graph for this function:

Here is the caller graph for this function: