zung2r()

subroutine zung2r	(	integer	m,
		integer	n,
		integer	k,
		complex*16, dimension( lda, * )	a,
		integer	lda,
		complex*16, dimension( * )	tau,
		complex*16, dimension( * )	work,
		integer	info )

ZUNG2R

Download ZUNG2R + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> ZUNG2R generates an m by n complex matrix Q with orthonormal columns,
!> which is defined as the first n columns of a product of k elementary
!> reflectors of order m
!>
!>       Q  =  H(1) H(2) . . . H(k)
!>
!> as returned by ZGEQRF.
!> 

Parameters

[in]	M	!> M is INTEGER !> The number of rows of the matrix Q. M >= 0. !>
[in]	N	!> N is INTEGER !> The number of columns of the matrix Q. M >= N >= 0. !>
[in]	K	!> K is INTEGER !> The number of elementary reflectors whose product defines the !> matrix Q. N >= K >= 0. !>
[in,out]	A	!> A is COMPLEX*16 array, dimension (LDA,N) !> On entry, the i-th column must contain the vector which !> defines the elementary reflector H(i), for i = 1,2,...,k, as !> returned by ZGEQRF in the first k columns of its array !> argument A. !> On exit, the m by n matrix Q. !>
[in]	LDA	!> LDA is INTEGER !> The first dimension of the array A. LDA >= max(1,M). !>
[in]	TAU	!> TAU is COMPLEX*16 array, dimension (K) !> TAU(i) must contain the scalar factor of the elementary !> reflector H(i), as returned by ZGEQRF. !>
[out]	WORK	!> WORK is COMPLEX*16 array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument has an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 111 of file zung2r.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      COMPLEX*16         A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla, zlarf1f, zscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZUNG2R', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Initialise columns k+1:n to columns of the unit matrix
*
      DO 20 j = k + 1, n
         DO 10 l = 1, m
            a( l, j ) = zero
   10    CONTINUE
         a( j, j ) = one
   20 CONTINUE
*
      DO 40 i = k, 1, -1
*
*        Apply H(i) to A(i:m,i:n) from the left
*
         IF( i.LT.n ) THEN
            CALL zlarf1f( 'Left', m-i+1, n-i, a( i, i ), 1, tau( i ),
     $                    a( i, i+1 ), lda, work )
         END IF
         IF( i.LT.m )
     $      CALL zscal( m-i, -tau( i ), a( i+1, i ), 1 )
         a( i, i ) = one - tau( i )
*
*        Set A(1:i-1,i) to zero
*
         DO 30 l = 1, i - 1
            a( l, i ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of ZUNG2R
*

Here is the call graph for this function:

Here is the caller graph for this function: