LAPACK 3.11.0
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
ssbgvx.f
Go to the documentation of this file.
1*> \brief \b SSBGVX
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> \htmlonly
9*> Download SSBGVX + dependencies
10*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ssbgvx.f">
11*> [TGZ]</a>
12*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ssbgvx.f">
13*> [ZIP]</a>
14*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ssbgvx.f">
15*> [TXT]</a>
16*> \endhtmlonly
17*
18* Definition:
19* ===========
20*
21* SUBROUTINE SSBGVX( JOBZ, RANGE, UPLO, N, KA, KB, AB, LDAB, BB,
22* LDBB, Q, LDQ, VL, VU, IL, IU, ABSTOL, M, W, Z,
23* LDZ, WORK, IWORK, IFAIL, INFO )
24*
25* .. Scalar Arguments ..
26* CHARACTER JOBZ, RANGE, UPLO
27* INTEGER IL, INFO, IU, KA, KB, LDAB, LDBB, LDQ, LDZ, M,
28* $ N
29* REAL ABSTOL, VL, VU
30* ..
31* .. Array Arguments ..
32* INTEGER IFAIL( * ), IWORK( * )
33* REAL AB( LDAB, * ), BB( LDBB, * ), Q( LDQ, * ),
34* $ W( * ), WORK( * ), Z( LDZ, * )
35* ..
36*
37*
38*> \par Purpose:
39* =============
40*>
41*> \verbatim
42*>
43*> SSBGVX computes selected eigenvalues, and optionally, eigenvectors
44*> of a real generalized symmetric-definite banded eigenproblem, of
45*> the form A*x=(lambda)*B*x. Here A and B are assumed to be symmetric
46*> and banded, and B is also positive definite. Eigenvalues and
47*> eigenvectors can be selected by specifying either all eigenvalues,
48*> a range of values or a range of indices for the desired eigenvalues.
49*> \endverbatim
50*
51* Arguments:
52* ==========
53*
54*> \param[in] JOBZ
55*> \verbatim
56*> JOBZ is CHARACTER*1
57*> = 'N': Compute eigenvalues only;
58*> = 'V': Compute eigenvalues and eigenvectors.
59*> \endverbatim
60*>
61*> \param[in] RANGE
62*> \verbatim
63*> RANGE is CHARACTER*1
64*> = 'A': all eigenvalues will be found.
65*> = 'V': all eigenvalues in the half-open interval (VL,VU]
66*> will be found.
67*> = 'I': the IL-th through IU-th eigenvalues will be found.
68*> \endverbatim
69*>
70*> \param[in] UPLO
71*> \verbatim
72*> UPLO is CHARACTER*1
73*> = 'U': Upper triangles of A and B are stored;
74*> = 'L': Lower triangles of A and B are stored.
75*> \endverbatim
76*>
77*> \param[in] N
78*> \verbatim
79*> N is INTEGER
80*> The order of the matrices A and B. N >= 0.
81*> \endverbatim
82*>
83*> \param[in] KA
84*> \verbatim
85*> KA is INTEGER
86*> The number of superdiagonals of the matrix A if UPLO = 'U',
87*> or the number of subdiagonals if UPLO = 'L'. KA >= 0.
88*> \endverbatim
89*>
90*> \param[in] KB
91*> \verbatim
92*> KB is INTEGER
93*> The number of superdiagonals of the matrix B if UPLO = 'U',
94*> or the number of subdiagonals if UPLO = 'L'. KB >= 0.
95*> \endverbatim
96*>
97*> \param[in,out] AB
98*> \verbatim
99*> AB is REAL array, dimension (LDAB, N)
100*> On entry, the upper or lower triangle of the symmetric band
101*> matrix A, stored in the first ka+1 rows of the array. The
102*> j-th column of A is stored in the j-th column of the array AB
103*> as follows:
104*> if UPLO = 'U', AB(ka+1+i-j,j) = A(i,j) for max(1,j-ka)<=i<=j;
105*> if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+ka).
106*>
107*> On exit, the contents of AB are destroyed.
108*> \endverbatim
109*>
110*> \param[in] LDAB
111*> \verbatim
112*> LDAB is INTEGER
113*> The leading dimension of the array AB. LDAB >= KA+1.
114*> \endverbatim
115*>
116*> \param[in,out] BB
117*> \verbatim
118*> BB is REAL array, dimension (LDBB, N)
119*> On entry, the upper or lower triangle of the symmetric band
120*> matrix B, stored in the first kb+1 rows of the array. The
121*> j-th column of B is stored in the j-th column of the array BB
122*> as follows:
123*> if UPLO = 'U', BB(ka+1+i-j,j) = B(i,j) for max(1,j-kb)<=i<=j;
124*> if UPLO = 'L', BB(1+i-j,j) = B(i,j) for j<=i<=min(n,j+kb).
125*>
126*> On exit, the factor S from the split Cholesky factorization
127*> B = S**T*S, as returned by SPBSTF.
128*> \endverbatim
129*>
130*> \param[in] LDBB
131*> \verbatim
132*> LDBB is INTEGER
133*> The leading dimension of the array BB. LDBB >= KB+1.
134*> \endverbatim
135*>
136*> \param[out] Q
137*> \verbatim
138*> Q is REAL array, dimension (LDQ, N)
139*> If JOBZ = 'V', the n-by-n matrix used in the reduction of
140*> A*x = (lambda)*B*x to standard form, i.e. C*x = (lambda)*x,
141*> and consequently C to tridiagonal form.
142*> If JOBZ = 'N', the array Q is not referenced.
143*> \endverbatim
144*>
145*> \param[in] LDQ
146*> \verbatim
147*> LDQ is INTEGER
148*> The leading dimension of the array Q. If JOBZ = 'N',
149*> LDQ >= 1. If JOBZ = 'V', LDQ >= max(1,N).
150*> \endverbatim
151*>
152*> \param[in] VL
153*> \verbatim
154*> VL is REAL
155*>
156*> If RANGE='V', the lower bound of the interval to
157*> be searched for eigenvalues. VL < VU.
158*> Not referenced if RANGE = 'A' or 'I'.
159*> \endverbatim
160*>
161*> \param[in] VU
162*> \verbatim
163*> VU is REAL
164*>
165*> If RANGE='V', the upper bound of the interval to
166*> be searched for eigenvalues. VL < VU.
167*> Not referenced if RANGE = 'A' or 'I'.
168*> \endverbatim
169*>
170*> \param[in] IL
171*> \verbatim
172*> IL is INTEGER
173*>
174*> If RANGE='I', the index of the
175*> smallest eigenvalue to be returned.
176*> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
177*> Not referenced if RANGE = 'A' or 'V'.
178*> \endverbatim
179*>
180*> \param[in] IU
181*> \verbatim
182*> IU is INTEGER
183*>
184*> If RANGE='I', the index of the
185*> largest eigenvalue to be returned.
186*> 1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
187*> Not referenced if RANGE = 'A' or 'V'.
188*> \endverbatim
189*>
190*> \param[in] ABSTOL
191*> \verbatim
192*> ABSTOL is REAL
193*> The absolute error tolerance for the eigenvalues.
194*> An approximate eigenvalue is accepted as converged
195*> when it is determined to lie in an interval [a,b]
196*> of width less than or equal to
197*>
198*> ABSTOL + EPS * max( |a|,|b| ) ,
199*>
200*> where EPS is the machine precision. If ABSTOL is less than
201*> or equal to zero, then EPS*|T| will be used in its place,
202*> where |T| is the 1-norm of the tridiagonal matrix obtained
203*> by reducing A to tridiagonal form.
204*>
205*> Eigenvalues will be computed most accurately when ABSTOL is
206*> set to twice the underflow threshold 2*SLAMCH('S'), not zero.
207*> If this routine returns with INFO>0, indicating that some
208*> eigenvectors did not converge, try setting ABSTOL to
209*> 2*SLAMCH('S').
210*> \endverbatim
211*>
212*> \param[out] M
213*> \verbatim
214*> M is INTEGER
215*> The total number of eigenvalues found. 0 <= M <= N.
216*> If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
217*> \endverbatim
218*>
219*> \param[out] W
220*> \verbatim
221*> W is REAL array, dimension (N)
222*> If INFO = 0, the eigenvalues in ascending order.
223*> \endverbatim
224*>
225*> \param[out] Z
226*> \verbatim
227*> Z is REAL array, dimension (LDZ, N)
228*> If JOBZ = 'V', then if INFO = 0, Z contains the matrix Z of
229*> eigenvectors, with the i-th column of Z holding the
230*> eigenvector associated with W(i). The eigenvectors are
231*> normalized so Z**T*B*Z = I.
232*> If JOBZ = 'N', then Z is not referenced.
233*> \endverbatim
234*>
235*> \param[in] LDZ
236*> \verbatim
237*> LDZ is INTEGER
238*> The leading dimension of the array Z. LDZ >= 1, and if
239*> JOBZ = 'V', LDZ >= max(1,N).
240*> \endverbatim
241*>
242*> \param[out] WORK
243*> \verbatim
244*> WORK is REAL array, dimension (7*N)
245*> \endverbatim
246*>
247*> \param[out] IWORK
248*> \verbatim
249*> IWORK is INTEGER array, dimension (5*N)
250*> \endverbatim
251*>
252*> \param[out] IFAIL
253*> \verbatim
254*> IFAIL is INTEGER array, dimension (M)
255*> If JOBZ = 'V', then if INFO = 0, the first M elements of
256*> IFAIL are zero. If INFO > 0, then IFAIL contains the
257*> indices of the eigenvalues that failed to converge.
258*> If JOBZ = 'N', then IFAIL is not referenced.
259*> \endverbatim
260*>
261*> \param[out] INFO
262*> \verbatim
263*> INFO is INTEGER
264*> = 0: successful exit
265*> < 0: if INFO = -i, the i-th argument had an illegal value
266*> <= N: if INFO = i, then i eigenvectors failed to converge.
267*> Their indices are stored in IFAIL.
268*> > N: SPBSTF returned an error code; i.e.,
269*> if INFO = N + i, for 1 <= i <= N, then the leading
270*> minor of order i of B is not positive definite.
271*> The factorization of B could not be completed and
272*> no eigenvalues or eigenvectors were computed.
273*> \endverbatim
274*
275* Authors:
276* ========
277*
278*> \author Univ. of Tennessee
279*> \author Univ. of California Berkeley
280*> \author Univ. of Colorado Denver
281*> \author NAG Ltd.
282*
283*> \ingroup realOTHEReigen
284*
285*> \par Contributors:
286* ==================
287*>
288*> Mark Fahey, Department of Mathematics, Univ. of Kentucky, USA
289*
290* =====================================================================
291 SUBROUTINE ssbgvx( JOBZ, RANGE, UPLO, N, KA, KB, AB, LDAB, BB,
292 $ LDBB, Q, LDQ, VL, VU, IL, IU, ABSTOL, M, W, Z,
293 $ LDZ, WORK, IWORK, IFAIL, INFO )
294*
295* -- LAPACK driver routine --
296* -- LAPACK is a software package provided by Univ. of Tennessee, --
297* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
298*
299* .. Scalar Arguments ..
300 CHARACTER JOBZ, RANGE, UPLO
301 INTEGER IL, INFO, IU, KA, KB, LDAB, LDBB, LDQ, LDZ, M,
302 $ n
303 REAL ABSTOL, VL, VU
304* ..
305* .. Array Arguments ..
306 INTEGER IFAIL( * ), IWORK( * )
307 REAL AB( LDAB, * ), BB( LDBB, * ), Q( LDQ, * ),
308 $ w( * ), work( * ), z( ldz, * )
309* ..
310*
311* =====================================================================
312*
313* .. Parameters ..
314 REAL ZERO, ONE
315 PARAMETER ( ZERO = 0.0e+0, one = 1.0e+0 )
316* ..
317* .. Local Scalars ..
318 LOGICAL ALLEIG, INDEIG, TEST, UPPER, VALEIG, WANTZ
319 CHARACTER ORDER, VECT
320 INTEGER I, IINFO, INDD, INDE, INDEE, INDIBL, INDISP,
321 $ indiwo, indwrk, itmp1, j, jj, nsplit
322 REAL TMP1
323* ..
324* .. External Functions ..
325 LOGICAL LSAME
326 EXTERNAL LSAME
327* ..
328* .. External Subroutines ..
329 EXTERNAL scopy, sgemv, slacpy, spbstf, ssbgst, ssbtrd,
331* ..
332* .. Intrinsic Functions ..
333 INTRINSIC min
334* ..
335* .. Executable Statements ..
336*
337* Test the input parameters.
338*
339 wantz = lsame( jobz, 'V' )
340 upper = lsame( uplo, 'U' )
341 alleig = lsame( range, 'A' )
342 valeig = lsame( range, 'V' )
343 indeig = lsame( range, 'I' )
344*
345 info = 0
346 IF( .NOT.( wantz .OR. lsame( jobz, 'N' ) ) ) THEN
347 info = -1
348 ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
349 info = -2
350 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
351 info = -3
352 ELSE IF( n.LT.0 ) THEN
353 info = -4
354 ELSE IF( ka.LT.0 ) THEN
355 info = -5
356 ELSE IF( kb.LT.0 .OR. kb.GT.ka ) THEN
357 info = -6
358 ELSE IF( ldab.LT.ka+1 ) THEN
359 info = -8
360 ELSE IF( ldbb.LT.kb+1 ) THEN
361 info = -10
362 ELSE IF( ldq.LT.1 .OR. ( wantz .AND. ldq.LT.n ) ) THEN
363 info = -12
364 ELSE
365 IF( valeig ) THEN
366 IF( n.GT.0 .AND. vu.LE.vl )
367 $ info = -14
368 ELSE IF( indeig ) THEN
369 IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
370 info = -15
371 ELSE IF ( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
372 info = -16
373 END IF
374 END IF
375 END IF
376 IF( info.EQ.0) THEN
377 IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
378 info = -21
379 END IF
380 END IF
381*
382 IF( info.NE.0 ) THEN
383 CALL xerbla( 'SSBGVX', -info )
384 RETURN
385 END IF
386*
387* Quick return if possible
388*
389 m = 0
390 IF( n.EQ.0 )
391 $ RETURN
392*
393* Form a split Cholesky factorization of B.
394*
395 CALL spbstf( uplo, n, kb, bb, ldbb, info )
396 IF( info.NE.0 ) THEN
397 info = n + info
398 RETURN
399 END IF
400*
401* Transform problem to standard eigenvalue problem.
402*
403 CALL ssbgst( jobz, uplo, n, ka, kb, ab, ldab, bb, ldbb, q, ldq,
404 $ work, iinfo )
405*
406* Reduce symmetric band matrix to tridiagonal form.
407*
408 indd = 1
409 inde = indd + n
410 indwrk = inde + n
411 IF( wantz ) THEN
412 vect = 'U'
413 ELSE
414 vect = 'N'
415 END IF
416 CALL ssbtrd( vect, uplo, n, ka, ab, ldab, work( indd ),
417 $ work( inde ), q, ldq, work( indwrk ), iinfo )
418*
419* If all eigenvalues are desired and ABSTOL is less than or equal
420* to zero, then call SSTERF or SSTEQR. If this fails for some
421* eigenvalue, then try SSTEBZ.
422*
423 test = .false.
424 IF( indeig ) THEN
425 IF( il.EQ.1 .AND. iu.EQ.n ) THEN
426 test = .true.
427 END IF
428 END IF
429 IF( ( alleig .OR. test ) .AND. ( abstol.LE.zero ) ) THEN
430 CALL scopy( n, work( indd ), 1, w, 1 )
431 indee = indwrk + 2*n
432 CALL scopy( n-1, work( inde ), 1, work( indee ), 1 )
433 IF( .NOT.wantz ) THEN
434 CALL ssterf( n, w, work( indee ), info )
435 ELSE
436 CALL slacpy( 'A', n, n, q, ldq, z, ldz )
437 CALL ssteqr( jobz, n, w, work( indee ), z, ldz,
438 $ work( indwrk ), info )
439 IF( info.EQ.0 ) THEN
440 DO 10 i = 1, n
441 ifail( i ) = 0
442 10 CONTINUE
443 END IF
444 END IF
445 IF( info.EQ.0 ) THEN
446 m = n
447 GO TO 30
448 END IF
449 info = 0
450 END IF
451*
452* Otherwise, call SSTEBZ and, if eigenvectors are desired,
453* call SSTEIN.
454*
455 IF( wantz ) THEN
456 order = 'B'
457 ELSE
458 order = 'E'
459 END IF
460 indibl = 1
461 indisp = indibl + n
462 indiwo = indisp + n
463 CALL sstebz( range, order, n, vl, vu, il, iu, abstol,
464 $ work( indd ), work( inde ), m, nsplit, w,
465 $ iwork( indibl ), iwork( indisp ), work( indwrk ),
466 $ iwork( indiwo ), info )
467*
468 IF( wantz ) THEN
469 CALL sstein( n, work( indd ), work( inde ), m, w,
470 $ iwork( indibl ), iwork( indisp ), z, ldz,
471 $ work( indwrk ), iwork( indiwo ), ifail, info )
472*
473* Apply transformation matrix used in reduction to tridiagonal
474* form to eigenvectors returned by SSTEIN.
475*
476 DO 20 j = 1, m
477 CALL scopy( n, z( 1, j ), 1, work( 1 ), 1 )
478 CALL sgemv( 'N', n, n, one, q, ldq, work, 1, zero,
479 $ z( 1, j ), 1 )
480 20 CONTINUE
481 END IF
482*
483 30 CONTINUE
484*
485* If eigenvalues are not in order, then sort them, along with
486* eigenvectors.
487*
488 IF( wantz ) THEN
489 DO 50 j = 1, m - 1
490 i = 0
491 tmp1 = w( j )
492 DO 40 jj = j + 1, m
493 IF( w( jj ).LT.tmp1 ) THEN
494 i = jj
495 tmp1 = w( jj )
496 END IF
497 40 CONTINUE
498*
499 IF( i.NE.0 ) THEN
500 itmp1 = iwork( indibl+i-1 )
501 w( i ) = w( j )
502 iwork( indibl+i-1 ) = iwork( indibl+j-1 )
503 w( j ) = tmp1
504 iwork( indibl+j-1 ) = itmp1
505 CALL sswap( n, z( 1, i ), 1, z( 1, j ), 1 )
506 IF( info.NE.0 ) THEN
507 itmp1 = ifail( i )
508 ifail( i ) = ifail( j )
509 ifail( j ) = itmp1
510 END IF
511 END IF
512 50 CONTINUE
513 END IF
514*
515 RETURN
516*
517* End of SSBGVX
518*
519 END
subroutine slacpy(UPLO, M, N, A, LDA, B, LDB)
SLACPY copies all or part of one two-dimensional array to another.
Definition: slacpy.f:103
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
subroutine ssteqr(COMPZ, N, D, E, Z, LDZ, WORK, INFO)
SSTEQR
Definition: ssteqr.f:131
subroutine ssterf(N, D, E, INFO)
SSTERF
Definition: ssterf.f:86
subroutine sstebz(RANGE, ORDER, N, VL, VU, IL, IU, ABSTOL, D, E, M, NSPLIT, W, IBLOCK, ISPLIT, WORK, IWORK, INFO)
SSTEBZ
Definition: sstebz.f:273
subroutine spbstf(UPLO, N, KD, AB, LDAB, INFO)
SPBSTF
Definition: spbstf.f:152
subroutine ssbtrd(VECT, UPLO, N, KD, AB, LDAB, D, E, Q, LDQ, WORK, INFO)
SSBTRD
Definition: ssbtrd.f:163
subroutine sstein(N, D, E, M, W, IBLOCK, ISPLIT, Z, LDZ, WORK, IWORK, IFAIL, INFO)
SSTEIN
Definition: sstein.f:174
subroutine ssbgst(VECT, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, X, LDX, WORK, INFO)
SSBGST
Definition: ssbgst.f:159
subroutine ssbgvx(JOBZ, RANGE, UPLO, N, KA, KB, AB, LDAB, BB, LDBB, Q, LDQ, VL, VU, IL, IU, ABSTOL, M, W, Z, LDZ, WORK, IWORK, IFAIL, INFO)
SSBGVX
Definition: ssbgvx.f:294
subroutine sswap(N, SX, INCX, SY, INCY)
SSWAP
Definition: sswap.f:82
subroutine scopy(N, SX, INCX, SY, INCY)
SCOPY
Definition: scopy.f:82
subroutine sgemv(TRANS, M, N, ALPHA, A, LDA, X, INCX, BETA, Y, INCY)
SGEMV
Definition: sgemv.f:156