ssygst()

subroutine ssygst	(	integer	itype,
		character	uplo,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

SSYGST

Download SSYGST + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SSYGST reduces a real symmetric-definite generalized eigenproblem
!> to standard form.
!>
!> If ITYPE = 1, the problem is A*x = lambda*B*x,
!> and A is overwritten by inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T)
!>
!> If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
!> B*A*x = lambda*x, and A is overwritten by U*A*U**T or L**T*A*L.
!>
!> B must have been previously factorized as U**T*U or L*L**T by SPOTRF.
!> 

Parameters

[in]	ITYPE	!> ITYPE is INTEGER !> = 1: compute inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T); !> = 2 or 3: compute U*A*U**T or L**T*A*L. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> = 'U': Upper triangle of A is stored and B is factored as !> U**T*U; !> = 'L': Lower triangle of A is stored and B is factored as !> L*L**T. !>
[in]	N	!> N is INTEGER !> The order of the matrices A and B. N >= 0. !>
[in,out]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the symmetric matrix A. If UPLO = 'U', the leading !> N-by-N upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading N-by-N lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, if INFO = 0, the transformed matrix, stored in the !> same format as A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	B	!> B is REAL array, dimension (LDB,N) !> The triangular factor from the Cholesky factorization of B, !> as returned by SPOTRF. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file ssygst.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, HALF
      parameter( one = 1.0, half = 0.5 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            K, KB, NB
*     ..
*     .. External Subroutines ..
      EXTERNAL           ssygs2, ssymm, ssyr2k, strmm, strsm,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      EXTERNAL           lsame, ilaenv
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSYGST', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Determine the block size for this environment.
*
      nb = ilaenv( 1, 'SSYGST', uplo, n, -1, -1, -1 )
*
      IF( nb.LE.1 .OR. nb.GE.n ) THEN
*
*        Use unblocked code
*
         CALL ssygs2( itype, uplo, n, a, lda, b, ldb, info )
      ELSE
*
*        Use blocked code
*
         IF( itype.EQ.1 ) THEN
            IF( upper ) THEN
*
*              Compute inv(U**T)*A*inv(U)
*
               DO 10 k = 1, n, nb
                  kb = min( n-k+1, nb )
*
*                 Update the upper triangle of A(k:n,k:n)
*
                  CALL ssygs2( itype, uplo, kb, a( k, k ), lda,
     $                         b( k, k ), ldb, info )
                  IF( k+kb.LE.n ) THEN
                     CALL strsm( 'Left', uplo, 'Transpose',
     $                           'Non-unit',
     $                           kb, n-k-kb+1, one, b( k, k ), ldb,
     $                           a( k, k+kb ), lda )
                     CALL ssymm( 'Left', uplo, kb, n-k-kb+1, -half,
     $                           a( k, k ), lda, b( k, k+kb ), ldb, one,
     $                           a( k, k+kb ), lda )
                     CALL ssyr2k( uplo, 'Transpose', n-k-kb+1, kb,
     $                            -one,
     $                            a( k, k+kb ), lda, b( k, k+kb ), ldb,
     $                            one, a( k+kb, k+kb ), lda )
                     CALL ssymm( 'Left', uplo, kb, n-k-kb+1, -half,
     $                           a( k, k ), lda, b( k, k+kb ), ldb, one,
     $                           a( k, k+kb ), lda )
                     CALL strsm( 'Right', uplo, 'No transpose',
     $                           'Non-unit', kb, n-k-kb+1, one,
     $                           b( k+kb, k+kb ), ldb, a( k, k+kb ),
     $                           lda )
                  END IF
   10          CONTINUE
            ELSE
*
*              Compute inv(L)*A*inv(L**T)
*
               DO 20 k = 1, n, nb
                  kb = min( n-k+1, nb )
*
*                 Update the lower triangle of A(k:n,k:n)
*
                  CALL ssygs2( itype, uplo, kb, a( k, k ), lda,
     $                         b( k, k ), ldb, info )
                  IF( k+kb.LE.n ) THEN
                     CALL strsm( 'Right', uplo, 'Transpose',
     $                           'Non-unit',
     $                           n-k-kb+1, kb, one, b( k, k ), ldb,
     $                           a( k+kb, k ), lda )
                     CALL ssymm( 'Right', uplo, n-k-kb+1, kb, -half,
     $                           a( k, k ), lda, b( k+kb, k ), ldb, one,
     $                           a( k+kb, k ), lda )
                     CALL ssyr2k( uplo, 'No transpose', n-k-kb+1, kb,
     $                            -one, a( k+kb, k ), lda, b( k+kb, k ),
     $                            ldb, one, a( k+kb, k+kb ), lda )
                     CALL ssymm( 'Right', uplo, n-k-kb+1, kb, -half,
     $                           a( k, k ), lda, b( k+kb, k ), ldb, one,
     $                           a( k+kb, k ), lda )
                     CALL strsm( 'Left', uplo, 'No transpose',
     $                           'Non-unit', n-k-kb+1, kb, one,
     $                           b( k+kb, k+kb ), ldb, a( k+kb, k ),
     $                           lda )
                  END IF
   20          CONTINUE
            END IF
         ELSE
            IF( upper ) THEN
*
*              Compute U*A*U**T
*
               DO 30 k = 1, n, nb
                  kb = min( n-k+1, nb )
*
*                 Update the upper triangle of A(1:k+kb-1,1:k+kb-1)
*
                  CALL strmm( 'Left', uplo, 'No transpose',
     $                        'Non-unit',
     $                        k-1, kb, one, b, ldb, a( 1, k ), lda )
                  CALL ssymm( 'Right', uplo, k-1, kb, half, a( k,
     $                        k ),
     $                        lda, b( 1, k ), ldb, one, a( 1, k ), lda )
                  CALL ssyr2k( uplo, 'No transpose', k-1, kb, one,
     $                         a( 1, k ), lda, b( 1, k ), ldb, one, a,
     $                         lda )
                  CALL ssymm( 'Right', uplo, k-1, kb, half, a( k,
     $                        k ),
     $                        lda, b( 1, k ), ldb, one, a( 1, k ), lda )
                  CALL strmm( 'Right', uplo, 'Transpose', 'Non-unit',
     $                        k-1, kb, one, b( k, k ), ldb, a( 1, k ),
     $                        lda )
                  CALL ssygs2( itype, uplo, kb, a( k, k ), lda,
     $                         b( k, k ), ldb, info )
   30          CONTINUE
            ELSE
*
*              Compute L**T*A*L
*
               DO 40 k = 1, n, nb
                  kb = min( n-k+1, nb )
*
*                 Update the lower triangle of A(1:k+kb-1,1:k+kb-1)
*
                  CALL strmm( 'Right', uplo, 'No transpose',
     $                        'Non-unit',
     $                        kb, k-1, one, b, ldb, a( k, 1 ), lda )
                  CALL ssymm( 'Left', uplo, kb, k-1, half, a( k, k ),
     $                        lda, b( k, 1 ), ldb, one, a( k, 1 ), lda )
                  CALL ssyr2k( uplo, 'Transpose', k-1, kb, one,
     $                         a( k, 1 ), lda, b( k, 1 ), ldb, one, a,
     $                         lda )
                  CALL ssymm( 'Left', uplo, kb, k-1, half, a( k, k ),
     $                        lda, b( k, 1 ), ldb, one, a( k, 1 ), lda )
                  CALL strmm( 'Left', uplo, 'Transpose', 'Non-unit',
     $                        kb,
     $                        k-1, one, b( k, k ), ldb, a( k, 1 ), lda )
                  CALL ssygs2( itype, uplo, kb, a( k, k ), lda,
     $                         b( k, k ), ldb, info )
   40          CONTINUE
            END IF
         END IF
      END IF
      RETURN
*
*     End of SSYGST
*

Here is the call graph for this function:

Here is the caller graph for this function: