schksy()

subroutine schksy	(	logical, dimension( * )	dotype,
		integer	nn,
		integer, dimension( * )	nval,
		integer	nnb,
		integer, dimension( * )	nbval,
		integer	nns,
		integer, dimension( * )	nsval,
		real	thresh,
		logical	tsterr,
		integer	nmax,
		real, dimension( * )	a,
		real, dimension( * )	afac,
		real, dimension( * )	ainv,
		real, dimension( * )	b,
		real, dimension( * )	x,
		real, dimension( * )	xact,
		real, dimension( * )	work,
		real, dimension( * )	rwork,
		integer, dimension( * )	iwork,
		integer	nout
	)

SCHKSY

Purpose:

 SCHKSY tests SSYTRF, -TRI2, -TRS, -TRS2, -RFS, and -CON.

Parameters

[in]	DOTYPE	DOTYPE is LOGICAL array, dimension (NTYPES) The matrix types to be used for testing. Matrices of type j (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) = .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
[in]	NN	NN is INTEGER The number of values of N contained in the vector NVAL.
[in]	NVAL	NVAL is INTEGER array, dimension (NN) The values of the matrix dimension N.
[in]	NNB	NNB is INTEGER The number of values of NB contained in the vector NBVAL.
[in]	NBVAL	NBVAL is INTEGER array, dimension (NNB) The values of the blocksize NB.
[in]	NNS	NNS is INTEGER The number of values of NRHS contained in the vector NSVAL.
[in]	NSVAL	NSVAL is INTEGER array, dimension (NNS) The values of the number of right hand sides NRHS.
[in]	THRESH	THRESH is REAL The threshold value for the test ratios. A result is included in the output file if RESULT >= THRESH. To have every test ratio printed, use THRESH = 0.
[in]	TSTERR	TSTERR is LOGICAL Flag that indicates whether error exits are to be tested.
[in]	NMAX	NMAX is INTEGER The maximum value permitted for N, used in dimensioning the work arrays.
[out]	A	A is REAL array, dimension (NMAX*NMAX)
[out]	AFAC	AFAC is REAL array, dimension (NMAX*NMAX)
[out]	AINV	AINV is REAL array, dimension (NMAX*NMAX)
[out]	B	B is REAL array, dimension (NMAX*NSMAX) where NSMAX is the largest entry in NSVAL.
[out]	X	X is REAL array, dimension (NMAX*NSMAX)
[out]	XACT	XACT is REAL array, dimension (NMAX*NSMAX)
[out]	WORK	WORK is REAL array, dimension (NMAX*max(3,NSMAX))
[out]	RWORK	RWORK is REAL array, dimension (max(NMAX,2*NSMAX))
[out]	IWORK	IWORK is INTEGER array, dimension (2*NMAX)
[in]	NOUT	NOUT is INTEGER The unit number for output.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 167 of file schksy.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNB, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
      REAL               A( * ), AFAC( * ), AINV( * ), B( * ),
     $                   RWORK( * ), WORK( * ), X( * ), XACT( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter( ntypes = 10 )
      INTEGER            NTESTS
      parameter( ntests = 9 )
*     ..
*     .. Local Scalars ..
      LOGICAL            TRFCON, ZEROT
      CHARACTER          DIST, TYPE, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
     $                   IUPLO, IZERO, J, K, KL, KU, LDA, LWORK, MODE,
     $                   N, NB, NERRS, NFAIL, NIMAT, NRHS, NRUN, NT
      REAL               ANORM, CNDNUM, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Functions ..
      REAL               SGET06, SLANSY
      EXTERNAL           sget06, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, serrsy, sget04, slacpy,
     $                   slarhs, slatb4, slatms, spot02, spot03, spot05,
     $                   ssycon, ssyconv, ssyrfs, ssyt01, ssytrf,
     $                   ssytri2, ssytrs, ssytrs2, xlaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'SY'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrsy( path, nout )
      infot = 0
*
*     Set the minimum block size for which the block routine should
*     be used, which will be later returned by ILAENV
*
      CALL xlaenv( 2, 2 )
*
*     Do for each value of N in NVAL
*
      DO 180 in = 1, nn
         n = nval( in )
         lda = max( n, 1 )
         xtype = 'N'
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         izero = 0
*
*        Do for each value of matrix type IMAT
*
         DO 170 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 170
*
*           Skip types 3, 4, 5, or 6 if the matrix size is too small.
*
            zerot = imat.GE.3 .AND. imat.LE.6
            IF( zerot .AND. n.LT.imat-2 )
     $         GO TO 170
*
*           Do first for UPLO = 'U', then for UPLO = 'L'
*
            DO 160 iuplo = 1, 2
               uplo = uplos( iuplo )
*
*              Begin generate the test matrix A.
*
*              Set up parameters with SLATB4 for the matrix generator
*              based on the type of matrix to be generated.
*
               CALL slatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                      CNDNUM, DIST )
*
*              Generate a matrix with SLATMS.
*
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, RWORK, MODE,
     $                      CNDNUM, ANORM, KL, KU, UPLO, A, LDA, WORK,
     $                      INFO )
*
*              Check error code from SLATMS and handle error.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, uplo, n, n, -1,
     $                         -1, -1, imat, nfail, nerrs, nout )
*
*                 Skip all tests for this generated matrix
*
                  GO TO 160
               END IF
*
*              For matrix types 3-6, zero one or more rows and
*              columns of the matrix to test that INFO is returned
*              correctly.
*
               IF( zerot ) THEN
                  IF( imat.EQ.3 ) THEN
                     izero = 1
                  ELSE IF( imat.EQ.4 ) THEN
                     izero = n
                  ELSE
                     izero = n / 2 + 1
                  END IF
*
                  IF( imat.LT.6 ) THEN
*
*                    Set row and column IZERO to zero.
*
                     IF( iuplo.EQ.1 ) THEN
                        ioff = ( izero-1 )*lda
                        DO 20 i = 1, izero - 1
                           a( ioff+i ) = zero
   20                   CONTINUE
                        ioff = ioff + izero
                        DO 30 i = izero, n
                           a( ioff ) = zero
                           ioff = ioff + lda
   30                   CONTINUE
                     ELSE
                        ioff = izero
                        DO 40 i = 1, izero - 1
                           a( ioff ) = zero
                           ioff = ioff + lda
   40                   CONTINUE
                        ioff = ioff - izero
                        DO 50 i = izero, n
                           a( ioff+i ) = zero
   50                   CONTINUE
                     END IF
                  ELSE
                     IF( iuplo.EQ.1 ) THEN
*
*                       Set the first IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 70 j = 1, n
                           i2 = min( j, izero )
                           DO 60 i = 1, i2
                              a( ioff+i ) = zero
   60                      CONTINUE
                           ioff = ioff + lda
   70                   CONTINUE
                     ELSE
*
*                       Set the last IZERO rows and columns to zero.
*
                        ioff = 0
                        DO 90 j = 1, n
                           i1 = max( j, izero )
                           DO 80 i = i1, n
                              a( ioff+i ) = zero
   80                      CONTINUE
                           ioff = ioff + lda
   90                   CONTINUE
                     END IF
                  END IF
               ELSE
                  izero = 0
               END IF
*
*              End generate the test matrix A.
*
*
*              Do for each value of NB in NBVAL
*
               DO 150 inb = 1, nnb
*
*                 Set the optimal blocksize, which will be later
*                 returned by ILAENV.
*
                  nb = nbval( inb )
                  CALL xlaenv( 1, nb )
*
*                 Copy the test matrix A into matrix AFAC which
*                 will be factorized in place. This is needed to
*                 preserve the test matrix A for subsequent tests.
*
                  CALL slacpy( uplo, n, n, a, lda, afac, lda )
*
*                 Compute the L*D*L**T or U*D*U**T factorization of the
*                 matrix. IWORK stores details of the interchanges and
*                 the block structure of D. AINV is a work array for
*                 block factorization, LWORK is the length of AINV.
*
                  lwork = max( 2, nb )*lda
                  srnamt = 'SSYTRF'
                  CALL ssytrf( uplo, n, afac, lda, iwork, ainv, lwork,
     $                         info )
*
*                 Adjust the expected value of INFO to account for
*                 pivoting.
*
                  k = izero
                  IF( k.GT.0 ) THEN
  100                CONTINUE
                     IF( iwork( k ).LT.0 ) THEN
                        IF( iwork( k ).NE.-k ) THEN
                           k = -iwork( k )
                           GO TO 100
                        END IF
                     ELSE IF( iwork( k ).NE.k ) THEN
                        k = iwork( k )
                        GO TO 100
                     END IF
                  END IF
*
*                 Check error code from SSYTRF and handle error.
*
                  IF( info.NE.k )
     $               CALL alaerh( path, 'SSYTRF', info, k, uplo, n, n,
     $                            -1, -1, nb, imat, nfail, nerrs, nout )
*
*                 Set the condition estimate flag if the INFO is not 0.
*
                  IF( info.NE.0 ) THEN
                     trfcon = .true.
                  ELSE
                     trfcon = .false.
                  END IF
*
*+    TEST 1
*                 Reconstruct matrix from factors and compute residual.
*
                  CALL ssyt01( uplo, n, a, lda, afac, lda, iwork, ainv,
     $                         lda, rwork, result( 1 ) )
                  nt = 1
*
*+    TEST 2
*                 Form the inverse and compute the residual,
*                 if the factorization was competed without INFO > 0
*                 (i.e. there is no zero rows and columns).
*                 Do it only for the first block size.
*
                  IF( inb.EQ.1 .AND. .NOT.trfcon ) THEN
                     CALL slacpy( uplo, n, n, afac, lda, ainv, lda )
                     srnamt = 'SSYTRI2'
                     lwork = (n+nb+1)*(nb+3)
                     CALL ssytri2( uplo, n, ainv, lda, iwork, work,
     $                            lwork, info )
*
*                    Check error code from SSYTRI2 and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYTRI2', info, -1, uplo, n,
     $                               n, -1, -1, -1, imat, nfail, nerrs,
     $                               nout )
*
*                    Compute the residual for a symmetric matrix times
*                    its inverse.
*
                     CALL spot03( uplo, n, a, lda, ainv, lda, work, lda,
     $                            rwork, rcondc, result( 2 ) )
                     nt = 2
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 110 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9999 )uplo, n, nb, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
  110             CONTINUE
                  nrun = nrun + nt
*
*                 Skip the other tests if this is not the first block
*                 size.
*
                  IF( inb.GT.1 )
     $               GO TO 150
*
*                 Do only the condition estimate if INFO is not 0.
*
                  IF( trfcon ) THEN
                     rcondc = zero
                     GO TO 140
                  END IF
*
*                 Do for each value of NRHS in NSVAL.
*
                  DO 130 irhs = 1, nns
                     nrhs = nsval( irhs )
*
*+    TEST 3 (Using DSYTRS)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'SLARHS'
                     CALL slarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'SSYTRS'
                     CALL ssytrs( uplo, n, nrhs, afac, lda, iwork, x,
     $                            lda, info )
*
*                    Check error code from SSYTRS and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYTRS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL spot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 3 ) )
*
*+    TEST 4 (Using DSYTRS2)
*                 Solve and compute residual for  A * X = B.
*
*                    Choose a set of NRHS random solution vectors
*                    stored in XACT and set up the right hand side B
*
                     srnamt = 'SLARHS'
                     CALL slarhs( path, xtype, uplo, ' ', n, n, kl, ku,
     $                            nrhs, a, lda, xact, lda, b, lda,
     $                            iseed, info )
                     CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'DSYTRS2'
                     CALL ssytrs2( uplo, n, nrhs, afac, lda, iwork, x,
     $                            lda, work, info )
*
*                    Check error code from SSYTRS2 and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYTRS2', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
*
*                    Compute the residual for the solution
*
                     CALL spot02( uplo, n, nrhs, a, lda, x, lda, work,
     $                            lda, rwork, result( 4 ) )
*
*+    TEST 5
*                 Check solution from generated exact solution.
*
                     CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 5 ) )
*
*+    TESTS 6, 7, and 8
*                 Use iterative refinement to improve the solution.
*
                     srnamt = 'SSYRFS'
                     CALL ssyrfs( uplo, n, nrhs, a, lda, afac, lda,
     $                            iwork, b, lda, x, lda, rwork,
     $                            rwork( nrhs+1 ), work, iwork( n+1 ),
     $                            info )
*
*                    Check error code from SSYRFS and handle error.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SSYRFS', info, 0, uplo, n,
     $                               n, -1, -1, nrhs, imat, nfail,
     $                               nerrs, nout )
*
                     CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 6 ) )
                     CALL spot05( uplo, n, nrhs, a, lda, b, lda, x, lda,
     $                            xact, lda, rwork, rwork( nrhs+1 ),
     $                            result( 7 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 120 k = 3, 8
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, n, nrhs,
     $                        imat, k, result( k )
                           nfail = nfail + 1
                        END IF
  120                CONTINUE
                     nrun = nrun + 6
*
*                 End do for each value of NRHS in NSVAL.
*
  130             CONTINUE
*
*+    TEST 9
*                 Get an estimate of RCOND = 1/CNDNUM.
*
  140             CONTINUE
                  anorm = slansy( '1', uplo, n, a, lda, rwork )
                  srnamt = 'SSYCON'
                  CALL ssycon( uplo, n, afac, lda, iwork, anorm, rcond,
     $                         work, iwork( n+1 ), info )
*
*                 Check error code from SSYCON and handle error.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'SSYCON', info, 0, uplo, n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
*                 Compute the test ratio to compare to values of RCOND
*
                  result( 9 ) = sget06( rcond, rcondc )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 9 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 )uplo, n, imat, 9,
     $                  result( 9 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
  150          CONTINUE
*
  160       CONTINUE
  170    CONTINUE
  180 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NB =', i4, ', type ',
     $      i2, ', test ', i2, ', ratio =', g12.5 )
 9998 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ', NRHS=', i3, ', type ',
     $      i2, ', test(', i2, ') =', g12.5 )
 9997 FORMAT( ' UPLO = ''', a1, ''', N =', i5, ',', 10x, ' type ', i2,
     $      ', test(', i2, ') =', g12.5 )
      RETURN
*
*     End of SCHKSY
*

Here is the call graph for this function:

Here is the caller graph for this function: