LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches
sorbdb2.f
Go to the documentation of this file.
1*> \brief \b SORBDB2
2*
3* =========== DOCUMENTATION ===========
4*
5* Online html documentation available at
6* http://www.netlib.org/lapack/explore-html/
7*
8*> Download SORBDB2 + dependencies
9*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sorbdb2.f">
10*> [TGZ]</a>
11*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sorbdb2.f">
12*> [ZIP]</a>
13*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sorbdb2.f">
14*> [TXT]</a>
15*
16* Definition:
17* ===========
18*
19* SUBROUTINE SORBDB2( M, P, Q, X11, LDX11, X21, LDX21, THETA, PHI,
20* TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
21*
22* .. Scalar Arguments ..
23* INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
24* ..
25* .. Array Arguments ..
26* REAL PHI(*), THETA(*)
27* REAL TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
28* $ X11(LDX11,*), X21(LDX21,*)
29* ..
30*
31*
32*> \par Purpose:
33* =============
34*>
35*>\verbatim
36*>
37*> SORBDB2 simultaneously bidiagonalizes the blocks of a tall and skinny
38*> matrix X with orthonormal columns:
39*>
40*> [ B11 ]
41*> [ X11 ] [ P1 | ] [ 0 ]
42*> [-----] = [---------] [-----] Q1**T .
43*> [ X21 ] [ | P2 ] [ B21 ]
44*> [ 0 ]
45*>
46*> X11 is P-by-Q, and X21 is (M-P)-by-Q. P must be no larger than M-P,
47*> Q, or M-Q. Routines SORBDB1, SORBDB3, and SORBDB4 handle cases in
48*> which P is not the minimum dimension.
49*>
50*> The orthogonal matrices P1, P2, and Q1 are P-by-P, (M-P)-by-(M-P),
51*> and (M-Q)-by-(M-Q), respectively. They are represented implicitly by
52*> Householder vectors.
53*>
54*> B11 and B12 are P-by-P bidiagonal matrices represented implicitly by
55*> angles THETA, PHI.
56*>
57*>\endverbatim
58*
59* Arguments:
60* ==========
61*
62*> \param[in] M
63*> \verbatim
64*> M is INTEGER
65*> The number of rows X11 plus the number of rows in X21.
66*> \endverbatim
67*>
68*> \param[in] P
69*> \verbatim
70*> P is INTEGER
71*> The number of rows in X11. 0 <= P <= min(M-P,Q,M-Q).
72*> \endverbatim
73*>
74*> \param[in] Q
75*> \verbatim
76*> Q is INTEGER
77*> The number of columns in X11 and X21. 0 <= Q <= M.
78*> \endverbatim
79*>
80*> \param[in,out] X11
81*> \verbatim
82*> X11 is REAL array, dimension (LDX11,Q)
83*> On entry, the top block of the matrix X to be reduced. On
84*> exit, the columns of tril(X11) specify reflectors for P1 and
85*> the rows of triu(X11,1) specify reflectors for Q1.
86*> \endverbatim
87*>
88*> \param[in] LDX11
89*> \verbatim
90*> LDX11 is INTEGER
91*> The leading dimension of X11. LDX11 >= P.
92*> \endverbatim
93*>
94*> \param[in,out] X21
95*> \verbatim
96*> X21 is REAL array, dimension (LDX21,Q)
97*> On entry, the bottom block of the matrix X to be reduced. On
98*> exit, the columns of tril(X21) specify reflectors for P2.
99*> \endverbatim
100*>
101*> \param[in] LDX21
102*> \verbatim
103*> LDX21 is INTEGER
104*> The leading dimension of X21. LDX21 >= M-P.
105*> \endverbatim
106*>
107*> \param[out] THETA
108*> \verbatim
109*> THETA is REAL array, dimension (Q)
110*> The entries of the bidiagonal blocks B11, B21 are defined by
111*> THETA and PHI. See Further Details.
112*> \endverbatim
113*>
114*> \param[out] PHI
115*> \verbatim
116*> PHI is REAL array, dimension (Q-1)
117*> The entries of the bidiagonal blocks B11, B21 are defined by
118*> THETA and PHI. See Further Details.
119*> \endverbatim
120*>
121*> \param[out] TAUP1
122*> \verbatim
123*> TAUP1 is REAL array, dimension (P-1)
124*> The scalar factors of the elementary reflectors that define
125*> P1.
126*> \endverbatim
127*>
128*> \param[out] TAUP2
129*> \verbatim
130*> TAUP2 is REAL array, dimension (Q)
131*> The scalar factors of the elementary reflectors that define
132*> P2.
133*> \endverbatim
134*>
135*> \param[out] TAUQ1
136*> \verbatim
137*> TAUQ1 is REAL array, dimension (Q)
138*> The scalar factors of the elementary reflectors that define
139*> Q1.
140*> \endverbatim
141*>
142*> \param[out] WORK
143*> \verbatim
144*> WORK is REAL array, dimension (LWORK)
145*> \endverbatim
146*>
147*> \param[in] LWORK
148*> \verbatim
149*> LWORK is INTEGER
150*> The dimension of the array WORK. LWORK >= M-Q.
151*>
152*> If LWORK = -1, then a workspace query is assumed; the routine
153*> only calculates the optimal size of the WORK array, returns
154*> this value as the first entry of the WORK array, and no error
155*> message related to LWORK is issued by XERBLA.
156*> \endverbatim
157*>
158*> \param[out] INFO
159*> \verbatim
160*> INFO is INTEGER
161*> = 0: successful exit.
162*> < 0: if INFO = -i, the i-th argument had an illegal value.
163*> \endverbatim
164*
165* Authors:
166* ========
167*
168*> \author Univ. of Tennessee
169*> \author Univ. of California Berkeley
170*> \author Univ. of Colorado Denver
171*> \author NAG Ltd.
172*
173*> \ingroup unbdb2
174*
175*> \par Further Details:
176* =====================
177*>
178*> \verbatim
179*>
180*> The upper-bidiagonal blocks B11, B21 are represented implicitly by
181*> angles THETA(1), ..., THETA(Q) and PHI(1), ..., PHI(Q-1). Every entry
182*> in each bidiagonal band is a product of a sine or cosine of a THETA
183*> with a sine or cosine of a PHI. See [1] or SORCSD for details.
184*>
185*> P1, P2, and Q1 are represented as products of elementary reflectors.
186*> See SORCSD2BY1 for details on generating P1, P2, and Q1 using SORGQR
187*> and SORGLQ.
188*> \endverbatim
189*
190*> \par References:
191* ================
192*>
193*> [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
194*> Algorithms, 50(1):33-65, 2009.
195*>
196* =====================================================================
197 SUBROUTINE sorbdb2( M, P, Q, X11, LDX11, X21, LDX21, THETA,
198 $ PHI,
199 $ TAUP1, TAUP2, TAUQ1, WORK, LWORK, INFO )
200*
201* -- LAPACK computational routine --
202* -- LAPACK is a software package provided by Univ. of Tennessee, --
203* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
204*
205* .. Scalar Arguments ..
206 INTEGER INFO, LWORK, M, P, Q, LDX11, LDX21
207* ..
208* .. Array Arguments ..
209 REAL PHI(*), THETA(*)
210 REAL TAUP1(*), TAUP2(*), TAUQ1(*), WORK(*),
211 $ x11(ldx11,*), x21(ldx21,*)
212* ..
213*
214* ====================================================================
215*
216* .. Parameters ..
217 REAL NEGONE
218 PARAMETER ( NEGONE = -1.0e0 )
219* ..
220* .. Local Scalars ..
221 REAL C, S
222 INTEGER CHILDINFO, I, ILARF, IORBDB5, LLARF, LORBDB5,
223 $ lworkmin, lworkopt
224 LOGICAL LQUERY
225* ..
226* .. External Subroutines ..
227 EXTERNAL slarf1f, slarfgp, sorbdb5, srot, sscal,
228 $ xerbla
229* ..
230* .. External Functions ..
231 REAL SNRM2
232 EXTERNAL SNRM2
233* ..
234* .. Intrinsic Function ..
235 INTRINSIC atan2, cos, max, sin, sqrt
236* ..
237* .. Executable Statements ..
238*
239* Test input arguments
240*
241 info = 0
242 lquery = lwork .EQ. -1
243*
244 IF( m .LT. 0 ) THEN
245 info = -1
246 ELSE IF( p .LT. 0 .OR. p .GT. m-p ) THEN
247 info = -2
248 ELSE IF( q .LT. 0 .OR. q .LT. p .OR. m-q .LT. p ) THEN
249 info = -3
250 ELSE IF( ldx11 .LT. max( 1, p ) ) THEN
251 info = -5
252 ELSE IF( ldx21 .LT. max( 1, m-p ) ) THEN
253 info = -7
254 END IF
255*
256* Compute workspace
257*
258 IF( info .EQ. 0 ) THEN
259 ilarf = 2
260 llarf = max( p-1, m-p, q-1 )
261 iorbdb5 = 2
262 lorbdb5 = q-1
263 lworkopt = max( ilarf+llarf-1, iorbdb5+lorbdb5-1 )
264 lworkmin = lworkopt
265 work(1) = real( lworkopt )
266 IF( lwork .LT. lworkmin .AND. .NOT.lquery ) THEN
267 info = -14
268 END IF
269 END IF
270 IF( info .NE. 0 ) THEN
271 CALL xerbla( 'SORBDB2', -info )
272 RETURN
273 ELSE IF( lquery ) THEN
274 RETURN
275 END IF
276*
277* Reduce rows 1, ..., P of X11 and X21
278*
279 DO i = 1, p
280*
281 IF( i .GT. 1 ) THEN
282 CALL srot( q-i+1, x11(i,i), ldx11, x21(i-1,i), ldx21, c,
283 $ s )
284 END IF
285 CALL slarfgp( q-i+1, x11(i,i), x11(i,i+1), ldx11, tauq1(i) )
286 c = x11(i,i)
287 CALL slarf1f( 'R', p-i, q-i+1, x11(i,i), ldx11, tauq1(i),
288 $ x11(i+1,i), ldx11, work(ilarf) )
289 CALL slarf1f( 'R', m-p-i+1, q-i+1, x11(i,i), ldx11,
290 $ tauq1(i), x21(i,i), ldx21, work(ilarf) )
291 s = sqrt( snrm2( p-i, x11(i+1,i), 1 )**2
292 $ + snrm2( m-p-i+1, x21(i,i), 1 )**2 )
293 theta(i) = atan2( s, c )
294*
295 CALL sorbdb5( p-i, m-p-i+1, q-i, x11(i+1,i), 1, x21(i,i), 1,
296 $ x11(i+1,i+1), ldx11, x21(i,i+1), ldx21,
297 $ work(iorbdb5), lorbdb5, childinfo )
298 CALL sscal( p-i, negone, x11(i+1,i), 1 )
299 CALL slarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
300 IF( i .LT. p ) THEN
301 CALL slarfgp( p-i, x11(i+1,i), x11(i+2,i), 1, taup1(i) )
302 phi(i) = atan2( x11(i+1,i), x21(i,i) )
303 c = cos( phi(i) )
304 s = sin( phi(i) )
305 CALL slarf1f( 'L', p-i, q-i, x11(i+1,i), 1, taup1(i),
306 $ x11(i+1,i+1), ldx11, work(ilarf) )
307 END IF
308 CALL slarf1f( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
309 $ x21(i,i+1), ldx21, work(ilarf) )
310*
311 END DO
312*
313* Reduce the bottom-right portion of X21 to the identity matrix
314*
315 DO i = p + 1, q
316 CALL slarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1, taup2(i) )
317 CALL slarf1f( 'L', m-p-i+1, q-i, x21(i,i), 1, taup2(i),
318 $ x21(i,i+1), ldx21, work(ilarf) )
319 END DO
320*
321 RETURN
322*
323* End of SORBDB2
324*
325 END
326
subroutine xerbla(srname, info)
Definition cblat2.f:3285
subroutine slarfgp(n, alpha, x, incx, tau)
SLARFGP generates an elementary reflector (Householder matrix) with non-negative beta.
Definition slarfgp.f:102
subroutine srot(n, sx, incx, sy, incy, c, s)
SROT
Definition srot.f:92
subroutine sscal(n, sa, sx, incx)
SSCAL
Definition sscal.f:79
subroutine sorbdb2(m, p, q, x11, ldx11, x21, ldx21, theta, phi, taup1, taup2, tauq1, work, lwork, info)
SORBDB2
Definition sorbdb2.f:200
subroutine sorbdb5(m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2, ldq2, work, lwork, info)
SORBDB5
Definition sorbdb5.f:155
subroutine slarf1f(side, m, n, v, incv, tau, c, ldc, work)
SLARF1F applies an elementary reflector to a general rectangular
Definition slarf1f.f:123