zupgtr()

subroutine zupgtr	(	character	uplo,
		integer	n,
		complex*16, dimension( * )	ap,
		complex*16, dimension( * )	tau,
		complex*16, dimension( ldq, * )	q,
		integer	ldq,
		complex*16, dimension( * )	work,
		integer	info
	)

ZUPGTR

Download ZUPGTR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZUPGTR generates a complex unitary matrix Q which is defined as the
 product of n-1 elementary reflectors H(i) of order n, as returned by
 ZHPTRD using packed storage:

 if UPLO = 'U', Q = H(n-1) . . . H(2) H(1),

 if UPLO = 'L', Q = H(1) H(2) . . . H(n-1).

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangular packed storage used in previous call to ZHPTRD; = 'L': Lower triangular packed storage used in previous call to ZHPTRD.
[in]	N	N is INTEGER The order of the matrix Q. N >= 0.
[in]	AP	AP is COMPLEX*16 array, dimension (N*(N+1)/2) The vectors which define the elementary reflectors, as returned by ZHPTRD.
[in]	TAU	TAU is COMPLEX*16 array, dimension (N-1) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by ZHPTRD.
[out]	Q	Q is COMPLEX*16 array, dimension (LDQ,N) The N-by-N unitary matrix Q.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[out]	WORK	WORK is COMPLEX*16 array, dimension (N-1)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 113 of file zupgtr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDQ, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         AP( * ), Q( LDQ, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I, IINFO, IJ, J
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zung2l, zung2r
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZUPGTR', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Q was determined by a call to ZHPTRD with UPLO = 'U'
*
*        Unpack the vectors which define the elementary reflectors and
*        set the last row and column of Q equal to those of the unit
*        matrix
*
         ij = 2
         DO 20 j = 1, n - 1
            DO 10 i = 1, j - 1
               q( i, j ) = ap( ij )
               ij = ij + 1
   10       CONTINUE
            ij = ij + 2
            q( n, j ) = czero
   20    CONTINUE
         DO 30 i = 1, n - 1
            q( i, n ) = czero
   30    CONTINUE
         q( n, n ) = cone
*
*        Generate Q(1:n-1,1:n-1)
*
         CALL zung2l( n-1, n-1, n-1, q, ldq, tau, work, iinfo )
*
      ELSE
*
*        Q was determined by a call to ZHPTRD with UPLO = 'L'.
*
*        Unpack the vectors which define the elementary reflectors and
*        set the first row and column of Q equal to those of the unit
*        matrix
*
         q( 1, 1 ) = cone
         DO 40 i = 2, n
            q( i, 1 ) = czero
   40    CONTINUE
         ij = 3
         DO 60 j = 2, n
            q( 1, j ) = czero
            DO 50 i = j + 1, n
               q( i, j ) = ap( ij )
               ij = ij + 1
   50       CONTINUE
            ij = ij + 2
   60    CONTINUE
         IF( n.GT.1 ) THEN
*
*           Generate Q(2:n,2:n)
*
            CALL zung2r( n-1, n-1, n-1, q( 2, 2 ), ldq, tau, work,
     $                   iinfo )
         END IF
      END IF
      RETURN
*
*     End of ZUPGTR
*

Here is the call graph for this function:

Here is the caller graph for this function: