cungql()

subroutine cungql	(	integer	m,
		integer	n,
		integer	k,
		complex, dimension( lda, * )	a,
		integer	lda,
		complex, dimension( * )	tau,
		complex, dimension( * )	work,
		integer	lwork,
		integer	info )

CUNGQL

Download CUNGQL + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> CUNGQL generates an M-by-N complex matrix Q with orthonormal columns,
!> which is defined as the last N columns of a product of K elementary
!> reflectors of order M
!>
!>       Q  =  H(k) . . . H(2) H(1)
!>
!> as returned by CGEQLF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q. M >= N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. N >= K >= 0. !>
[in,out]	A	!> A is COMPLEX array, dimension (LDA,N) !> On entry, the (n-k+i)-th column must contain the vector which !> defines the elementary reflector H(i), for i = 1,2,...,k, as !> returned by CGEQLF in the last k columns of its array !> argument A. !> On exit, the M-by-N matrix Q. !>
[in]	LDA	!> LDA is INTEGER !> The first dimension of the array A. LDA >= max(1,M). !>
[in]	TAU	!> TAU is COMPLEX array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by CGEQLF. !>
[out]	WORK	!> WORK is COMPLEX array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,N). !> For optimum performance LWORK >= N*NB, where NB is the !> optimal blocksize. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument has an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 125 of file cungql.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY
      INTEGER            I, IB, IINFO, IWS, J, KK, L, LDWORK, LWKOPT,
     $                   NB, NBMIN, NX
*     ..
*     .. External Subroutines ..
      EXTERNAL           clarfb, clarft, cung2l, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      REAL               SROUNDUP_LWORK
      EXTERNAL           ilaenv, sroundup_lwork
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            lwkopt = 1
         ELSE
            nb = ilaenv( 1, 'CUNGQL', ' ', m, n, k, -1 )
            lwkopt = n*nb
         END IF
         work( 1 ) = sroundup_lwork(lwkopt)
*
         IF( lwork.LT.max( 1, n ) .AND. .NOT.lquery ) THEN
            info = -8
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CUNGQL', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 ) THEN
         RETURN
      END IF
*
      nbmin = 2
      nx = 0
      iws = n
      IF( nb.GT.1 .AND. nb.LT.k ) THEN
*
*        Determine when to cross over from blocked to unblocked code.
*
         nx = max( 0, ilaenv( 3, 'CUNGQL', ' ', m, n, k, -1 ) )
         IF( nx.LT.k ) THEN
*
*           Determine if workspace is large enough for blocked code.
*
            ldwork = n
            iws = ldwork*nb
            IF( lwork.LT.iws ) THEN
*
*              Not enough workspace to use optimal NB:  reduce NB and
*              determine the minimum value of NB.
*
               nb = lwork / ldwork
               nbmin = max( 2, ilaenv( 2, 'CUNGQL', ' ', m, n, k,
     $                      -1 ) )
            END IF
         END IF
      END IF
*
      IF( nb.GE.nbmin .AND. nb.LT.k .AND. nx.LT.k ) THEN
*
*        Use blocked code after the first block.
*        The last kk columns are handled by the block method.
*
         kk = min( k, ( ( k-nx+nb-1 ) / nb )*nb )
*
*        Set A(m-kk+1:m,1:n-kk) to zero.
*
         DO 20 j = 1, n - kk
            DO 10 i = m - kk + 1, m
               a( i, j ) = zero
   10       CONTINUE
   20    CONTINUE
      ELSE
         kk = 0
      END IF
*
*     Use unblocked code for the first or only block.
*
      CALL cung2l( m-kk, n-kk, k-kk, a, lda, tau, work, iinfo )
*
      IF( kk.GT.0 ) THEN
*
*        Use blocked code
*
         DO 50 i = k - kk + 1, k, nb
            ib = min( nb, k-i+1 )
            IF( n-k+i.GT.1 ) THEN
*
*              Form the triangular factor of the block reflector
*              H = H(i+ib-1) . . . H(i+1) H(i)
*
               CALL clarft( 'Backward', 'Columnwise', m-k+i+ib-1, ib,
     $                      a( 1, n-k+i ), lda, tau( i ), work, ldwork )
*
*              Apply H to A(1:m-k+i+ib-1,1:n-k+i-1) from the left
*
               CALL clarfb( 'Left', 'No transpose', 'Backward',
     $                      'Columnwise', m-k+i+ib-1, n-k+i-1, ib,
     $                      a( 1, n-k+i ), lda, work, ldwork, a, lda,
     $                      work( ib+1 ), ldwork )
            END IF
*
*           Apply H to rows 1:m-k+i+ib-1 of current block
*
            CALL cung2l( m-k+i+ib-1, ib, ib, a( 1, n-k+i ), lda,
     $                   tau( i ), work, iinfo )
*
*           Set rows m-k+i+ib:m of current block to zero
*
            DO 40 j = n - k + i, n - k + i + ib - 1
               DO 30 l = m - k + i + ib, m
                  a( l, j ) = zero
   30          CONTINUE
   40       CONTINUE
   50    CONTINUE
      END IF
*
      work( 1 ) = cmplx( iws )
      RETURN
*
*     End of CUNGQL
*

Here is the call graph for this function:

Here is the caller graph for this function: