dasum()

double precision function dasum	(	integer	n,
		double precision, dimension(*)	dx,
		integer	incx )

DASUM

Purpose:

!>
!>    DASUM takes the sum of the absolute values.
!> 

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	DX	!> DX is DOUBLE PRECISION array, dimension ( 1 + ( N - 1 )*abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of DX !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>     jack dongarra, linpack, 3/11/78.
!>     modified 3/93 to return if incx .le. 0.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!> 

Definition at line 70 of file dasum.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION DX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION DTEMP
      INTEGER I,M,MP1,NINCX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC dabs,mod
*     ..
      dasum = 0.0d0
      dtemp = 0.0d0
      IF (n.LE.0 .OR. incx.LE.0) RETURN
      IF (incx.EQ.1) THEN
*        code for increment equal to 1
*
*
*        clean-up loop
*
         m = mod(n,6)
         IF (m.NE.0) THEN
            DO i = 1,m
               dtemp = dtemp + dabs(dx(i))
            END DO
            IF (n.LT.6) THEN
               dasum = dtemp
               RETURN
            END IF
         END IF
         mp1 = m + 1
         DO i = mp1,n,6
            dtemp = dtemp + dabs(dx(i)) + dabs(dx(i+1)) +
     $              dabs(dx(i+2)) + dabs(dx(i+3)) +
     $              dabs(dx(i+4)) + dabs(dx(i+5))
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         nincx = n*incx
         DO i = 1,nincx,incx
            dtemp = dtemp + dabs(dx(i))
         END DO
      END IF
      dasum = dtemp
      RETURN
*
*     End of DASUM
*

Here is the call graph for this function:

Here is the caller graph for this function: