ztpt05()

subroutine ztpt05	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	nrhs,
		complex*16, dimension( * )	ap,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( ldxact, * )	xact,
		integer	ldxact,
		double precision, dimension( * )	ferr,
		double precision, dimension( * )	berr,
		double precision, dimension( * )	reslts )

ZTPT05

Purpose:

!>
!> ZTPT05 tests the error bounds from iterative refinement for the
!> computed solution to a system of equations A*X = B, where A is a
!> triangular matrix in packed storage format.
!>
!> RESLTS(1) = test of the error bound
!>           = norm(X - XACT) / ( norm(X) * FERR )
!>
!> A large value is returned if this ratio is not less than one.
!>
!> RESLTS(2) = residual from the iterative refinement routine
!>           = the maximum of BERR / ( (n+1)*EPS + (*) ), where
!>             (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the form of the system of equations. !> = 'N': A * X = B (No transpose) !> = 'T': A'* X = B (Transpose) !> = 'C': A'* X = B (Conjugate transpose = Transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The number of rows of the matrices X, B, and XACT, and the !> order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns of the matrices X, B, and XACT. !> NRHS >= 0. !>
[in]	AP	!> AP is COMPLEX*16 array, dimension (N*(N+1)/2) !> The upper or lower triangular matrix A, packed columnwise in !> a linear array. The j-th column of A is stored in the array !> AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n. !> If DIAG = 'U', the diagonal elements of A are not referenced !> and are assumed to be 1. !>
[in]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in]	X	!> X is COMPLEX*16 array, dimension (LDX,NRHS) !> The computed solution vectors. Each vector is stored as a !> column of the matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	XACT	!> XACT is COMPLEX*16 array, dimension (LDX,NRHS) !> The exact solution vectors. Each vector is stored as a !> column of the matrix XACT. !>
[in]	LDXACT	!> LDXACT is INTEGER !> The leading dimension of the array XACT. LDXACT >= max(1,N). !>
[in]	FERR	!> FERR is DOUBLE PRECISION array, dimension (NRHS) !> The estimated forward error bounds for each solution vector !> X. If XTRUE is the true solution, FERR bounds the magnitude !> of the largest entry in (X - XTRUE) divided by the magnitude !> of the largest entry in X. !>
[in]	BERR	!> BERR is DOUBLE PRECISION array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector (i.e., the smallest relative change in any entry of A !> or B that makes X an exact solution). !>
[out]	RESLTS	!> RESLTS is DOUBLE PRECISION array, dimension (2) !> The maximum over the NRHS solution vectors of the ratios: !> RESLTS(1) = norm(X - XACT) / ( norm(X) * FERR ) !> RESLTS(2) = BERR / ( (n+1)*EPS + (*) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 173 of file ztpt05.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            LDB, LDX, LDXACT, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   BERR( * ), FERR( * ), RESLTS( * )
      COMPLEX*16         AP( * ), B( LDB, * ), X( LDX, * ),
     $                   XACT( LDXACT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOTRAN, UNIT, UPPER
      INTEGER            I, IFU, IMAX, J, JC, K
      DOUBLE PRECISION   AXBI, DIFF, EPS, ERRBND, OVFL, TMP, UNFL, XNORM
      COMPLEX*16         ZDUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           lsame, izamax, dlamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dimag, max, min
*     ..
*     .. Statement Functions ..
      DOUBLE PRECISION   CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( dble( zdum ) ) + abs( dimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0 or NRHS = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         reslts( 1 ) = zero
         reslts( 2 ) = zero
         RETURN
      END IF
*
      eps = dlamch( 'Epsilon' )
      unfl = dlamch( 'Safe minimum' )
      ovfl = one / unfl
      upper = lsame( uplo, 'U' )
      notran = lsame( trans, 'N' )
      unit = lsame( diag, 'U' )
*
*     Test 1:  Compute the maximum of
*        norm(X - XACT) / ( norm(X) * FERR )
*     over all the vectors X and XACT using the infinity-norm.
*
      errbnd = zero
      DO 30 j = 1, nrhs
         imax = izamax( n, x( 1, j ), 1 )
         xnorm = max( cabs1( x( imax, j ) ), unfl )
         diff = zero
         DO 10 i = 1, n
            diff = max( diff, cabs1( x( i, j )-xact( i, j ) ) )
   10    CONTINUE
*
         IF( xnorm.GT.one ) THEN
            GO TO 20
         ELSE IF( diff.LE.ovfl*xnorm ) THEN
            GO TO 20
         ELSE
            errbnd = one / eps
            GO TO 30
         END IF
*
   20    CONTINUE
         IF( diff / xnorm.LE.ferr( j ) ) THEN
            errbnd = max( errbnd, ( diff / xnorm ) / ferr( j ) )
         ELSE
            errbnd = one / eps
         END IF
   30 CONTINUE
      reslts( 1 ) = errbnd
*
*     Test 2:  Compute the maximum of BERR / ( (n+1)*EPS + (*) ), where
*     (*) = (n+1)*UNFL / (min_i (abs(A)*abs(X) +abs(b))_i )
*
      ifu = 0
      IF( unit )
     $   ifu = 1
      DO 90 k = 1, nrhs
         DO 80 i = 1, n
            tmp = cabs1( b( i, k ) )
            IF( upper ) THEN
               jc = ( ( i-1 )*i ) / 2
               IF( .NOT.notran ) THEN
                  DO 40 j = 1, i - ifu
                     tmp = tmp + cabs1( ap( jc+j ) )*cabs1( x( j, k ) )
   40             CONTINUE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  jc = jc + i
                  IF( unit ) THEN
                     tmp = tmp + cabs1( x( i, k ) )
                     jc = jc + i
                  END IF
                  DO 50 j = i + ifu, n
                     tmp = tmp + cabs1( ap( jc ) )*cabs1( x( j, k ) )
                     jc = jc + j
   50             CONTINUE
               END IF
            ELSE
               IF( notran ) THEN
                  jc = i
                  DO 60 j = 1, i - ifu
                     tmp = tmp + cabs1( ap( jc ) )*cabs1( x( j, k ) )
                     jc = jc + n - j
   60             CONTINUE
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
               ELSE
                  jc = ( i-1 )*( n-i ) + ( i*( i+1 ) ) / 2
                  IF( unit )
     $               tmp = tmp + cabs1( x( i, k ) )
                  DO 70 j = i + ifu, n
                     tmp = tmp + cabs1( ap( jc+j-i ) )*
     $                     cabs1( x( j, k ) )
   70             CONTINUE
               END IF
            END IF
            IF( i.EQ.1 ) THEN
               axbi = tmp
            ELSE
               axbi = min( axbi, tmp )
            END IF
   80    CONTINUE
         tmp = berr( k ) / ( ( n+1 )*eps+( n+1 )*unfl /
     $         max( axbi, ( n+1 )*unfl ) )
         IF( k.EQ.1 ) THEN
            reslts( 2 ) = tmp
         ELSE
            reslts( 2 ) = max( reslts( 2 ), tmp )
         END IF
   90 CONTINUE
*
      RETURN
*
*     End of ZTPT05
*

Here is the caller graph for this function: