cgeqlf()

subroutine cgeqlf	(	integer	m,
		integer	n,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info
	)

CGEQLF

Download CGEQLF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CGEQLF computes a QL factorization of a complex M-by-N matrix A:
 A = Q * L.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the M-by-N matrix A. On exit, if m >= n, the lower triangle of the subarray A(m-n+1:m,1:n) contains the N-by-N lower triangular matrix L; if m <= n, the elements on and below the (n-m)-th superdiagonal contain the M-by-N lower trapezoidal matrix L; the remaining elements, with the array TAU, represent the unitary matrix Q as a product of elementary reflectors (see Further Details).
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[out]	TAU	TAU is COMPLEX array, dimension (min(M,N)) The scalar factors of the elementary reflectors (see Further Details).
[out]	WORK	WORK is COMPLEX array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK. LWORK >= max(1,N). For optimum performance LWORK >= N*NB, where NB is the optimal blocksize. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

  The matrix Q is represented as a product of elementary reflectors

     Q = H(k) . . . H(2) H(1), where k = min(m,n).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(m-k+i+1:m) = 0 and v(m-k+i) = 1; v(1:m-k+i-1) is stored on exit in
  A(1:m-k+i-1,n-k+i), and tau in TAU(i).

Definition at line 137 of file cgeqlf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, IINFO, IWS, K, KI, KK, LDWORK, LWKOPT,
     $                   MU, NB, NBMIN, NU, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgeql2, clarfb, clarft, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -4
      END IF
*
      IF( info.EQ.0 ) THEN
         k = min( m, n )
         IF( k.EQ.0 ) THEN
            lwkopt = 1
         ELSE
            nb = ilaenv( 1, 'CGEQLF', ' ', m, n, -1, -1 )
            lwkopt = n*nb
         END IF
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
            info = -7
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGEQLF', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( k.EQ.0 ) THEN
         RETURN
      END IF
*
      nbmin = 2
      nx = 1
      iws = n
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'CGEQLF', ' ', m, n, -1, -1 ) )
         IF( nx.LT.k ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = n
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'CGEQLF', ' ', m, n, -1,
     $                 -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
*
*        Use blocked code initially.
*        The last kk columns are handled by the block method.
*
         ki = ( ( k-nx-1 ) / nb )*nb
         kk = min( k, ki+nb )
*
         DO 10 i = k - kk + ki + 1, k - kk + 1, -nb
            ib = min( k-i+1, nb )
*
*           Compute the QL factorization of the current block
*           A(1:m-k+i+ib-1,n-k+i:n-k+i+ib-1)
*
            CALL cgeql2( m-k+i+ib-1, ib, a( 1, n-k+i ), lda, tau( i ),
     $                   work, iinfo )
            IF( n-k+i.GT.1 ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL clarft( 'Backward', 'Columnwise', m-k+i+ib-1, ib,
     $                      a( 1, n-k+i ), lda, tau( i ), work, ldwork )
*
*              Apply H**H to A(1:m-k+i+ib-1,1:n-k+i-1) from the left
*
               CALL clarfb( 'Left', 'Conjugate transpose', 'Backward',
     $                      'Columnwise', m-k+i+ib-1, n-k+i-1, ib,
     $                      a( 1, n-k+i ), lda, work, ldwork, a, lda,
     $                      work( ib+1 ), ldwork )
            END IF
   10    CONTINUE
         mu = m - k + i + nb - 1
         nu = n - k + i + nb - 1
      ELSE
         mu = m
         nu = n
      END IF
*
*     Use unblocked code to factor the last or only block
*
      IF( mu.GT.0 .AND. nu.GT.0 )
     $   CALL cgeql2( mu, nu, a, lda, tau, work, iinfo )
*
      work( 1 ) = sroundup_lwork(iws)
      RETURN
*
*     End of CGEQLF
*

Here is the call graph for this function:

Here is the caller graph for this function: