dgeev()

subroutine dgeev	(	character	jobvl,
		character	jobvr,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision, dimension( * )	wr,
		double precision, dimension( * )	wi,
		double precision, dimension( ldvl, * )	vl,
		integer	ldvl,
		double precision, dimension( ldvr, * )	vr,
		integer	ldvr,
		double precision, dimension( * )	work,
		integer	lwork,
		integer	info )

DGEEV computes the eigenvalues and, optionally, the left and/or right eigenvectors for GE matrices

Download DGEEV + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DGEEV computes for an N-by-N real nonsymmetric matrix A, the
!> eigenvalues and, optionally, the left and/or right eigenvectors.
!>
!> The right eigenvector v(j) of A satisfies
!>                  A * v(j) = lambda(j) * v(j)
!> where lambda(j) is its eigenvalue.
!> The left eigenvector u(j) of A satisfies
!>               u(j)**H * A = lambda(j) * u(j)**H
!> where u(j)**H denotes the conjugate-transpose of u(j).
!>
!> The computed eigenvectors are normalized to have Euclidean norm
!> equal to 1 and largest component real.
!> 

Parameters

[in]	JOBVL	!> JOBVL is CHARACTER*1 !> = 'N': left eigenvectors of A are not computed; !> = 'V': left eigenvectors of A are computed. !>
[in]	JOBVR	!> JOBVR is CHARACTER*1 !> = 'N': right eigenvectors of A are not computed; !> = 'V': right eigenvectors of A are computed. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> On entry, the N-by-N matrix A. !> On exit, A has been overwritten. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[out]	WR	!> WR is DOUBLE PRECISION array, dimension (N) !>
[out]	WI	!> WI is DOUBLE PRECISION array, dimension (N) !> WR and WI contain the real and imaginary parts, !> respectively, of the computed eigenvalues. Complex !> conjugate pairs of eigenvalues appear consecutively !> with the eigenvalue having the positive imaginary part !> first. !>
[out]	VL	!> VL is DOUBLE PRECISION array, dimension (LDVL,N) !> If JOBVL = 'V', the left eigenvectors u(j) are stored one !> after another in the columns of VL, in the same order !> as their eigenvalues. !> If JOBVL = 'N', VL is not referenced. !> If the j-th eigenvalue is real, then u(j) = VL(:,j), !> the j-th column of VL. !> If the j-th and (j+1)-st eigenvalues form a complex !> conjugate pair, then u(j) = VL(:,j) + i*VL(:,j+1) and !> u(j+1) = VL(:,j) - i*VL(:,j+1). !>
[in]	LDVL	!> LDVL is INTEGER !> The leading dimension of the array VL. LDVL >= 1; if !> JOBVL = 'V', LDVL >= N. !>
[out]	VR	!> VR is DOUBLE PRECISION array, dimension (LDVR,N) !> If JOBVR = 'V', the right eigenvectors v(j) are stored one !> after another in the columns of VR, in the same order !> as their eigenvalues. !> If JOBVR = 'N', VR is not referenced. !> If the j-th eigenvalue is real, then v(j) = VR(:,j), !> the j-th column of VR. !> If the j-th and (j+1)-st eigenvalues form a complex !> conjugate pair, then v(j) = VR(:,j) + i*VR(:,j+1) and !> v(j+1) = VR(:,j) - i*VR(:,j+1). !>
[in]	LDVR	!> LDVR is INTEGER !> The leading dimension of the array VR. LDVR >= 1; if !> JOBVR = 'V', LDVR >= N. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)) !> On exit, if INFO = 0, WORK(1) returns the optimal LWORK. !>
[in]	LWORK	!> LWORK is INTEGER !> The dimension of the array WORK. LWORK >= max(1,3*N), and !> if JOBVL = 'V' or JOBVR = 'V', LWORK >= 4*N. For good !> performance, LWORK must generally be larger. !> !> If LWORK = -1, then a workspace query is assumed; the routine !> only calculates the optimal size of the WORK array, returns !> this value as the first entry of the WORK array, and no error !> message related to LWORK is issued by XERBLA. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, the QR algorithm failed to compute all the !> eigenvalues, and no eigenvectors have been computed; !> elements i+1:N of WR and WI contain eigenvalues which !> have converged. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 188 of file dgeev.f.

      implicit none
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          JOBVL, JOBVR
      INTEGER            INFO, LDA, LDVL, LDVR, LWORK, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), VL( LDVL, * ), VR( LDVR, * ),
     $                   WI( * ), WORK( * ), WR( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, SCALEA, WANTVL, WANTVR
      CHARACTER          SIDE
      INTEGER            HSWORK, I, IBAL, IERR, IHI, ILO, ITAU, IWRK, K,
     $                   LWORK_TREVC, MAXWRK, MINWRK, NOUT
      DOUBLE PRECISION   ANRM, BIGNUM, CS, CSCALE, EPS, R, SCL, SMLNUM,
     $                   SN
*     ..
*     .. Local Arrays ..
      LOGICAL            SELECT( 1 )
      DOUBLE PRECISION   DUM( 1 )
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgebak, dgebal, dgehrd, dhseqr, dlacpy,
     $                   dlartg,
     $                   dlascl, dorghr, drot, dscal, dtrevc3, xerbla
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IDAMAX, ILAENV
      DOUBLE PRECISION   DLAMCH, DLANGE, DLAPY2, DNRM2
      EXTERNAL           lsame, idamax, ilaenv, dlamch, dlange,
     $                   dlapy2,
     $                   dnrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      lquery = ( lwork.EQ.-1 )
      wantvl = lsame( jobvl, 'V' )
      wantvr = lsame( jobvr, 'V' )
      IF( ( .NOT.wantvl ) .AND. ( .NOT.lsame( jobvl, 'N' ) ) ) THEN
         info = -1
      ELSE IF( ( .NOT.wantvr ) .AND.
     $         ( .NOT.lsame( jobvr, 'N' ) ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldvl.LT.1 .OR. ( wantvl .AND. ldvl.LT.n ) ) THEN
         info = -9
      ELSE IF( ldvr.LT.1 .OR. ( wantvr .AND. ldvr.LT.n ) ) THEN
         info = -11
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.
*       HSWORK refers to the workspace preferred by DHSEQR, as
*       calculated below. HSWORK is computed assuming ILO=1 and IHI=N,
*       the worst case.)
*
      IF( info.EQ.0 ) THEN
         IF( n.EQ.0 ) THEN
            minwrk = 1
            maxwrk = 1
         ELSE
            maxwrk = 2*n + n*ilaenv( 1, 'DGEHRD', ' ', n, 1, n, 0 )
            IF( wantvl ) THEN
               minwrk = 4*n
               maxwrk = max( maxwrk, 2*n + ( n - 1 )*ilaenv( 1,
     $                       'DORGHR', ' ', n, 1, n, -1 ) )
               CALL dhseqr( 'S', 'V', n, 1, n, a, lda, wr, wi, vl,
     $                      ldvl,
     $                      work, -1, info )
               hswork = int( work(1) )
               maxwrk = max( maxwrk, n + 1, n + hswork )
               CALL dtrevc3( 'L', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr, n, nout,
     $                       work, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               maxwrk = max( maxwrk, 4*n )
            ELSE IF( wantvr ) THEN
               minwrk = 4*n
               maxwrk = max( maxwrk, 2*n + ( n - 1 )*ilaenv( 1,
     $                       'DORGHR', ' ', n, 1, n, -1 ) )
               CALL dhseqr( 'S', 'V', n, 1, n, a, lda, wr, wi, vr,
     $                      ldvr,
     $                      work, -1, info )
               hswork = int( work(1) )
               maxwrk = max( maxwrk, n + 1, n + hswork )
               CALL dtrevc3( 'R', 'B', SELECT, n, a, lda,
     $                       vl, ldvl, vr, ldvr, n, nout,
     $                       work, -1, ierr )
               lwork_trevc = int( work(1) )
               maxwrk = max( maxwrk, n + lwork_trevc )
               maxwrk = max( maxwrk, 4*n )
            ELSE
               minwrk = 3*n
               CALL dhseqr( 'E', 'N', n, 1, n, a, lda, wr, wi, vr,
     $                      ldvr,
     $                      work, -1, info )
               hswork = int( work(1) )
               maxwrk = max( maxwrk, n + 1, n + hswork )
            END IF
            maxwrk = max( maxwrk, minwrk )
         END IF
         work( 1 ) = maxwrk
*
         IF( lwork.LT.minwrk .AND. .NOT.lquery ) THEN
            info = -13
         END IF
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEEV ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Get machine constants
*
      eps = dlamch( 'P' )
      smlnum = dlamch( 'S' )
      bignum = one / smlnum
      smlnum = sqrt( smlnum ) / eps
      bignum = one / smlnum
*
*     Scale A if max element outside range [SMLNUM,BIGNUM]
*
      anrm = dlange( 'M', n, n, a, lda, dum )
      scalea = .false.
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
         scalea = .true.
         cscale = smlnum
      ELSE IF( anrm.GT.bignum ) THEN
         scalea = .true.
         cscale = bignum
      END IF
      IF( scalea )
     $   CALL dlascl( 'G', 0, 0, anrm, cscale, n, n, a, lda, ierr )
*
*     Balance the matrix
*     (Workspace: need N)
*
      ibal = 1
      CALL dgebal( 'B', n, a, lda, ilo, ihi, work( ibal ), ierr )
*
*     Reduce to upper Hessenberg form
*     (Workspace: need 3*N, prefer 2*N+N*NB)
*
      itau = ibal + n
      iwrk = itau + n
      CALL dgehrd( n, ilo, ihi, a, lda, work( itau ), work( iwrk ),
     $             lwork-iwrk+1, ierr )
*
      IF( wantvl ) THEN
*
*        Want left eigenvectors
*        Copy Householder vectors to VL
*
         side = 'L'
         CALL dlacpy( 'L', n, n, a, lda, vl, ldvl )
*
*        Generate orthogonal matrix in VL
*        (Workspace: need 3*N-1, prefer 2*N+(N-1)*NB)
*
         CALL dorghr( n, ilo, ihi, vl, ldvl, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VL
*        (Workspace: need N+1, prefer N+HSWORK (see comments) )
*
         iwrk = itau
         CALL dhseqr( 'S', 'V', n, ilo, ihi, a, lda, wr, wi, vl,
     $                ldvl,
     $                work( iwrk ), lwork-iwrk+1, info )
*
         IF( wantvr ) THEN
*
*           Want left and right eigenvectors
*           Copy Schur vectors to VR
*
            side = 'B'
            CALL dlacpy( 'F', n, n, vl, ldvl, vr, ldvr )
         END IF
*
      ELSE IF( wantvr ) THEN
*
*        Want right eigenvectors
*        Copy Householder vectors to VR
*
         side = 'R'
         CALL dlacpy( 'L', n, n, a, lda, vr, ldvr )
*
*        Generate orthogonal matrix in VR
*        (Workspace: need 3*N-1, prefer 2*N+(N-1)*NB)
*
         CALL dorghr( n, ilo, ihi, vr, ldvr, work( itau ),
     $                work( iwrk ),
     $                lwork-iwrk+1, ierr )
*
*        Perform QR iteration, accumulating Schur vectors in VR
*        (Workspace: need N+1, prefer N+HSWORK (see comments) )
*
         iwrk = itau
         CALL dhseqr( 'S', 'V', n, ilo, ihi, a, lda, wr, wi, vr,
     $                ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
*
      ELSE
*
*        Compute eigenvalues only
*        (Workspace: need N+1, prefer N+HSWORK (see comments) )
*
         iwrk = itau
         CALL dhseqr( 'E', 'N', n, ilo, ihi, a, lda, wr, wi, vr,
     $                ldvr,
     $                work( iwrk ), lwork-iwrk+1, info )
      END IF
*
*     If INFO .NE. 0 from DHSEQR, then quit
*
      IF( info.NE.0 )
     $   GO TO 50
*
      IF( wantvl .OR. wantvr ) THEN
*
*        Compute left and/or right eigenvectors
*        (Workspace: need 4*N, prefer N + N + 2*N*NB)
*
         CALL dtrevc3( side, 'B', SELECT, n, a, lda, vl, ldvl, vr,
     $                 ldvr,
     $                 n, nout, work( iwrk ), lwork-iwrk+1, ierr )
      END IF
*
      IF( wantvl ) THEN
*
*        Undo balancing of left eigenvectors
*        (Workspace: need N)
*
         CALL dgebak( 'B', 'L', n, ilo, ihi, work( ibal ), n, vl,
     $                ldvl,
     $                ierr )
*
*        Normalize left eigenvectors and make largest component real
*
         DO 20 i = 1, n
            IF( wi( i ).EQ.zero ) THEN
               scl = one / dnrm2( n, vl( 1, i ), 1 )
               CALL dscal( n, scl, vl( 1, i ), 1 )
            ELSE IF( wi( i ).GT.zero ) THEN
               scl = one / dlapy2( dnrm2( n, vl( 1, i ), 1 ),
     $               dnrm2( n, vl( 1, i+1 ), 1 ) )
               CALL dscal( n, scl, vl( 1, i ), 1 )
               CALL dscal( n, scl, vl( 1, i+1 ), 1 )
               DO 10 k = 1, n
                  work( iwrk+k-1 ) = vl( k, i )**2 + vl( k, i+1 )**2
   10          CONTINUE
               k = idamax( n, work( iwrk ), 1 )
               CALL dlartg( vl( k, i ), vl( k, i+1 ), cs, sn, r )
               CALL drot( n, vl( 1, i ), 1, vl( 1, i+1 ), 1, cs, sn )
               vl( k, i+1 ) = zero
            END IF
   20    CONTINUE
      END IF
*
      IF( wantvr ) THEN
*
*        Undo balancing of right eigenvectors
*        (Workspace: need N)
*
         CALL dgebak( 'B', 'R', n, ilo, ihi, work( ibal ), n, vr,
     $                ldvr,
     $                ierr )
*
*        Normalize right eigenvectors and make largest component real
*
         DO 40 i = 1, n
            IF( wi( i ).EQ.zero ) THEN
               scl = one / dnrm2( n, vr( 1, i ), 1 )
               CALL dscal( n, scl, vr( 1, i ), 1 )
            ELSE IF( wi( i ).GT.zero ) THEN
               scl = one / dlapy2( dnrm2( n, vr( 1, i ), 1 ),
     $               dnrm2( n, vr( 1, i+1 ), 1 ) )
               CALL dscal( n, scl, vr( 1, i ), 1 )
               CALL dscal( n, scl, vr( 1, i+1 ), 1 )
               DO 30 k = 1, n
                  work( iwrk+k-1 ) = vr( k, i )**2 + vr( k, i+1 )**2
   30          CONTINUE
               k = idamax( n, work( iwrk ), 1 )
               CALL dlartg( vr( k, i ), vr( k, i+1 ), cs, sn, r )
               CALL drot( n, vr( 1, i ), 1, vr( 1, i+1 ), 1, cs, sn )
               vr( k, i+1 ) = zero
            END IF
   40    CONTINUE
      END IF
*
*     Undo scaling if necessary
*
   50 CONTINUE
      IF( scalea ) THEN
         CALL dlascl( 'G', 0, 0, cscale, anrm, n-info, 1,
     $                wr( info+1 ),
     $                max( n-info, 1 ), ierr )
         CALL dlascl( 'G', 0, 0, cscale, anrm, n-info, 1,
     $                wi( info+1 ),
     $                max( n-info, 1 ), ierr )
         IF( info.GT.0 ) THEN
            CALL dlascl( 'G', 0, 0, cscale, anrm, ilo-1, 1, wr, n,
     $                   ierr )
            CALL dlascl( 'G', 0, 0, cscale, anrm, ilo-1, 1, wi, n,
     $                   ierr )
         END IF
      END IF
*
      work( 1 ) = maxwrk
      RETURN
*
*     End of DGEEV
*

Here is the call graph for this function:

Here is the caller graph for this function: