zchktp.f

Go to the documentation of this file.

*> \brief \b ZCHKTP
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZCHKTP( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          NMAX, AP, AINVP, B, X, XACT, WORK, RWORK,
*                          NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNS, NOUT
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            NSVAL( * ), NVAL( * )
*       DOUBLE PRECISION   RWORK( * )
*       COMPLEX*16         AINVP( * ), AP( * ), B( * ), WORK( * ), X( * ),
*      $                   XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZCHKTP tests ZTPTRI, -TRS, -RFS, and -CON, and ZLATPS
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The leading dimension of the work arrays.  NMAX >= the
*>          maximum value of N in NVAL.
*> \endverbatim
*>
*> \param[out] AP
*> \verbatim
*>          AP is COMPLEX*16 array, dimension (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] AINVP
*> \verbatim
*>          AINVP is COMPLEX*16 array, dimension (NMAX*(NMAX+1)/2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is COMPLEX*16 array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension
*>                      (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE zchktp( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   NMAX, AP, AINVP, B, X, XACT, WORK, RWORK,
     $                   NOUT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNS, NOUT
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NSVAL( * ), NVAL( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         AINVP( * ), AP( * ), B( * ), WORK( * ), X( * ),
     $                   xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPE1, NTYPES
      PARAMETER          ( NTYPE1 = 10, ntypes = 18 )
      INTEGER            NTESTS
      parameter( ntests = 9 )
      INTEGER            NTRAN
      parameter( ntran = 3 )
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIAG, NORM, TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IDIAG, IMAT, IN, INFO, IRHS, ITRAN, IUPLO,
     $                   k, lap, lda, n, nerrs, nfail, nrhs, nrun
      DOUBLE PRECISION   AINVNM, ANORM, RCOND, RCONDC, RCONDI, RCONDO,
     $                   SCALE
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( NTRAN ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      DOUBLE PRECISION   RESULT( NTESTS )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      DOUBLE PRECISION   ZLANTP
      EXTERNAL           lsame, zlantp
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, zcopy, zerrtr, zget04,
     $                   zlacpy, zlarhs, zlatps, zlattp, ztpcon, ztprfs,
     $                   ztpt01, ztpt02, ztpt03, ztpt05, ztpt06, ztptri,
     $                   ztptrs
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Zomplex precision'
      path( 2: 3 ) = 'TP'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL zerrtr( path, nout )
      infot = 0
*
      DO 110 in = 1, nn
*
*        Do for each value of N in NVAL
*
         n = nval( in )
         lda = max( 1, n )
         lap = lda*( lda+1 ) / 2
         xtype = 'N'
*
         DO 70 imat = 1, ntype1
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 70
*
            DO 60 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
*
*              Call ZLATTP to generate a triangular test matrix.
*
               srnamt = 'ZLATTP'
               CALL zlattp( imat, uplo, 'No transpose', diag, iseed, n,
     $                      ap, x, work, rwork, info )
*
*              Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
               IF( lsame( diag, 'N' ) ) THEN
                  idiag = 1
               ELSE
                  idiag = 2
               END IF
*
*+    TEST 1
*              Form the inverse of A.
*
               IF( n.GT.0 )
     $            CALL zcopy( lap, ap, 1, ainvp, 1 )
               srnamt = 'ZTPTRI'
               CALL ztptri( uplo, diag, n, ainvp, info )
*
*              Check error code from ZTPTRI.
*
               IF( info.NE.0 )
     $            CALL alaerh( path, 'ZTPTRI', info, 0, uplo // diag, n,
     $                         n, -1, -1, -1, imat, nfail, nerrs, nout )
*
*              Compute the infinity-norm condition number of A.
*
               anorm = zlantp( 'I', uplo, diag, n, ap, rwork )
               ainvnm = zlantp( 'I', uplo, diag, n, ainvp, rwork )
               IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                  rcondi = one
               ELSE
                  rcondi = ( one / anorm ) / ainvnm
               END IF
*
*              Compute the residual for the triangular matrix times its
*              inverse.  Also compute the 1-norm condition number of A.
*
               CALL ztpt01( uplo, diag, n, ap, ainvp, rcondo, rwork,
     $                      result( 1 ) )
*
*              Print the test ratio if it is .GE. THRESH.
*
               IF( result( 1 ).GE.thresh ) THEN
                  IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $               CALL alahd( nout, path )
                  WRITE( nout, fmt = 9999 )uplo, diag, n, imat, 1,
     $               result( 1 )
                  nfail = nfail + 1
               END IF
               nrun = nrun + 1
*
               DO 40 irhs = 1, nns
                  nrhs = nsval( irhs )
                  xtype = 'N'
*
                  DO 30 itran = 1, ntran
*
*                 Do for op(A) = A, A**T, or A**H.
*
                     trans = transs( itran )
                     IF( itran.EQ.1 ) THEN
                        norm = 'O'
                        rcondc = rcondo
                     ELSE
                        norm = 'I'
                        rcondc = rcondi
                     END IF
*
*+    TEST 2
*                 Solve and compute residual for op(A)*x = b.
*
                     srnamt = 'ZLARHS'
                     CALL zlarhs( path, xtype, uplo, trans, n, n, 0,
     $                            idiag, nrhs, ap, lap, xact, lda, b,
     $                            lda, iseed, info )
                     xtype = 'C'
                     CALL zlacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                     srnamt = 'ZTPTRS'
                     CALL ztptrs( uplo, trans, diag, n, nrhs, ap, x,
     $                            lda, info )
*
*                 Check error code from ZTPTRS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZTPTRS', info, 0,
     $                               uplo // trans // diag, n, n, -1,
     $                               -1, -1, imat, nfail, nerrs, nout )
*
                     CALL ztpt02( uplo, trans, diag, n, nrhs, ap, x,
     $                            lda, b, lda, work, rwork,
     $                            result( 2 ) )
*
*+    TEST 3
*                 Check solution from generated exact solution.
*
                     CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 3 ) )
*
*+    TESTS 4, 5, and 6
*                 Use iterative refinement to improve the solution and
*                 compute error bounds.
*
                     srnamt = 'ZTPRFS'
                     CALL ztprfs( uplo, trans, diag, n, nrhs, ap, b,
     $                            lda, x, lda, rwork, rwork( nrhs+1 ),
     $                            work, rwork( 2*nrhs+1 ), info )
*
*                 Check error code from ZTPRFS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'ZTPRFS', info, 0,
     $                               uplo // trans // diag, n, n, -1,
     $                               -1, nrhs, imat, nfail, nerrs,
     $                               nout )
*
                     CALL zget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 4 ) )
                     CALL ztpt05( uplo, trans, diag, n, nrhs, ap, b,
     $                            lda, x, lda, xact, lda, rwork,
     $                            rwork( nrhs+1 ), result( 5 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     DO 20 k = 2, 6
                        IF( result( k ).GE.thresh ) THEN
                           IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                        CALL alahd( nout, path )
                           WRITE( nout, fmt = 9998 )uplo, trans, diag,
     $                        n, nrhs, imat, k, result( k )
                           nfail = nfail + 1
                        END IF
   20                CONTINUE
                     nrun = nrun + 5
   30             CONTINUE
   40          CONTINUE
*
*+    TEST 7
*                 Get an estimate of RCOND = 1/CNDNUM.
*
               DO 50 itran = 1, 2
                  IF( itran.EQ.1 ) THEN
                     norm = 'O'
                     rcondc = rcondo
                  ELSE
                     norm = 'I'
                     rcondc = rcondi
                  END IF
                  srnamt = 'ZTPCON'
                  CALL ztpcon( norm, uplo, diag, n, ap, rcond, work,
     $                         rwork, info )
*
*                 Check error code from ZTPCON.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZTPCON', info, 0,
     $                            norm // uplo // diag, n, n, -1, -1,
     $                            -1, imat, nfail, nerrs, nout )
*
                  CALL ztpt06( rcond, rcondc, uplo, diag, n, ap, rwork,
     $                         result( 7 ) )
*
*                 Print the test ratio if it is .GE. THRESH.
*
                  IF( result( 7 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9997 ) 'ZTPCON', norm, uplo,
     $                  diag, n, imat, 7, result( 7 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 1
   50          CONTINUE
   60       CONTINUE
   70    CONTINUE
*
*        Use pathological test matrices to test ZLATPS.
*
         DO 100 imat = ntype1 + 1, ntypes
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( .NOT.dotype( imat ) )
     $         GO TO 100
*
            DO 90 iuplo = 1, 2
*
*              Do first for UPLO = 'U', then for UPLO = 'L'
*
               uplo = uplos( iuplo )
               DO 80 itran = 1, ntran
*
*                 Do for op(A) = A, A**T, or A**H.
*
                  trans = transs( itran )
*
*                 Call ZLATTP to generate a triangular test matrix.
*
                  srnamt = 'ZLATTP'
                  CALL zlattp( imat, uplo, trans, diag, iseed, n, ap, x,
     $                         work, rwork, info )
*
*+    TEST 8
*                 Solve the system op(A)*x = b.
*
                  srnamt = 'ZLATPS'
                  CALL zcopy( n, x, 1, b, 1 )
                  CALL zlatps( uplo, trans, diag, 'N', n, ap, b, scale,
     $                         rwork, info )
*
*                 Check error code from ZLATPS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZLATPS', info, 0,
     $                            uplo // trans // diag // 'N', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ztpt03( uplo, trans, diag, n, 1, ap, scale,
     $                         rwork, one, b, lda, x, lda, work,
     $                         result( 8 ) )
*
*+    TEST 9
*                 Solve op(A)*x = b again with NORMIN = 'Y'.
*
                  CALL zcopy( n, x, 1, b( n+1 ), 1 )
                  CALL zlatps( uplo, trans, diag, 'Y', n, ap, b( n+1 ),
     $                         scale, rwork, info )
*
*                 Check error code from ZLATPS.
*
                  IF( info.NE.0 )
     $               CALL alaerh( path, 'ZLATPS', info, 0,
     $                            uplo // trans // diag // 'Y', n, n,
     $                            -1, -1, -1, imat, nfail, nerrs, nout )
*
                  CALL ztpt03( uplo, trans, diag, n, 1, ap, scale,
     $                         rwork, one, b( n+1 ), lda, x, lda, work,
     $                         result( 9 ) )
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  IF( result( 8 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'ZLATPS', uplo, trans,
     $                  diag, 'N', n, imat, 8, result( 8 )
                     nfail = nfail + 1
                  END IF
                  IF( result( 9 ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL alahd( nout, path )
                     WRITE( nout, fmt = 9996 )'ZLATPS', uplo, trans,
     $                  diag, 'Y', n, imat, 9, result( 9 )
                     nfail = nfail + 1
                  END IF
                  nrun = nrun + 2
   80          CONTINUE
   90       CONTINUE
  100    CONTINUE
  110 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', DIAG=''', a1, ''', N=', i5,
     $      ', type ', i2, ', test(', i2, ')= ', g12.5 )
 9998 FORMAT( ' UPLO=''', a1, ''', TRANS=''', a1, ''', DIAG=''', a1,
     $      ''', N=', i5, ''', NRHS=', i5, ', type ', i2, ', test(',
     $      i2, ')= ', g12.5 )
 9997 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''',',
     $      i5, ', ... ), type ', i2, ', test(', i2, ')=', g12.5 )
 9996 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''', ''',
     $      a1, ''',', i5, ', ... ), type ', i2, ', test(', i2, ')=',
     $      g12.5 )
      RETURN
*
*     End of ZCHKTP
*
      END