dqrt11.f

Go to the documentation of this file.

*> \brief \b DQRT11
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION DQRT11( M, K, A, LDA, TAU, WORK, LWORK )
*
*       .. Scalar Arguments ..
*       INTEGER            K, LDA, LWORK, M
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DQRT11 computes the test ratio
*>
*>       || Q'*Q - I || / (eps * m)
*>
*> where the orthogonal matrix Q is represented as a product of
*> elementary transformations.  Each transformation has the form
*>
*>    H(k) = I - tau(k) v(k) v(k)'
*>
*> where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
*> [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
*> in A(k+1:m,k).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.
*> \endverbatim
*>
*> \param[in] K
*> \verbatim
*>          K is INTEGER
*>          The number of columns of A whose subdiagonal entries
*>          contain information about orthogonal transformations.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,K)
*>          The (possibly partial) output of a QR reduction routine.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (K)
*>          The scaling factors tau for the elementary transformations as
*>          computed by the QR factorization routine.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of the array WORK.  LWORK >= M*M + M.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION dqrt11( M, K, A, LDA, TAU, WORK, LWORK )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            k, lda, lwork, m
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            info, j
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlaset, dorm2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rdummy( 1 )
*     ..
*     .. Executable Statements ..
*
      dqrt11 = zero
*
*     Test for sufficient workspace
*
      IF( lwork.LT.m*m+m ) THEN
         CALL xerbla( 'DQRT11', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      CALL dlaset( 'Full', m, m, zero, one, work, m )
*
*     Form Q
*
      CALL dorm2r( 'Left', 'No transpose', m, m, k, a, lda, tau, work,
     $             m, work( m*m+1 ), info )
*
*     Form Q'*Q
*
      CALL dorm2r( 'Left', 'Transpose', m, m, k, a, lda, tau, work, m,
     $             work( m*m+1 ), info )
*
      DO j = 1, m
         work( ( j-1 )*m+j ) = work( ( j-1 )*m+j ) - one
      END DO
*
      dqrt11 = dlange( 'One-norm', m, m, work, m, rdummy ) /
     $         ( dble( m )*dlamch( 'Epsilon' ) )
*
      RETURN
*
*     End of DQRT11
*
      END