ssygs2()

subroutine ssygs2	(	integer	itype,
		character	uplo,
		integer	n,
		real, dimension( lda, * )	a,
		integer	lda,
		real, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

SSYGS2 reduces a symmetric definite generalized eigenproblem to standard form, using the factorization results obtained from spotrf (unblocked algorithm).

Download SSYGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> SSYGS2 reduces a real symmetric-definite generalized eigenproblem
!> to standard form.
!>
!> If ITYPE = 1, the problem is A*x = lambda*B*x,
!> and A is overwritten by inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T)
!>
!> If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
!> B*A*x = lambda*x, and A is overwritten by U*A*U**T or L**T *A*L.
!>
!> B must have been previously factorized as U**T *U or L*L**T by SPOTRF.
!> 

Parameters

[in]	ITYPE	!> ITYPE is INTEGER !> = 1: compute inv(U**T)*A*inv(U) or inv(L)*A*inv(L**T); !> = 2 or 3: compute U*A*U**T or L**T *A*L. !>
[in]	UPLO	!> UPLO is CHARACTER*1 !> Specifies whether the upper or lower triangular part of the !> symmetric matrix A is stored, and how B has been factorized. !> = 'U': Upper triangular !> = 'L': Lower triangular !>
[in]	N	!> N is INTEGER !> The order of the matrices A and B. N >= 0. !>
[in,out]	A	!> A is REAL array, dimension (LDA,N) !> On entry, the symmetric matrix A. If UPLO = 'U', the leading !> n by n upper triangular part of A contains the upper !> triangular part of the matrix A, and the strictly lower !> triangular part of A is not referenced. If UPLO = 'L', the !> leading n by n lower triangular part of A contains the lower !> triangular part of the matrix A, and the strictly upper !> triangular part of A is not referenced. !> !> On exit, if INFO = 0, the transformed matrix, stored in the !> same format as A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,N). !>
[in]	B	!> B is REAL array, dimension (LDB,N) !> The triangular factor from the Cholesky factorization of B, !> as returned by SPOTRF. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 124 of file ssygs2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, ITYPE, LDA, LDB, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, HALF
      parameter( one = 1.0, half = 0.5 )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            K
      REAL               AKK, BKK, CT
*     ..
*     .. External Subroutines ..
      EXTERNAL           saxpy, sscal, ssyr2, strmv, strsv,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         info = -1
      ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -7
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSYGS2', -info )
         RETURN
      END IF
*
      IF( itype.EQ.1 ) THEN
         IF( upper ) THEN
*
*           Compute inv(U**T)*A*inv(U)
*
            DO 10 k = 1, n
*
*              Update the upper triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL sscal( n-k, one / bkk, a( k, k+1 ), lda )
                  ct = -half*akk
                  CALL saxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL ssyr2( uplo, n-k, -one, a( k, k+1 ), lda,
     $                        b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
                  CALL saxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
     $                        lda )
                  CALL strsv( uplo, 'Transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k, k+1 ), lda )
               END IF
   10       CONTINUE
         ELSE
*
*           Compute inv(L)*A*inv(L**T)
*
            DO 20 k = 1, n
*
*              Update the lower triangle of A(k:n,k:n)
*
               akk = a( k, k )
               bkk = b( k, k )
               akk = akk / bkk**2
               a( k, k ) = akk
               IF( k.LT.n ) THEN
                  CALL sscal( n-k, one / bkk, a( k+1, k ), 1 )
                  ct = -half*akk
                  CALL saxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ),
     $                        1 )
                  CALL ssyr2( uplo, n-k, -one, a( k+1, k ), 1,
     $                        b( k+1, k ), 1, a( k+1, k+1 ), lda )
                  CALL saxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ),
     $                        1 )
                  CALL strsv( uplo, 'No transpose', 'Non-unit', n-k,
     $                        b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
               END IF
   20       CONTINUE
         END IF
      ELSE
         IF( upper ) THEN
*
*           Compute U*A*U**T
*
            DO 30 k = 1, n
*
*              Update the upper triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL strmv( uplo, 'No transpose', 'Non-unit', k-1, b,
     $                     ldb, a( 1, k ), 1 )
               ct = half*akk
               CALL saxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL ssyr2( uplo, k-1, one, a( 1, k ), 1, b( 1, k ),
     $                     1,
     $                     a, lda )
               CALL saxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
               CALL sscal( k-1, bkk, a( 1, k ), 1 )
               a( k, k ) = akk*bkk**2
   30       CONTINUE
         ELSE
*
*           Compute L**T *A*L
*
            DO 40 k = 1, n
*
*              Update the lower triangle of A(1:k,1:k)
*
               akk = a( k, k )
               bkk = b( k, k )
               CALL strmv( uplo, 'Transpose', 'Non-unit', k-1, b,
     $                     ldb,
     $                     a( k, 1 ), lda )
               ct = half*akk
               CALL saxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL ssyr2( uplo, k-1, one, a( k, 1 ), lda, b( k, 1 ),
     $                     ldb, a, lda )
               CALL saxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
               CALL sscal( k-1, bkk, a( k, 1 ), lda )
               a( k, k ) = akk*bkk**2
   40       CONTINUE
         END IF
      END IF
      RETURN
*
*     End of SSYGS2
*

Here is the call graph for this function:

Here is the caller graph for this function: