ztpt03()

subroutine ztpt03	(	character	uplo,
		character	trans,
		character	diag,
		integer	n,
		integer	nrhs,
		complex*16, dimension( * )	ap,
		double precision	scale,
		double precision, dimension( * )	cnorm,
		double precision	tscal,
		complex*16, dimension( ldx, * )	x,
		integer	ldx,
		complex*16, dimension( ldb, * )	b,
		integer	ldb,
		complex*16, dimension( * )	work,
		double precision	resid )

ZTPT03

Purpose:

!>
!> ZTPT03 computes the residual for the solution to a scaled triangular
!> system of equations A*x = s*b,  A**T *x = s*b,  or  A**H *x = s*b,
!> when the triangular matrix A is stored in packed format.  Here A**T
!> denotes the transpose of A, A**H denotes the conjugate transpose of
!> A, s is a scalar, and x and b are N by NRHS matrices.  The test ratio
!> is the maximum over the number of right hand sides of
!>    norm(s*b - op(A)*x) / ( norm(op(A)) * norm(x) * EPS ),
!> where op(A) denotes A, A**T, or A**H, and EPS is the machine epsilon.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the matrix A is upper or lower triangular. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	TRANS	!> TRANS is CHARACTER*1 !> Specifies the operation applied to A. !> = 'N': A *x = s*b (No transpose) !> = 'T': A**T *x = s*b (Transpose) !> = 'C': A**H *x = s*b (Conjugate transpose) !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> Specifies whether or not the matrix A is unit triangular. !> = 'N': Non-unit triangular !> = 'U': Unit triangular !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrices X and B. NRHS >= 0. !>
[in]	AP	!> AP is COMPLEX*16 array, dimension (N*(N+1)/2) !> The upper or lower triangular matrix A, packed columnwise in !> a linear array. The j-th column of A is stored in the array !> AP as follows: !> if UPLO = 'U', AP((j-1)*j/2 + i) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', !> AP((j-1)*(n-j) + j*(j+1)/2 + i-j) = A(i,j) for j<=i<=n. !>
[in]	SCALE	!> SCALE is DOUBLE PRECISION !> The scaling factor s used in solving the triangular system. !>
[in]	CNORM	!> CNORM is DOUBLE PRECISION array, dimension (N) !> The 1-norms of the columns of A, not counting the diagonal. !>
[in]	TSCAL	!> TSCAL is DOUBLE PRECISION !> The scaling factor used in computing the 1-norms in CNORM. !> CNORM actually contains the column norms of TSCAL*A. !>
[in]	X	!> X is COMPLEX*16 array, dimension (LDX,NRHS) !> The computed solution vectors for the system of linear !> equations. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[in]	B	!> B is COMPLEX*16 array, dimension (LDB,NRHS) !> The right hand side vectors for the system of linear !> equations. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (N) !>
[out]	RESID	!> RESID is DOUBLE PRECISION !> The maximum over the number of right hand sides of !> norm(op(A)*x - s*b) / ( norm(op(A)) * norm(x) * EPS ). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 160 of file ztpt03.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            LDB, LDX, N, NRHS
      DOUBLE PRECISION   RESID, SCALE, TSCAL
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   CNORM( * )
      COMPLEX*16         AP( * ), B( LDB, * ), WORK( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            IX, J, JJ
      DOUBLE PRECISION   EPS, ERR, SMLNUM, TNORM, XNORM, XSCAL
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            IZAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           lsame, izamax, dlamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy, zdscal, ztpmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dcmplx, max
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 .OR. nrhs.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
      eps = dlamch( 'Epsilon' )
      smlnum = dlamch( 'Safe minimum' )
*
*     Compute the norm of the triangular matrix A using the column
*     norms already computed by ZLATPS.
*
      tnorm = 0.d0
      IF( lsame( diag, 'N' ) ) THEN
         IF( lsame( uplo, 'U' ) ) THEN
            jj = 1
            DO 10 j = 1, n
               tnorm = max( tnorm, tscal*abs( ap( jj ) )+cnorm( j ) )
               jj = jj + j
   10       CONTINUE
         ELSE
            jj = 1
            DO 20 j = 1, n
               tnorm = max( tnorm, tscal*abs( ap( jj ) )+cnorm( j ) )
               jj = jj + n - j + 1
   20       CONTINUE
         END IF
      ELSE
         DO 30 j = 1, n
            tnorm = max( tnorm, tscal+cnorm( j ) )
   30    CONTINUE
      END IF
*
*     Compute the maximum over the number of right hand sides of
*        norm(op(A)*x - s*b) / ( norm(A) * norm(x) * EPS ).
*
      resid = zero
      DO 40 j = 1, nrhs
         CALL zcopy( n, x( 1, j ), 1, work, 1 )
         ix = izamax( n, work, 1 )
         xnorm = max( one, abs( x( ix, j ) ) )
         xscal = ( one / xnorm ) / dble( n )
         CALL zdscal( n, xscal, work, 1 )
         CALL ztpmv( uplo, trans, diag, n, ap, work, 1 )
         CALL zaxpy( n, dcmplx( -scale*xscal ), b( 1, j ), 1, work, 1 )
         ix = izamax( n, work, 1 )
         err = tscal*abs( work( ix ) )
         ix = izamax( n, x( 1, j ), 1 )
         xnorm = abs( x( ix, j ) )
         IF( err*smlnum.LE.xnorm ) THEN
            IF( xnorm.GT.zero )
     $         err = err / xnorm
         ELSE
            IF( err.GT.zero )
     $         err = one / eps
         END IF
         IF( err*smlnum.LE.tnorm ) THEN
            IF( tnorm.GT.zero )
     $         err = err / tnorm
         ELSE
            IF( err.GT.zero )
     $         err = one / eps
         END IF
         resid = max( resid, err )
   40 CONTINUE
*
      RETURN
*
*     End of ZTPT03
*

Here is the call graph for this function:

Here is the caller graph for this function: