ztptri()

subroutine ztptri	(	character	uplo,
		character	diag,
		integer	n,
		complex*16, dimension( * )	ap,
		integer	info )

ZTPTRI

Download ZTPTRI + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZTPTRI computes the inverse of a complex upper or lower triangular
!> matrix A stored in packed format.
!> 

Parameters

[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': A is upper triangular; !> = 'L': A is lower triangular. !>
[in]	DIAG	!> DIAG is CHARACTER*1 !> = 'N': A is non-unit triangular; !> = 'U': A is unit triangular. !>
[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	AP	!> AP is COMPLEX*16 array, dimension (N*(N+1)/2) !> On entry, the upper or lower triangular matrix A, stored !> columnwise in a linear array. The j-th column of A is stored !> in the array AP as follows: !> if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j; !> if UPLO = 'L', AP(i + (j-1)*((2*n-j)/2) = A(i,j) for j<=i<=n. !> See below for further details. !> On exit, the (triangular) inverse of the original matrix, in !> the same packed storage format. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !> > 0: if INFO = i, A(i,i) is exactly zero. The triangular !> matrix is singular and its inverse can not be computed. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  A triangular matrix A can be transferred to packed storage using one
!>  of the following program segments:
!>
!>  UPLO = 'U':                      UPLO = 'L':
!>
!>        JC = 1                           JC = 1
!>        DO 2 J = 1, N                    DO 2 J = 1, N
!>           DO 1 I = 1, J                    DO 1 I = J, N
!>              AP(JC+I-1) = A(I,J)              AP(JC+I-J) = A(I,J)
!>      1    CONTINUE                    1    CONTINUE
!>           JC = JC + J                      JC = JC + N - J + 1
!>      2 CONTINUE                       2 CONTINUE
!> 

Definition at line 114 of file ztptri.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT, UPPER
      INTEGER            J, JC, JCLAST, JJ
      COMPLEX*16         AJJ
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zscal, ztpmv
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      nounit = lsame( diag, 'N' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.nounit .AND. .NOT.lsame( diag, 'U' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZTPTRI', -info )
         RETURN
      END IF
*
*     Check for singularity if non-unit.
*
      IF( nounit ) THEN
         IF( upper ) THEN
            jj = 0
            DO 10 info = 1, n
               jj = jj + info
               IF( ap( jj ).EQ.zero )
     $            RETURN
   10       CONTINUE
         ELSE
            jj = 1
            DO 20 info = 1, n
               IF( ap( jj ).EQ.zero )
     $            RETURN
               jj = jj + n - info + 1
   20       CONTINUE
         END IF
         info = 0
      END IF
*
      IF( upper ) THEN
*
*        Compute inverse of upper triangular matrix.
*
         jc = 1
         DO 30 j = 1, n
            IF( nounit ) THEN
               ap( jc+j-1 ) = one / ap( jc+j-1 )
               ajj = -ap( jc+j-1 )
            ELSE
               ajj = -one
            END IF
*
*           Compute elements 1:j-1 of j-th column.
*
            CALL ztpmv( 'Upper', 'No transpose', diag, j-1, ap,
     $                  ap( jc ), 1 )
            CALL zscal( j-1, ajj, ap( jc ), 1 )
            jc = jc + j
   30    CONTINUE
*
      ELSE
*
*        Compute inverse of lower triangular matrix.
*
         jc = n*( n+1 ) / 2
         DO 40 j = n, 1, -1
            IF( nounit ) THEN
               ap( jc ) = one / ap( jc )
               ajj = -ap( jc )
            ELSE
               ajj = -one
            END IF
            IF( j.LT.n ) THEN
*
*              Compute elements j+1:n of j-th column.
*
               CALL ztpmv( 'Lower', 'No transpose', diag, n-j,
     $                     ap( jclast ), ap( jc+1 ), 1 )
               CALL zscal( n-j, ajj, ap( jc+1 ), 1 )
            END IF
            jclast = jc
            jc = jc - n + j - 2
   40    CONTINUE
      END IF
*
      RETURN
*
*     End of ZTPTRI
*

Here is the call graph for this function:

Here is the caller graph for this function: