sgtt02()

subroutine sgtt02	(	character	trans,
		integer	n,
		integer	nrhs,
		real, dimension( * )	dl,
		real, dimension( * )	d,
		real, dimension( * )	du,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real	resid
	)

SGTT02

Purpose:

 SGTT02 computes the residual for the solution to a tridiagonal
 system of equations:
    RESID = norm(B - op(A)*X) / (norm(op(A)) * norm(X) * EPS),
 where EPS is the machine epsilon.
 The norm used is the 1-norm.

Parameters

[in]	TRANS	TRANS is CHARACTER Specifies the form of the residual. = 'N': B - A * X (No transpose) = 'T': B - A**T * X (Transpose) = 'C': B - A**H * X (Conjugate transpose = Transpose)
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices B and X. NRHS >= 0.
[in]	DL	DL is REAL array, dimension (N-1) The (n-1) sub-diagonal elements of A.
[in]	D	D is REAL array, dimension (N) The diagonal elements of A.
[in]	DU	DU is REAL array, dimension (N-1) The (n-1) super-diagonal elements of A.
[in]	X	X is REAL array, dimension (LDX,NRHS) The computed solution vectors X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(1,N).
[in,out]	B	B is REAL array, dimension (LDB,NRHS) On entry, the right hand side vectors for the system of linear equations. On exit, B is overwritten with the difference B - op(A)*X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	RESID	RESID is REAL norm(B - op(A)*X) / (norm(op(A)) * norm(X) * EPS)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 123 of file sgtt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDB, LDX, N, NRHS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               B( LDB, * ), D( * ), DL( * ), DU( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      REAL               ANORM, BNORM, EPS, XNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SASUM, SLAMCH, SLANGT
      EXTERNAL           lsame, sasum, slamch, slangt
*     ..
*     .. External Subroutines ..
      EXTERNAL           slagtm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0
*
      resid = zero
      IF( n.LE.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Compute the maximum over the number of right hand sides of
*        norm(B - op(A)*X) / ( norm(op(A)) * norm(X) * EPS ).
*
      IF( lsame( trans, 'N' ) ) THEN
         anorm = slangt( '1', n, dl, d, du )
      ELSE
         anorm = slangt( 'I', n, dl, d, du )
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute B - op(A)*X and store in B.
*
      CALL slagtm( trans, n, nrhs, -one, dl, d, du, x, ldx, one, b,
     $             ldb )
*
      DO 10 j = 1, nrhs
         bnorm = sasum( n, b( 1, j ), 1 )
         xnorm = sasum( n, x( 1, j ), 1 )
         IF( xnorm.LE.zero ) THEN
            resid = one / eps
         ELSE
            resid = max( resid, ( ( bnorm / anorm ) / xnorm ) / eps )
         END IF
   10 CONTINUE
*
      RETURN
*
*     End of SGTT02
*

Here is the call graph for this function:

Here is the caller graph for this function: