dgrqts.f

Go to the documentation of this file.

*> \brief \b DGRQTS
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DGRQTS( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
*                          BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LDB, LWORK, M, N, P
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), B( LDB, * ),
*      $                   BF( LDB, * ), BWK( LDB, * ), Q( LDA, * ),
*      $                   R( LDA, * ), RESULT( 4 ), RWORK( * ),
*      $                   T( LDB, * ), TAUA( * ), TAUB( * ),
*      $                   WORK( LWORK ), Z( LDB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DGRQTS tests DGGRQF, which computes the GRQ factorization of an
*> M-by-N matrix A and a P-by-N matrix B: A = R*Q and B = Z*T*Q.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of rows of the matrix B.  P >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrices A and B.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>          The M-by-N matrix A.
*> \endverbatim
*>
*> \param[out] AF
*> \verbatim
*>          AF is DOUBLE PRECISION array, dimension (LDA,N)
*>          Details of the GRQ factorization of A and B, as returned
*>          by DGGRQF, see SGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is DOUBLE PRECISION array, dimension (LDA,N)
*>          The N-by-N orthogonal matrix Q.
*> \endverbatim
*>
*> \param[out] R
*> \verbatim
*>          R is DOUBLE PRECISION array, dimension (LDA,MAX(M,N))
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the arrays A, AF, R and Q.
*>          LDA >= max(M,N).
*> \endverbatim
*>
*> \param[out] TAUA
*> \verbatim
*>          TAUA is DOUBLE PRECISION array, dimension (min(M,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by DGGQRC.
*> \endverbatim
*>
*> \param[in] B
*> \verbatim
*>          B is DOUBLE PRECISION array, dimension (LDB,N)
*>          On entry, the P-by-N matrix A.
*> \endverbatim
*>
*> \param[out] BF
*> \verbatim
*>          BF is DOUBLE PRECISION array, dimension (LDB,N)
*>          Details of the GQR factorization of A and B, as returned
*>          by DGGRQF, see SGGRQF for further details.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (LDB,P)
*>          The P-by-P orthogonal matrix Z.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is DOUBLE PRECISION array, dimension (LDB,max(P,N))
*> \endverbatim
*>
*> \param[out] BWK
*> \verbatim
*>          BWK is DOUBLE PRECISION array, dimension (LDB,N)
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the arrays B, BF, Z and T.
*>          LDB >= max(P,N).
*> \endverbatim
*>
*> \param[out] TAUB
*> \verbatim
*>          TAUB is DOUBLE PRECISION array, dimension (min(P,N))
*>          The scalar factors of the elementary reflectors, as returned
*>          by DGGRQF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK, LWORK >= max(M,P,N)**2.
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (M)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (4)
*>          The test ratios:
*>            RESULT(1) = norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP)
*>            RESULT(2) = norm( T*Q - Z'*B ) / (MAX(P,N)*norm(B)*ULP)
*>            RESULT(3) = norm( I - Q'*Q ) / ( N*ULP )
*>            RESULT(4) = norm( I - Z'*Z ) / ( P*ULP )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE dgrqts( M, P, N, A, AF, Q, R, LDA, TAUA, B, BF, Z, T,
     $                   BWK, LDB, TAUB, WORK, LWORK, RWORK, RESULT )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LWORK, M, N, P
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), B( LDB, * ),
     $                   bf( ldb, * ), bwk( ldb, * ), q( lda, * ),
     $                   r( lda, * ), result( 4 ), rwork( * ),
     $                   t( ldb, * ), taua( * ), taub( * ),
     $                   work( lwork ), z( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   ROGUE
      parameter( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, BNORM, RESID, ULP, UNFL
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dggrqf, dlacpy, dlaset, dorgqr, dorgrq,
     $                   dsyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max, min
*     ..
*     .. Executable Statements ..
*
      ulp = dlamch( 'Precision' )
      unfl = dlamch( 'Safe minimum' )
*
*     Copy the matrix A to the array AF.
*
      CALL dlacpy( 'Full', m, n, a, lda, af, lda )
      CALL dlacpy( 'Full', p, n, b, ldb, bf, ldb )
*
      anorm = max( dlange( '1', m, n, a, lda, rwork ), unfl )
      bnorm = max( dlange( '1', p, n, b, ldb, rwork ), unfl )
*
*     Factorize the matrices A and B in the arrays AF and BF.
*
      CALL dggrqf( m, p, n, af, lda, taua, bf, ldb, taub, work, lwork,
     $             info )
*
*     Generate the N-by-N matrix Q
*
      CALL dlaset( 'Full', n, n, rogue, rogue, q, lda )
      IF( m.LE.n ) THEN
         IF( m.GT.0 .AND. m.LT.n )
     $      CALL dlacpy( 'Full', m, n-m, af, lda, q( n-m+1, 1 ), lda )
         IF( m.GT.1 )
     $      CALL dlacpy( 'Lower', m-1, m-1, af( 2, n-m+1 ), lda,
     $                   q( n-m+2, n-m+1 ), lda )
      ELSE
         IF( n.GT.1 )
     $      CALL dlacpy( 'Lower', n-1, n-1, af( m-n+2, 1 ), lda,
     $                   q( 2, 1 ), lda )
      END IF
      CALL dorgrq( n, n, min( m, n ), q, lda, taua, work, lwork, info )
*
*     Generate the P-by-P matrix Z
*
      CALL dlaset( 'Full', p, p, rogue, rogue, z, ldb )
      IF( p.GT.1 )
     $   CALL dlacpy( 'Lower', p-1, n, bf( 2, 1 ), ldb, z( 2, 1 ), ldb )
      CALL dorgqr( p, p, min( p, n ), z, ldb, taub, work, lwork, info )
*
*     Copy R
*
      CALL dlaset( 'Full', m, n, zero, zero, r, lda )
      IF( m.LE.n ) THEN
         CALL dlacpy( 'Upper', m, m, af( 1, n-m+1 ), lda, r( 1, n-m+1 ),
     $                lda )
      ELSE
         CALL dlacpy( 'Full', m-n, n, af, lda, r, lda )
         CALL dlacpy( 'Upper', n, n, af( m-n+1, 1 ), lda, r( m-n+1, 1 ),
     $                lda )
      END IF
*
*     Copy T
*
      CALL dlaset( 'Full', p, n, zero, zero, t, ldb )
      CALL dlacpy( 'Upper', p, n, bf, ldb, t, ldb )
*
*     Compute R - A*Q'
*
      CALL dgemm( 'No transpose', 'Transpose', m, n, n, -one, a, lda, q,
     $            lda, one, r, lda )
*
*     Compute norm( R - A*Q' ) / ( MAX(M,N)*norm(A)*ULP ) .
*
      resid = dlange( '1', m, n, r, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, m, n ) ) ) / anorm ) /
     $                 ulp
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute T*Q - Z'*B
*
      CALL dgemm( 'Transpose', 'No transpose', p, n, p, one, z, ldb, b,
     $            ldb, zero, bwk, ldb )
      CALL dgemm( 'No transpose', 'No transpose', p, n, n, one, t, ldb,
     $            q, lda, -one, bwk, ldb )
*
*     Compute norm( T*Q - Z'*B ) / ( MAX(P,N)*norm(A)*ULP ) .
*
      resid = dlange( '1', p, n, bwk, ldb, rwork )
      IF( bnorm.GT.zero ) THEN
         result( 2 ) = ( ( resid / dble( max( 1, p, m ) ) ) / bnorm ) /
     $                 ulp
      ELSE
         result( 2 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL dlaset( 'Full', n, n, zero, one, r, lda )
      CALL dsyrk( 'Upper', 'No Transpose', n, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q'*Q ) / ( N * ULP ) .
*
      resid = dlansy( '1', 'Upper', n, r, lda, rwork )
      result( 3 ) = ( resid / dble( max( 1, n ) ) ) / ulp
*
*     Compute I - Z'*Z
*
      CALL dlaset( 'Full', p, p, zero, one, t, ldb )
      CALL dsyrk( 'Upper', 'Transpose', p, p, -one, z, ldb, one, t,
     $            ldb )
*
*     Compute norm( I - Z'*Z ) / ( P*ULP ) .
*
      resid = dlansy( '1', 'Upper', p, t, ldb, rwork )
      result( 4 ) = ( resid / dble( max( 1, p ) ) ) / ulp
*
      RETURN
*
*     End of DGRQTS
*
      END