cchkbd()

subroutine cchkbd	(	integer	nsizes,
		integer, dimension( * )	mval,
		integer, dimension( * )	nval,
		integer	ntypes,
		logical, dimension( * )	dotype,
		integer	nrhs,
		integer, dimension( 4 )	iseed,
		real	thresh,
		complex, dimension( lda, * )	a,
		integer	lda,
		real, dimension( * )	bd,
		real, dimension( * )	be,
		real, dimension( * )	s1,
		real, dimension( * )	s2,
		complex, dimension( ldx, * )	x,
		integer	ldx,
		complex, dimension( ldx, * )	y,
		complex, dimension( ldx, * )	z,
		complex, dimension( ldq, * )	q,
		integer	ldq,
		complex, dimension( ldpt, * )	pt,
		integer	ldpt,
		complex, dimension( ldpt, * )	u,
		complex, dimension( ldpt, * )	vt,
		complex, dimension( * )	work,
		integer	lwork,
		real, dimension( * )	rwork,
		integer	nout,
		integer	info )

CCHKBD

Purpose:

!>
!> CCHKBD checks the singular value decomposition (SVD) routines.
!>
!> CGEBRD reduces a complex general m by n matrix A to real upper or
!> lower bidiagonal form by an orthogonal transformation: Q' * A * P = B
!> (or A = Q * B * P').  The matrix B is upper bidiagonal if m >= n
!> and lower bidiagonal if m < n.
!>
!> CUNGBR generates the orthogonal matrices Q and P' from CGEBRD.
!> Note that Q and P are not necessarily square.
!>
!> CBDSQR computes the singular value decomposition of the bidiagonal
!> matrix B as B = U S V'.  It is called three times to compute
!>    1)  B = U S1 V', where S1 is the diagonal matrix of singular
!>        values and the columns of the matrices U and V are the left
!>        and right singular vectors, respectively, of B.
!>    2)  Same as 1), but the singular values are stored in S2 and the
!>        singular vectors are not computed.
!>    3)  A = (UQ) S (P'V'), the SVD of the original matrix A.
!> In addition, CBDSQR has an option to apply the left orthogonal matrix
!> U to a matrix X, useful in least squares applications.
!>
!> For each pair of matrix dimensions (M,N) and each selected matrix
!> type, an M by N matrix A and an M by NRHS matrix X are generated.
!> The problem dimensions are as follows
!>    A:          M x N
!>    Q:          M x min(M,N) (but M x M if NRHS > 0)
!>    P:          min(M,N) x N
!>    B:          min(M,N) x min(M,N)
!>    U, V:       min(M,N) x min(M,N)
!>    S1, S2      diagonal, order min(M,N)
!>    X:          M x NRHS
!>
!> For each generated matrix, 14 tests are performed:
!>
!> Test CGEBRD and CUNGBR
!>
!> (1)   | A - Q B PT | / ( |A| max(M,N) ulp ), PT = P'
!>
!> (2)   | I - Q' Q | / ( M ulp )
!>
!> (3)   | I - PT PT' | / ( N ulp )
!>
!> Test CBDSQR on bidiagonal matrix B
!>
!> (4)   | B - U S1 VT | / ( |B| min(M,N) ulp ), VT = V'
!>
!> (5)   | Y - U Z | / ( |Y| max(min(M,N),k) ulp ), where Y = Q' X
!>                                                  and   Z = U' Y.
!> (6)   | I - U' U | / ( min(M,N) ulp )
!>
!> (7)   | I - VT VT' | / ( min(M,N) ulp )
!>
!> (8)   S1 contains min(M,N) nonnegative values in decreasing order.
!>       (Return 0 if true, 1/ULP if false.)
!>
!> (9)   0 if the true singular values of B are within THRESH of
!>       those in S1.  2*THRESH if they are not.  (Tested using
!>       SSVDCH)
!>
!> (10)  | S1 - S2 | / ( |S1| ulp ), where S2 is computed without
!>                                   computing U and V.
!>
!> Test CBDSQR on matrix A
!>
!> (11)  | A - (QU) S (VT PT) | / ( |A| max(M,N) ulp )
!>
!> (12)  | X - (QU) Z | / ( |X| max(M,k) ulp )
!>
!> (13)  | I - (QU)'(QU) | / ( M ulp )
!>
!> (14)  | I - (VT PT) (PT'VT') | / ( N ulp )
!>
!> The possible matrix types are
!>
!> (1)  The zero matrix.
!> (2)  The identity matrix.
!>
!> (3)  A diagonal matrix with evenly spaced entries
!>      1, ..., ULP  and random signs.
!>      (ULP = (first number larger than 1) - 1 )
!> (4)  A diagonal matrix with geometrically spaced entries
!>      1, ..., ULP  and random signs.
!> (5)  A diagonal matrix with  entries 1, ULP, ..., ULP
!>      and random signs.
!>
!> (6)  Same as (3), but multiplied by SQRT( overflow threshold )
!> (7)  Same as (3), but multiplied by SQRT( underflow threshold )
!>
!> (8)  A matrix of the form  U D V, where U and V are orthogonal and
!>      D has evenly spaced entries 1, ..., ULP with random signs
!>      on the diagonal.
!>
!> (9)  A matrix of the form  U D V, where U and V are orthogonal and
!>      D has geometrically spaced entries 1, ..., ULP with random
!>      signs on the diagonal.
!>
!> (10) A matrix of the form  U D V, where U and V are orthogonal and
!>      D has  entries 1, ULP,..., ULP with random
!>      signs on the diagonal.
!>
!> (11) Same as (8), but multiplied by SQRT( overflow threshold )
!> (12) Same as (8), but multiplied by SQRT( underflow threshold )
!>
!> (13) Rectangular matrix with random entries chosen from (-1,1).
!> (14) Same as (13), but multiplied by SQRT( overflow threshold )
!> (15) Same as (13), but multiplied by SQRT( underflow threshold )
!>
!> Special case:
!> (16) A bidiagonal matrix with random entries chosen from a
!>      logarithmic distribution on [ulp^2,ulp^(-2)]  (I.e., each
!>      entry is  e^x, where x is chosen uniformly on
!>      [ 2 log(ulp), -2 log(ulp) ] .)  For *this* type:
!>      (a) CGEBRD is not called to reduce it to bidiagonal form.
!>      (b) the bidiagonal is  min(M,N) x min(M,N); if M<N, the
!>          matrix will be lower bidiagonal, otherwise upper.
!>      (c) only tests 5--8 and 14 are performed.
!>
!> A subset of the full set of matrix types may be selected through
!> the logical array DOTYPE.
!> 

Parameters

[in]	NSIZES	!> NSIZES is INTEGER !> The number of values of M and N contained in the vectors !> MVAL and NVAL. The matrix sizes are used in pairs (M,N). !>
[in]	MVAL	!> MVAL is INTEGER array, dimension (NM) !> The values of the matrix row dimension M. !>
[in]	NVAL	!> NVAL is INTEGER array, dimension (NM) !> The values of the matrix column dimension N. !>
[in]	NTYPES	!> NTYPES is INTEGER !> The number of elements in DOTYPE. If it is zero, CCHKBD !> does nothing. It must be at least zero. If it is MAXTYP+1 !> and NSIZES is 1, then an additional type, MAXTYP+1 is !> defined, which is to use whatever matrices are in A and B. !> This is only useful if DOTYPE(1:MAXTYP) is .FALSE. and !> DOTYPE(MAXTYP+1) is .TRUE. . !>
[in]	DOTYPE	!> DOTYPE is LOGICAL array, dimension (NTYPES) !> If DOTYPE(j) is .TRUE., then for each size (m,n), a matrix !> of type j will be generated. If NTYPES is smaller than the !> maximum number of types defined (PARAMETER MAXTYP), then !> types NTYPES+1 through MAXTYP will not be generated. If !> NTYPES is larger than MAXTYP, DOTYPE(MAXTYP+1) through !> DOTYPE(NTYPES) will be ignored. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of columns in the matrices X, Y, !> and Z, used in testing CBDSQR. If NRHS = 0, then the !> operations on the right-hand side will not be tested. !> NRHS must be at least 0. !>
[in,out]	ISEED	!> ISEED is INTEGER array, dimension (4) !> On entry ISEED specifies the seed of the random number !> generator. The array elements should be between 0 and 4095; !> if not they will be reduced mod 4096. Also, ISEED(4) must !> be odd. The values of ISEED are changed on exit, and can be !> used in the next call to CCHKBD to continue the same random !> number sequence. !>
[in]	THRESH	!> THRESH is REAL !> The threshold value for the test ratios. A result is !> included in the output file if RESULT >= THRESH. To have !> every test ratio printed, use THRESH = 0. Note that the !> expected value of the test ratios is O(1), so THRESH should !> be a reasonably small multiple of 1, e.g., 10 or 100. !>
[out]	A	!> A is COMPLEX array, dimension (LDA,NMAX) !> where NMAX is the maximum value of N in NVAL. !>
[in]	LDA	!> LDA is INTEGER !> The leading dimension of the array A. LDA >= max(1,MMAX), !> where MMAX is the maximum value of M in MVAL. !>
[out]	BD	!> BD is REAL array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	BE	!> BE is REAL array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	S1	!> S1 is REAL array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	S2	!> S2 is REAL array, dimension !> (max(min(MVAL(j),NVAL(j)))) !>
[out]	X	!> X is COMPLEX array, dimension (LDX,NRHS) !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the arrays X, Y, and Z. !> LDX >= max(1,MMAX). !>
[out]	Y	!> Y is COMPLEX array, dimension (LDX,NRHS) !>
[out]	Z	!> Z is COMPLEX array, dimension (LDX,NRHS) !>
[out]	Q	!> Q is COMPLEX array, dimension (LDQ,MMAX) !>
[in]	LDQ	!> LDQ is INTEGER !> The leading dimension of the array Q. LDQ >= max(1,MMAX). !>
[out]	PT	!> PT is COMPLEX array, dimension (LDPT,NMAX) !>
[in]	LDPT	!> LDPT is INTEGER !> The leading dimension of the arrays PT, U, and V. !> LDPT >= max(1, max(min(MVAL(j),NVAL(j)))). !>
[out]	U	!> U is COMPLEX array, dimension !> (LDPT,max(min(MVAL(j),NVAL(j)))) !>
[out]	VT	!> VT is COMPLEX array, dimension !> (LDPT,max(min(MVAL(j),NVAL(j)))) !>
[out]	WORK	!> WORK is COMPLEX array, dimension (LWORK) !>
[in]	LWORK	!> LWORK is INTEGER !> The number of entries in WORK. This must be at least !> 3(M+N) and M(M + max(M,N,k) + 1) + N*min(M,N) for all !> pairs (M,N)=(MM(j),NN(j)) !>
[out]	RWORK	!> RWORK is REAL array, dimension !> (5*max(min(M,N))) !>
[in]	NOUT	!> NOUT is INTEGER !> The FORTRAN unit number for printing out error messages !> (e.g., if a routine returns IINFO not equal to 0.) !>
[out]	INFO	!> INFO is INTEGER !> If 0, then everything ran OK. !> -1: NSIZES < 0 !> -2: Some MM(j) < 0 !> -3: Some NN(j) < 0 !> -4: NTYPES < 0 !> -6: NRHS < 0 !> -8: THRESH < 0 !> -11: LDA < 1 or LDA < MMAX, where MMAX is max( MM(j) ). !> -17: LDB < 1 or LDB < MMAX. !> -21: LDQ < 1 or LDQ < MMAX. !> -23: LDP < 1 or LDP < MNMAX. !> -27: LWORK too small. !> If CLATMR, CLATMS, CGEBRD, CUNGBR, or CBDSQR, !> returns an error code, the !> absolute value of it is returned. !> !>----------------------------------------------------------------------- !> !> Some Local Variables and Parameters: !> ---- ----- --------- --- ---------- !> !> ZERO, ONE Real 0 and 1. !> MAXTYP The number of types defined. !> NTEST The number of tests performed, or which can !> be performed so far, for the current matrix. !> MMAX Largest value in NN. !> NMAX Largest value in NN. !> MNMIN min(MM(j), NN(j)) (the dimension of the bidiagonal !> matrix.) !> MNMAX The maximum value of MNMIN for j=1,...,NSIZES. !> NFAIL The number of tests which have exceeded THRESH !> COND, IMODE Values to be passed to the matrix generators. !> ANORM Norm of A; passed to matrix generators. !> !> OVFL, UNFL Overflow and underflow thresholds. !> RTOVFL, RTUNFL Square roots of the previous 2 values. !> ULP, ULPINV Finest relative precision and its inverse. !> !> The following four arrays decode JTYPE: !> KTYPE(j) The general type (1-10) for type . !> KMODE(j) The MODE value to be passed to the matrix !> generator for type . !> KMAGN(j) The order of magnitude ( O(1), !> O(overflow^(1/2) ), O(underflow^(1/2) ) !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 411 of file cchkbd.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDPT, LDQ, LDX, LWORK, NOUT, NRHS,
     $                   NSIZES, NTYPES
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), MVAL( * ), NVAL( * )
      REAL               BD( * ), BE( * ), RWORK( * ), S1( * ), S2( * )
      COMPLEX            A( LDA, * ), PT( LDPT, * ), Q( LDQ, * ),
     $                   U( LDPT, * ), VT( LDPT, * ), WORK( * ),
     $                   X( LDX, * ), Y( LDX, * ), Z( LDX, * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO, HALF
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0,
     $                   half = 0.5e0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
      INTEGER            MAXTYP
      parameter( maxtyp = 16 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADMM, BADNN, BIDIAG
      CHARACTER          UPLO
      CHARACTER*3        PATH
      INTEGER            I, IINFO, IMODE, ITYPE, J, JCOL, JSIZE, JTYPE,
     $                   LOG2UI, M, MINWRK, MMAX, MNMAX, MNMIN, MQ,
     $                   MTYPES, N, NFAIL, NMAX, NTEST
      REAL               AMNINV, ANORM, COND, OVFL, RTOVFL, RTUNFL,
     $                   TEMP1, TEMP2, ULP, ULPINV, UNFL
*     ..
*     .. Local Arrays ..
      INTEGER            IOLDSD( 4 ), IWORK( 1 ), KMAGN( MAXTYP ),
     $                   KMODE( MAXTYP ), KTYPE( MAXTYP )
      REAL               DUMMA( 1 ), RESULT( 14 )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLARND
      EXTERNAL           slamch, slarnd
*     ..
*     .. External Subroutines ..
      EXTERNAL           alasum, cbdsqr, cbdt01, cbdt02, cbdt03,
     $                   cgebrd, cgemm, clacpy, claset, clatmr,
     $                   clatms, cungbr, cunt01, scopy, slahd2,
     $                   ssvdch, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, exp, int, log, max, min, sqrt
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA            ktype / 1, 2, 5*4, 5*6, 3*9, 10 /
      DATA            kmagn / 2*1, 3*1, 2, 3, 3*1, 2, 3, 1, 2, 3, 0 /
      DATA            kmode / 2*0, 4, 3, 1, 4, 4, 4, 3, 1, 4, 4, 0,
     $                   0, 0, 0 /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badmm = .false.
      badnn = .false.
      mmax = 1
      nmax = 1
      mnmax = 1
      minwrk = 1
      DO 10 j = 1, nsizes
         mmax = max( mmax, mval( j ) )
         IF( mval( j ).LT.0 )
     $      badmm = .true.
         nmax = max( nmax, nval( j ) )
         IF( nval( j ).LT.0 )
     $      badnn = .true.
         mnmax = max( mnmax, min( mval( j ), nval( j ) ) )
         minwrk = max( minwrk, 3*( mval( j )+nval( j ) ),
     $            mval( j )*( mval( j )+max( mval( j ), nval( j ),
     $            nrhs )+1 )+nval( j )*min( nval( j ), mval( j ) ) )
   10 CONTINUE
*
*     Check for errors
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badmm ) THEN
         info = -2
      ELSE IF( badnn ) THEN
         info = -3
      ELSE IF( ntypes.LT.0 ) THEN
         info = -4
      ELSE IF( nrhs.LT.0 ) THEN
         info = -6
      ELSE IF( lda.LT.mmax ) THEN
         info = -11
      ELSE IF( ldx.LT.mmax ) THEN
         info = -17
      ELSE IF( ldq.LT.mmax ) THEN
         info = -21
      ELSE IF( ldpt.LT.mnmax ) THEN
         info = -23
      ELSE IF( minwrk.GT.lwork ) THEN
         info = -27
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CCHKBD', -info )
         RETURN
      END IF
*
*     Initialize constants
*
      path( 1: 1 ) = 'Complex precision'
      path( 2: 3 ) = 'BD'
      nfail = 0
      ntest = 0
      unfl = slamch( 'Safe minimum' )
      ovfl = slamch( 'Overflow' )
      ulp = slamch( 'Precision' )
      ulpinv = one / ulp
      log2ui = int( log( ulpinv ) / log( two ) )
      rtunfl = sqrt( unfl )
      rtovfl = sqrt( ovfl )
      infot = 0
*
*     Loop over sizes, types
*
      DO 180 jsize = 1, nsizes
         m = mval( jsize )
         n = nval( jsize )
         mnmin = min( m, n )
         amninv = one / max( m, n, 1 )
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 170 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 170
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
            DO 30 j = 1, 14
               result( j ) = -one
   30       CONTINUE
*
            uplo = ' '
*
*           Compute "A"
*
*           Control parameters:
*
*           KMAGN  KMODE        KTYPE
*       =1  O(1)   clustered 1  zero
*       =2  large  clustered 2  identity
*       =3  small  exponential  (none)
*       =4         arithmetic   diagonal, (w/ eigenvalues)
*       =5         random       symmetric, w/ eigenvalues
*       =6                      nonsymmetric, w/ singular values
*       =7                      random diagonal
*       =8                      random symmetric
*       =9                      random nonsymmetric
*       =10                     random bidiagonal (log. distrib.)
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 100
*
            itype = ktype( jtype )
            imode = kmode( jtype )
*
*           Compute norm
*
            GO TO ( 40, 50, 60 )kmagn( jtype )
*
   40       CONTINUE
            anorm = one
            GO TO 70
*
   50       CONTINUE
            anorm = ( rtovfl*ulp )*amninv
            GO TO 70
*
   60       CONTINUE
            anorm = rtunfl*max( m, n )*ulpinv
            GO TO 70
*
   70       CONTINUE
*
            CALL claset( 'Full', lda, n, czero, czero, a, lda )
            iinfo = 0
            cond = ulpinv
*
            bidiag = .false.
            IF( itype.EQ.1 ) THEN
*
*              Zero matrix
*
               iinfo = 0
*
            ELSE IF( itype.EQ.2 ) THEN
*
*              Identity
*
               DO 80 jcol = 1, mnmin
                  a( jcol, jcol ) = anorm
   80          CONTINUE
*
            ELSE IF( itype.EQ.4 ) THEN
*
*              Diagonal Matrix, [Eigen]values Specified
*
               CALL clatms( mnmin, mnmin, 'S', iseed, 'N', rwork, imode,
     $                      cond, anorm, 0, 0, 'N', a, lda, work,
     $                      iinfo )
*
            ELSE IF( itype.EQ.5 ) THEN
*
*              Symmetric, eigenvalues specified
*
               CALL clatms( mnmin, mnmin, 'S', iseed, 'S', rwork, imode,
     $                      cond, anorm, m, n, 'N', a, lda, work,
     $                      iinfo )
*
            ELSE IF( itype.EQ.6 ) THEN
*
*              Nonsymmetric, singular values specified
*
               CALL clatms( m, n, 'S', iseed, 'N', rwork, imode, cond,
     $                      anorm, m, n, 'N', a, lda, work, iinfo )
*
            ELSE IF( itype.EQ.7 ) THEN
*
*              Diagonal, random entries
*
               CALL clatmr( mnmin, mnmin, 'S', iseed, 'N', work, 6, one,
     $                      cone, 'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( 2*mnmin+1 ), 1, one, 'N', iwork, 0, 0,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.8 ) THEN
*
*              Symmetric, random entries
*
               CALL clatmr( mnmin, mnmin, 'S', iseed, 'S', work, 6, one,
     $                      cone, 'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( m+mnmin+1 ), 1, one, 'N', iwork, m, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.9 ) THEN
*
*              Nonsymmetric, random entries
*
               CALL clatmr( m, n, 'S', iseed, 'N', work, 6, one, cone,
     $                      'T', 'N', work( mnmin+1 ), 1, one,
     $                      work( m+mnmin+1 ), 1, one, 'N', iwork, m, n,
     $                      zero, anorm, 'NO', a, lda, iwork, iinfo )
*
            ELSE IF( itype.EQ.10 ) THEN
*
*              Bidiagonal, random entries
*
               temp1 = -two*log( ulp )
               DO 90 j = 1, mnmin
                  bd( j ) = exp( temp1*slarnd( 2, iseed ) )
                  IF( j.LT.mnmin )
     $               be( j ) = exp( temp1*slarnd( 2, iseed ) )
   90          CONTINUE
*
               iinfo = 0
               bidiag = .true.
               IF( m.GE.n ) THEN
                  uplo = 'U'
               ELSE
                  uplo = 'L'
               END IF
            ELSE
               iinfo = 1
            END IF
*
            IF( iinfo.EQ.0 ) THEN
*
*              Generate Right-Hand Side
*
               IF( bidiag ) THEN
                  CALL clatmr( mnmin, nrhs, 'S', iseed, 'N', work, 6,
     $                         one, cone, 'T', 'N', work( mnmin+1 ), 1,
     $                         one, work( 2*mnmin+1 ), 1, one, 'N',
     $                         iwork, mnmin, nrhs, zero, one, 'NO', y,
     $                         ldx, iwork, iinfo )
               ELSE
                  CALL clatmr( m, nrhs, 'S', iseed, 'N', work, 6, one,
     $                         cone, 'T', 'N', work( m+1 ), 1, one,
     $                         work( 2*m+1 ), 1, one, 'N', iwork, m,
     $                         nrhs, zero, one, 'NO', x, ldx, iwork,
     $                         iinfo )
               END IF
            END IF
*
*           Error Exit
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'Generator', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               RETURN
            END IF
*
  100       CONTINUE
*
*           Call CGEBRD and CUNGBR to compute B, Q, and P, do tests.
*
            IF( .NOT.bidiag ) THEN
*
*              Compute transformations to reduce A to bidiagonal form:
*              B := Q' * A * P.
*
               CALL clacpy( ' ', m, n, a, lda, q, ldq )
               CALL cgebrd( m, n, q, ldq, bd, be, work, work( mnmin+1 ),
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from CGEBRD.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'CGEBRD', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
               CALL clacpy( ' ', m, n, q, ldq, pt, ldpt )
               IF( m.GE.n ) THEN
                  uplo = 'U'
               ELSE
                  uplo = 'L'
               END IF
*
*              Generate Q
*
               mq = m
               IF( nrhs.LE.0 )
     $            mq = mnmin
               CALL cungbr( 'Q', m, mq, n, q, ldq, work,
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from CUNGBR.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'CUNGBR(Q)', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
*              Generate P'
*
               CALL cungbr( 'P', mnmin, n, m, pt, ldpt, work( mnmin+1 ),
     $                      work( 2*mnmin+1 ), lwork-2*mnmin, iinfo )
*
*              Check error code from CUNGBR.
*
               IF( iinfo.NE.0 ) THEN
                  WRITE( nout, fmt = 9998 )'CUNGBR(P)', iinfo, m, n,
     $               jtype, ioldsd
                  info = abs( iinfo )
                  RETURN
               END IF
*
*              Apply Q' to an M by NRHS matrix X:  Y := Q' * X.
*
               CALL cgemm( 'Conjugate transpose', 'No transpose', m,
     $                     nrhs, m, cone, q, ldq, x, ldx, czero, y,
     $                     ldx )
*
*              Test 1:  Check the decomposition A := Q * B * PT
*                   2:  Check the orthogonality of Q
*                   3:  Check the orthogonality of PT
*
               CALL cbdt01( m, n, 1, a, lda, q, ldq, bd, be, pt, ldpt,
     $                      work, rwork, result( 1 ) )
               CALL cunt01( 'Columns', m, mq, q, ldq, work, lwork,
     $                      rwork, result( 2 ) )
               CALL cunt01( 'Rows', mnmin, n, pt, ldpt, work, lwork,
     $                      rwork, result( 3 ) )
            END IF
*
*           Use CBDSQR to form the SVD of the bidiagonal matrix B:
*           B := U * S1 * VT, and compute Z = U' * Y.
*
            CALL scopy( mnmin, bd, 1, s1, 1 )
            IF( mnmin.GT.0 )
     $         CALL scopy( mnmin-1, be, 1, rwork, 1 )
            CALL clacpy( ' ', m, nrhs, y, ldx, z, ldx )
            CALL claset( 'Full', mnmin, mnmin, czero, cone, u, ldpt )
            CALL claset( 'Full', mnmin, mnmin, czero, cone, vt, ldpt )
*
            CALL cbdsqr( uplo, mnmin, mnmin, mnmin, nrhs, s1, rwork, vt,
     $                   ldpt, u, ldpt, z, ldx, rwork( mnmin+1 ),
     $                   iinfo )
*
*           Check error code from CBDSQR.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'CBDSQR(vects)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 4 ) = ulpinv
                  GO TO 150
               END IF
            END IF
*
*           Use CBDSQR to compute only the singular values of the
*           bidiagonal matrix B;  U, VT, and Z should not be modified.
*
            CALL scopy( mnmin, bd, 1, s2, 1 )
            IF( mnmin.GT.0 )
     $         CALL scopy( mnmin-1, be, 1, rwork, 1 )
*
            CALL cbdsqr( uplo, mnmin, 0, 0, 0, s2, rwork, vt, ldpt, u,
     $                   ldpt, z, ldx, rwork( mnmin+1 ), iinfo )
*
*           Check error code from CBDSQR.
*
            IF( iinfo.NE.0 ) THEN
               WRITE( nout, fmt = 9998 )'CBDSQR(values)', iinfo, m, n,
     $            jtype, ioldsd
               info = abs( iinfo )
               IF( iinfo.LT.0 ) THEN
                  RETURN
               ELSE
                  result( 9 ) = ulpinv
                  GO TO 150
               END IF
            END IF
*
*           Test 4:  Check the decomposition B := U * S1 * VT
*                5:  Check the computation Z := U' * Y
*                6:  Check the orthogonality of U
*                7:  Check the orthogonality of VT
*
            CALL cbdt03( uplo, mnmin, 1, bd, be, u, ldpt, s1, vt, ldpt,
     $                   work, result( 4 ) )
            CALL cbdt02( mnmin, nrhs, y, ldx, z, ldx, u, ldpt, work,
     $                   rwork, result( 5 ) )
            CALL cunt01( 'Columns', mnmin, mnmin, u, ldpt, work, lwork,
     $                   rwork, result( 6 ) )
            CALL cunt01( 'Rows', mnmin, mnmin, vt, ldpt, work, lwork,
     $                   rwork, result( 7 ) )
*
*           Test 8:  Check that the singular values are sorted in
*                    non-increasing order and are non-negative
*
            result( 8 ) = zero
            DO 110 i = 1, mnmin - 1
               IF( s1( i ).LT.s1( i+1 ) )
     $            result( 8 ) = ulpinv
               IF( s1( i ).LT.zero )
     $            result( 8 ) = ulpinv
  110       CONTINUE
            IF( mnmin.GE.1 ) THEN
               IF( s1( mnmin ).LT.zero )
     $            result( 8 ) = ulpinv
            END IF
*
*           Test 9:  Compare CBDSQR with and without singular vectors
*
            temp2 = zero
*
            DO 120 j = 1, mnmin
               temp1 = abs( s1( j )-s2( j ) ) /
     $                 max( sqrt( unfl )*max( s1( 1 ), one ),
     $                 ulp*max( abs( s1( j ) ), abs( s2( j ) ) ) )
               temp2 = max( temp1, temp2 )
  120       CONTINUE
*
            result( 9 ) = temp2
*
*           Test 10:  Sturm sequence test of singular values
*                     Go up by factors of two until it succeeds
*
            temp1 = thresh*( half-ulp )
*
            DO 130 j = 0, log2ui
               CALL ssvdch( mnmin, bd, be, s1, temp1, iinfo )
               IF( iinfo.EQ.0 )
     $            GO TO 140
               temp1 = temp1*two
  130       CONTINUE
*
  140       CONTINUE
            result( 10 ) = temp1
*
*           Use CBDSQR to form the decomposition A := (QU) S (VT PT)
*           from the bidiagonal form A := Q B PT.
*
            IF( .NOT.bidiag ) THEN
               CALL scopy( mnmin, bd, 1, s2, 1 )
               IF( mnmin.GT.0 )
     $            CALL scopy( mnmin-1, be, 1, rwork, 1 )
*
               CALL cbdsqr( uplo, mnmin, n, m, nrhs, s2, rwork, pt,
     $                      ldpt, q, ldq, y, ldx, rwork( mnmin+1 ),
     $                      iinfo )
*
*              Test 11:  Check the decomposition A := Q*U * S2 * VT*PT
*                   12:  Check the computation Z := U' * Q' * X
*                   13:  Check the orthogonality of Q*U
*                   14:  Check the orthogonality of VT*PT
*
               CALL cbdt01( m, n, 0, a, lda, q, ldq, s2, dumma, pt,
     $                      ldpt, work, rwork, result( 11 ) )
               CALL cbdt02( m, nrhs, x, ldx, y, ldx, q, ldq, work,
     $                      rwork, result( 12 ) )
               CALL cunt01( 'Columns', m, mq, q, ldq, work, lwork,
     $                      rwork, result( 13 ) )
               CALL cunt01( 'Rows', mnmin, n, pt, ldpt, work, lwork,
     $                      rwork, result( 14 ) )
            END IF
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  150       CONTINUE
            DO 160 j = 1, 14
               IF( result( j ).GE.thresh ) THEN
                  IF( nfail.EQ.0 )
     $               CALL slahd2( nout, path )
                  WRITE( nout, fmt = 9999 )m, n, jtype, ioldsd, j,
     $               result( j )
                  nfail = nfail + 1
               END IF
  160       CONTINUE
            IF( .NOT.bidiag ) THEN
               ntest = ntest + 14
            ELSE
               ntest = ntest + 5
            END IF
*
  170    CONTINUE
  180 CONTINUE
*
*     Summary
*
      CALL alasum( path, nout, nfail, ntest, 0 )
*
      RETURN
*
*     End of CCHKBD
*
 9999 FORMAT( ' M=', i5, ', N=', i5, ', type ', i2, ', seed=',
     $      4( i4, ',' ), ' test(', i2, ')=', g11.4 )
 9998 FORMAT( ' CCHKBD: ', a, ' returned INFO=', i6, '.', / 9x, 'M=',
     $      i6, ', N=', i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ),
     $      i5, ')' )
*

Here is the call graph for this function:

Here is the caller graph for this function: