dqrt13()

subroutine dqrt13	(	integer	scale,
		integer	m,
		integer	n,
		double precision, dimension( lda, * )	a,
		integer	lda,
		double precision	norma,
		integer, dimension( 4 )	iseed )

DQRT13

Purpose:

!>
!> DQRT13 generates a full-rank matrix that may be scaled to have large
!> or small norm.
!> 

Parameters

[in]	SCALE	!> SCALE is INTEGER !> SCALE = 1: normally scaled matrix !> SCALE = 2: matrix scaled up !> SCALE = 3: matrix scaled down !>
[in]	M	!> M is INTEGER !> The number of rows of the matrix A. !>
[in]	N	!> N is INTEGER !> The number of columns of A. !>
[out]	A	!> A is DOUBLE PRECISION array, dimension (LDA,N) !> The M-by-N matrix A. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. !>
[out]	NORMA	!> NORMA is DOUBLE PRECISION !> The one-norm of A. !>
[in,out]	ISEED	!> ISEED is integer array, dimension (4) !> Seed for random number generator !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 90 of file dqrt13.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, M, N, SCALE
      DOUBLE PRECISION   NORMA
*     ..
*     .. Array Arguments ..
      INTEGER            ISEED( 4 )
      DOUBLE PRECISION   A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, J
      DOUBLE PRECISION   BIGNUM, SMLNUM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DASUM, DLAMCH, DLANGE
      EXTERNAL           dasum, dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlarnv, dlascl
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          sign
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   DUMMY( 1 )
*     ..
*     .. Executable Statements ..
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     benign matrix
*
      DO 10 j = 1, n
         CALL dlarnv( 2, iseed, m, a( 1, j ) )
         IF( j.LE.m ) THEN
            a( j, j ) = a( j, j ) + sign( dasum( m, a( 1, j ), 1 ),
     $                  a( j, j ) )
         END IF
   10 CONTINUE
*
*     scaled versions
*
      IF( scale.NE.1 ) THEN
         norma = dlange( 'Max', m, n, a, lda, dummy )
         smlnum = dlamch( 'Safe minimum' )
         bignum = one / smlnum
         smlnum = smlnum / dlamch( 'Epsilon' )
         bignum = one / smlnum
*
         IF( scale.EQ.2 ) THEN
*
*           matrix scaled up
*
            CALL dlascl( 'General', 0, 0, norma, bignum, m, n, a, lda,
     $                   info )
         ELSE IF( scale.EQ.3 ) THEN
*
*           matrix scaled down
*
            CALL dlascl( 'General', 0, 0, norma, smlnum, m, n, a, lda,
     $                   info )
         END IF
      END IF
*
      norma = dlange( 'One-norm', m, n, a, lda, dummy )
      RETURN
*
*     End of DQRT13
*

Here is the call graph for this function:

Here is the caller graph for this function: