dsbt21()

subroutine dsbt21	(	character	uplo,
		integer	n,
		integer	ka,
		integer	ks,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( ldu, * )	u,
		integer	ldu,
		double precision, dimension( * )	work,
		double precision, dimension( 2 )	result
	)

DSBT21

Purpose:

 DSBT21  generally checks a decomposition of the form

         A = U S U**T

 where **T means transpose, A is symmetric banded, U is
 orthogonal, and S is diagonal (if KS=0) or symmetric
 tridiagonal (if KS=1).

 Specifically:

         RESULT(1) = | A - U S U**T | / ( |A| n ulp ) and
         RESULT(2) = | I - U U**T | / ( n ulp )

Parameters

[in]	UPLO	UPLO is CHARACTER If UPLO='U', the upper triangle of A and V will be used and the (strictly) lower triangle will not be referenced. If UPLO='L', the lower triangle of A and V will be used and the (strictly) upper triangle will not be referenced.
[in]	N	N is INTEGER The size of the matrix. If it is zero, DSBT21 does nothing. It must be at least zero.
[in]	KA	KA is INTEGER The bandwidth of the matrix A. It must be at least zero. If it is larger than N-1, then max( 0, N-1 ) will be used.
[in]	KS	KS is INTEGER The bandwidth of the matrix S. It may only be zero or one. If zero, then S is diagonal, and E is not referenced. If one, then S is symmetric tri-diagonal.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA, N) The original (unfactored) matrix. It is assumed to be symmetric, and only the upper (UPLO='U') or only the lower (UPLO='L') will be referenced.
[in]	LDA	LDA is INTEGER The leading dimension of A. It must be at least 1 and at least min( KA, N-1 ).
[in]	D	D is DOUBLE PRECISION array, dimension (N) The diagonal of the (symmetric tri-) diagonal matrix S.
[in]	E	E is DOUBLE PRECISION array, dimension (N-1) The off-diagonal of the (symmetric tri-) diagonal matrix S. E(1) is the (1,2) and (2,1) element, E(2) is the (2,3) and (3,2) element, etc. Not referenced if KS=0.
[in]	U	U is DOUBLE PRECISION array, dimension (LDU, N) The orthogonal matrix in the decomposition, expressed as a dense matrix (i.e., not as a product of Householder transformations, Givens transformations, etc.)
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N and at least 1.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (N**2+N)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) The values computed by the two tests described above. The values are currently limited to 1/ulp, to avoid overflow.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 145 of file dsbt21.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            KA, KS, LDA, LDU, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), D( * ), E( * ), RESULT( 2 ),
     $                   U( LDU, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER
      CHARACTER          CUPLO
      INTEGER            IKA, J, JC, JR, LW
      DOUBLE PRECISION   ANORM, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSB, DLANSP
      EXTERNAL           lsame, dlamch, dlange, dlansb, dlansp
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dspr, dspr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
*     Constants
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      ika = max( 0, min( n-1, ka ) )
      lw = ( n*( n+1 ) ) / 2
*
      IF( lsame( uplo, 'U' ) ) THEN
         lower = .false.
         cuplo = 'U'
      ELSE
         lower = .true.
         cuplo = 'L'
      END IF
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )*dlamch( 'Base' )
*
*     Some Error Checks
*
*     Do Test 1
*
*     Norm of A:
*
      anorm = max( dlansb( '1', cuplo, n, ika, a, lda, work ), unfl )
*
*     Compute error matrix:    Error = A - U S U**T
*
*     Copy A from SB to SP storage format.
*
      j = 0
      DO 50 jc = 1, n
         IF( lower ) THEN
            DO 10 jr = 1, min( ika+1, n+1-jc )
               j = j + 1
               work( j ) = a( jr, jc )
   10       CONTINUE
            DO 20 jr = ika + 2, n + 1 - jc
               j = j + 1
               work( j ) = zero
   20       CONTINUE
         ELSE
            DO 30 jr = ika + 2, jc
               j = j + 1
               work( j ) = zero
   30       CONTINUE
            DO 40 jr = min( ika, jc-1 ), 0, -1
               j = j + 1
               work( j ) = a( ika+1-jr, jc )
   40       CONTINUE
         END IF
   50 CONTINUE
*
      DO 60 j = 1, n
         CALL dspr( cuplo, n, -d( j ), u( 1, j ), 1, work )
   60 CONTINUE
*
      IF( n.GT.1 .AND. ks.EQ.1 ) THEN
         DO 70 j = 1, n - 1
            CALL dspr2( cuplo, n, -e( j ), u( 1, j ), 1, u( 1, j+1 ), 1,
     $                  work )
   70    CONTINUE
      END IF
      wnorm = dlansp( '1', cuplo, n, work, work( lw+1 ) )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U U**T - I
*
      CALL dgemm( 'N', 'C', n, n, n, one, u, ldu, u, ldu, zero, work,
     $            n )
*
      DO 80 j = 1, n
         work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
   80 CONTINUE
*
      result( 2 ) = min( dlange( '1', n, n, work, n, work( n**2+1 ) ),
     $              dble( n ) ) / ( n*ulp )
*
      RETURN
*
*     End of DSBT21
*

Here is the call graph for this function:

Here is the caller graph for this function: