zqrt04()

subroutine zqrt04	(	integer	m,
		integer	n,
		integer	nb,
		double precision, dimension(6)	result
	)

ZQRT04

Purpose:

 ZQRT04 tests ZGEQRT and ZGEMQRT.

Parameters

[in]	M	M is INTEGER Number of rows in test matrix.
[in]	N	N is INTEGER Number of columns in test matrix.
[in]	NB	NB is INTEGER Block size of test matrix. NB <= Min(M,N).
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (6) Results of each of the six tests below. RESULT(1) = | A - Q R | RESULT(2) = | I - Q^H Q | RESULT(3) = | Q C - Q C | RESULT(4) = | Q^H C - Q^H C | RESULT(5) = | C Q - C Q | RESULT(6) = | C Q^H - C Q^H |

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 72 of file zqrt04.f.

      IMPLICIT NONE
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER M, N, NB, LDT
*     .. Return values ..
      DOUBLE PRECISION RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      COMPLEX*16, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  R(:,:), WORK( : ), T(:,:),
     $  CF(:,:), DF(:,:), A(:,:), C(:,:), D(:,:)
      DOUBLE PRECISION, ALLOCATABLE :: RWORK(:)
*
*     .. Parameters ..
      DOUBLE PRECISION ZERO
      COMPLEX*16 ONE, CZERO
      parameter( zero = 0.0, one = (1.0,0.0), czero=(0.0,0.0) )
*     ..
*     .. Local Scalars ..
      INTEGER INFO, J, K, L, LWORK
      DOUBLE PRECISION   ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DLAMCH
      DOUBLE PRECISION ZLANGE, ZLANSY
      LOGICAL  LSAME
      EXTERNAL dlamch, zlange, zlansy, lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
      eps = dlamch( 'Epsilon' )
      k = min(m,n)
      l = max(m,n)
      lwork = max(2,l)*max(2,l)*nb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(m,m), r(m,l), rwork(l),
     $           work(lwork), t(nb,n), c(m,n), cf(m,n),
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      ldt=nb
      DO j=1,n
         CALL zlarnv( 2, iseed, m, a( 1, j ) )
      END DO
      CALL zlacpy( 'Full', m, n, a, m, af, m )
*
*     Factor the matrix A in the array AF.
*
      CALL zgeqrt( m, n, nb, af, m, t, ldt, work, info )
*
*     Generate the m-by-m matrix Q
*
      CALL zlaset( 'Full', m, m, czero, one, q, m )
      CALL zgemqrt( 'R', 'N', m, m, k, nb, af, m, t, ldt, q, m,
     $              work, info )
*
*     Copy R
*
      CALL zlaset( 'Full', m, n, czero, czero, r, m )
      CALL zlacpy( 'Upper', m, n, af, m, r, m )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL zgemm( 'C', 'N', m, n, m, -one, q, m, a, m, one, r, m )
      anorm = zlange( '1', m, n, a, m, rwork )
      resid = zlange( '1', m, n, r, m, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL zlaset( 'Full', m, m, czero, one, r, m )
      CALL zherk( 'U', 'C', m, m, dreal(-one), q, m, dreal(one), r, m )
      resid = zlansy( '1', 'Upper', m, r, m, rwork )
      result( 2 ) = resid / (eps*max(1,m))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL zlarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = zlange( '1', m, n, c, m, rwork)
      CALL zlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as Q*C
*
      CALL zgemqrt( 'L', 'N', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL zgemm( 'N', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = zlange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL zlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as QT*C
*
      CALL zgemqrt( 'L', 'C', m, n, k, nb, af, m, t, nb, cf, m,
     $             work, info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL zgemm( 'C', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = zlange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m
         CALL zlarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = zlange( '1', n, m, d, n, rwork)
      CALL zlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      CALL zgemqrt( 'R', 'N', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL zgemm( 'N', 'N', n, m, m, -one, d, n, q, m, one, df, n )
      resid = zlange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL zlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*QT
*
      CALL zgemqrt( 'R', 'C', n, m, k, nb, af, m, t, nb, df, n,
     $             work, info)
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL zgemm( 'N', 'C', n, m, m, -one, d, n, q, m, one, df, n )
      resid = zlange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
*
      RETURN

Here is the call graph for this function:

Here is the caller graph for this function: