sgtt05()

subroutine sgtt05	(	character	trans,
		integer	n,
		integer	nrhs,
		real, dimension( * )	dl,
		real, dimension( * )	d,
		real, dimension( * )	du,
		real, dimension( ldb, * )	b,
		integer	ldb,
		real, dimension( ldx, * )	x,
		integer	ldx,
		real, dimension( ldxact, * )	xact,
		integer	ldxact,
		real, dimension( * )	ferr,
		real, dimension( * )	berr,
		real, dimension( * )	reslts )

SGTT05

Purpose:

!>
!> SGTT05 tests the error bounds from iterative refinement for the
!> computed solution to a system of equations A*X = B, where A is a
!> general tridiagonal matrix of order n and op(A) = A or A**T,
!> depending on TRANS.
!>
!> RESLTS(1) = test of the error bound
!>           = norm(X - XACT) / ( norm(X) * FERR )
!>
!> A large value is returned if this ratio is not less than one.
!>
!> RESLTS(2) = residual from the iterative refinement routine
!>           = the maximum of BERR / ( NZ*EPS + (*) ), where
!>             (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
!>             and NZ = max. number of nonzeros in any row of A, plus 1
!> 

Parameters

[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations. !> = 'N': A * X = B (No transpose) !> = 'T': A**T * X = B (Transpose) !> = 'C': A**H * X = B (Conjugate transpose = Transpose) !>
[in]	N	!> N is INTEGER !> The number of rows of the matrices X and XACT. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of the matrices X and XACT. NRHS >= 0. !>
[in]	DL	!> DL is REAL array, dimension (N-1) !> The (n-1) sub-diagonal elements of A. !>
[in]	D	!> D is REAL array, dimension (N) !> The diagonal elements of A. !>
[in]	DU	!> DU is REAL array, dimension (N-1) !> The (n-1) super-diagonal elements of A. !>
[in]	B	!> B is REAL array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	X	!> X is REAL array, dimension (LDX,NRHS) !> The computed solution vectors. Each vector is stored as a !> column of the matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	XACT	!> XACT is REAL array, dimension (LDX,NRHS) !> The exact solution vectors. Each vector is stored as a !> column of the matrix XACT. !>
[in]	LDXACT	!> LDXACT is INTEGER !> The leading dimension of the array XACT. LDXACT >= max(1,N). !>
[in]	FERR	!> FERR is REAL array, dimension (NRHS) !> The estimated forward error bounds for each solution vector !> X. If XTRUE is the true solution, FERR bounds the magnitude !> of the largest entry in (X - XTRUE) divided by the magnitude !> of the largest entry in X. !>
[in]	BERR	!> BERR is REAL array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector (i.e., the smallest relative change in any entry of A !> or B that makes X an exact solution). !>
[out]	RESLTS	!> RESLTS is REAL array, dimension (2) !> The maximum over the NRHS solution vectors of the ratios: !> RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR ) !> RESLTS(2) = BERR / ( NZ*EPS + (*) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 163 of file sgtt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            LDB, LDX, LDXACT, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               B( LDB, * ), BERR( * ), D( * ), DL( * ),
     $                   DU( * ), FERR( * ), RESLTS( * ), X( LDX, * ),
     $                   XACT( LDXACT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN
      INTEGER            I, IMAX, J, K, NZ
      REAL               AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX
      REAL               SLAMCH
      EXTERNAL           lsame, isamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         RETURN
      END IF
*
      eps = slamch( 'Epsilon' )
      unfl = slamch( 'Safe minimum' )
      ovfl = one / unfl
      notran = lsame( trans, 'N' )
      nz = 4
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = isamax( n, x( 1, j ), 1 )
         xnorm = max( abs( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, abs( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
*
         IF( xnorm.GT.one ) THEN
            GO TO 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            GO TO 20
         ELSE
            errbnd = one / eps
            GO TO 30
         END IF
*
   20    CONTINUE
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 CONTINUE
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( NZ*EPS + (*) ), where
*     (*) = NZ*UNFL / (min_i (abs(op(A))*abs(X) +abs(b))_i )
*
      DO 60 k = 1, nrhs
         IF( notran ) THEN
            IF( n.EQ.1 ) THEN
               axbi = abs( b( 1, k ) ) + abs( d( 1 )*x( 1, k ) )
            ELSE
               axbi = abs( b( 1, k ) ) + abs( d( 1 )*x( 1, k ) ) +
     $                abs( du( 1 )*x( 2, k ) )
               DO 40 i = 2, n - 1
                  tmp = abs( b( i, k ) ) + abs( dl( i-1 )*x( i-1, k ) )
     $                   + abs( d( i )*x( i, k ) ) +
     $                  abs( du( i )*x( i+1, k ) )
                  axbi = min( axbi, tmp )
   40          CONTINUE
               tmp = abs( b( n, k ) ) + abs( dl( n-1 )*x( n-1, k ) ) +
     $               abs( d( n )*x( n, k ) )
               axbi = min( axbi, tmp )
            END IF
         ELSE
            IF( n.EQ.1 ) THEN
               axbi = abs( b( 1, k ) ) + abs( d( 1 )*x( 1, k ) )
            ELSE
               axbi = abs( b( 1, k ) ) + abs( d( 1 )*x( 1, k ) ) +
     $                abs( dl( 1 )*x( 2, k ) )
               DO 50 i = 2, n - 1
                  tmp = abs( b( i, k ) ) + abs( du( i-1 )*x( i-1, k ) )
     $                   + abs( d( i )*x( i, k ) ) +
     $                  abs( dl( i )*x( i+1, k ) )
                  axbi = min( axbi, tmp )
   50          CONTINUE
               tmp = abs( b( n, k ) ) + abs( du( n-1 )*x( n-1, k ) ) +
     $               abs( d( n )*x( n, k ) )
               axbi = min( axbi, tmp )
            END IF
         END IF
         tmp = berr( k ) / ( nz*eps+nz*unfl / max( axbi, nz*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   60 CONTINUE
*
      RETURN
*
*     End of SGTT05
*

Here is the caller graph for this function: