cqlt01()

subroutine cqlt01	(	integer	m,
		integer	n,
		complex, dimension( lda, * )	a,
		complex, dimension( lda, * )	af,
		complex, dimension( lda, * )	q,
		complex, dimension( lda, * )	l,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( lwork )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		real, dimension( * )	result
	)

CQLT01

Purpose:

 CQLT01 tests CGEQLF, which computes the QL factorization of an m-by-n
 matrix A, and partially tests CUNGQL which forms the m-by-m
 orthogonal matrix Q.

 CQLT01 compares L with Q'*A, and checks that Q is orthogonal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A.
[out]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the QL factorization of A, as returned by CGEQLF. See CGEQLF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,M) The m-by-m orthogonal matrix Q.
[out]	L	L is COMPLEX array, dimension (LDA,max(M,N))
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and R. LDA >= max(M,N).
[out]	TAU	TAU is COMPLEX array, dimension (min(M,N)) The scalar factors of the elementary reflectors, as returned by CGEQLF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( L - Q'*A ) / ( M * norm(A) * EPS ) RESULT(2) = norm( I - Q'*Q ) / ( M * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file cqlt01.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, cgeqlf, cherk, clacpy, claset, cungql
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'CGEQLF'
      CALL cgeqlf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL claset( 'Full', m, m, rogue, rogue, q, lda )
      IF( m.GE.n ) THEN
         IF( n.LT.m .AND. n.GT.0 )
     $      CALL clacpy( 'Full', m-n, n, af, lda, q( 1, m-n+1 ), lda )
         IF( n.GT.1 )
     $      CALL clacpy( 'Upper', n-1, n-1, af( m-n+1, 2 ), lda,
     $                   q( m-n+1, m-n+2 ), lda )
      ELSE
         IF( m.GT.1 )
     $      CALL clacpy( 'Upper', m-1, m-1, af( 1, n-m+2 ), lda,
     $                   q( 1, 2 ), lda )
      END IF
*
*     Generate the m-by-m matrix Q
*
      srnamt = 'CUNGQL'
      CALL cungql( m, m, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( zero ), l, lda )
      IF( m.GE.n ) THEN
         IF( n.GT.0 )
     $      CALL clacpy( 'Lower', n, n, af( m-n+1, 1 ), lda,
     $                   l( m-n+1, 1 ), lda )
      ELSE
         IF( n.GT.m .AND. m.GT.0 )
     $      CALL clacpy( 'Full', m, n-m, af, lda, l, lda )
         IF( m.GT.0 )
     $      CALL clacpy( 'Lower', m, m, af( 1, n-m+1 ), lda,
     $                   l( 1, n-m+1 ), lda )
      END IF
*
*     Compute L - Q'*A
*
      CALL cgemm( 'Conjugate transpose', 'No transpose', m, n, m,
     $            cmplx( -one ), q, lda, a, lda, cmplx( one ), l, lda )
*
*     Compute norm( L - Q'*A ) / ( M * norm(A) * EPS ) .
*
      anorm = clange( '1', m, n, a, lda, rwork )
      resid = clange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, m ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q'*Q
*
      CALL claset( 'Full', m, m, cmplx( zero ), cmplx( one ), l, lda )
      CALL cherk( 'Upper', 'Conjugate transpose', m, m, -one, q, lda,
     $            one, l, lda )
*
*     Compute norm( I - Q'*Q ) / ( M * EPS ) .
*
      resid = clansy( '1', 'Upper', m, l, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, m ) ) ) / eps
*
      RETURN
*
*     End of CQLT01
*

Here is the call graph for this function:

Here is the caller graph for this function: