sorbdb5.f

Go to the documentation of this file.

*> \brief \b SORBDB5
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SORBDB5 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sorbdb5.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sorbdb5.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sorbdb5.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE SORBDB5( M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2,
*                           LDQ2, WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INCX1, INCX2, INFO, LDQ1, LDQ2, LWORK, M1, M2,
*      $                   N
*       ..
*       .. Array Arguments ..
*       REAL               Q1(LDQ1,*), Q2(LDQ2,*), WORK(*), X1(*), X2(*)
*       ..
*
*
*> \par Purpose:
*  =============
*>
*>\verbatim
*>
*> SORBDB5 orthogonalizes the column vector
*>      X = [ X1 ]
*>          [ X2 ]
*> with respect to the columns of
*>      Q = [ Q1 ] .
*>          [ Q2 ]
*> The columns of Q must be orthonormal.
*>
*> If the projection is zero according to Kahan's "twice is enough"
*> criterion, then some other vector from the orthogonal complement
*> is returned. This vector is chosen in an arbitrary but deterministic
*> way.
*>
*>\endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M1
*> \verbatim
*>          M1 is INTEGER
*>           The dimension of X1 and the number of rows in Q1. 0 <= M1.
*> \endverbatim
*>
*> \param[in] M2
*> \verbatim
*>          M2 is INTEGER
*>           The dimension of X2 and the number of rows in Q2. 0 <= M2.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>           The number of columns in Q1 and Q2. 0 <= N.
*> \endverbatim
*>
*> \param[in,out] X1
*> \verbatim
*>          X1 is REAL array, dimension (M1)
*>           On entry, the top part of the vector to be orthogonalized.
*>           On exit, the top part of the projected vector.
*> \endverbatim
*>
*> \param[in] INCX1
*> \verbatim
*>          INCX1 is INTEGER
*>           Increment for entries of X1.
*> \endverbatim
*>
*> \param[in,out] X2
*> \verbatim
*>          X2 is REAL array, dimension (M2)
*>           On entry, the bottom part of the vector to be
*>           orthogonalized. On exit, the bottom part of the projected
*>           vector.
*> \endverbatim
*>
*> \param[in] INCX2
*> \verbatim
*>          INCX2 is INTEGER
*>           Increment for entries of X2.
*> \endverbatim
*>
*> \param[in] Q1
*> \verbatim
*>          Q1 is REAL array, dimension (LDQ1, N)
*>           The top part of the orthonormal basis matrix.
*> \endverbatim
*>
*> \param[in] LDQ1
*> \verbatim
*>          LDQ1 is INTEGER
*>           The leading dimension of Q1. LDQ1 >= M1.
*> \endverbatim
*>
*> \param[in] Q2
*> \verbatim
*>          Q2 is REAL array, dimension (LDQ2, N)
*>           The bottom part of the orthonormal basis matrix.
*> \endverbatim
*>
*> \param[in] LDQ2
*> \verbatim
*>          LDQ2 is INTEGER
*>           The leading dimension of Q2. LDQ2 >= M2.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>           The dimension of the array WORK. LWORK >= N.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>           = 0:  successful exit.
*>           < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup unbdb5
*
*  =====================================================================
      SUBROUTINE sorbdb5( M1, M2, N, X1, INCX1, X2, INCX2, Q1, LDQ1, Q2,
     $                    LDQ2, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INCX1, INCX2, INFO, LDQ1, LDQ2, LWORK, M1, M2,
     $                   n
*     ..
*     .. Array Arguments ..
      REAL               Q1(LDQ1,*), Q2(LDQ2,*), WORK(*), X1(*), X2(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               REALZERO
      parameter( realzero = 0.0e0 )
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            CHILDINFO, I, J
      REAL               EPS, NORM, SCL, SSQ
*     ..
*     .. External Subroutines ..
      EXTERNAL           slassq, sorbdb6, sscal, xerbla
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SNRM2
      EXTERNAL           slamch, snrm2
*     ..
*     .. Intrinsic Function ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test input arguments
*
      info = 0
      IF( m1 .LT. 0 ) THEN
         info = -1
      ELSE IF( m2 .LT. 0 ) THEN
         info = -2
      ELSE IF( n .LT. 0 ) THEN
         info = -3
      ELSE IF( incx1 .LT. 1 ) THEN
         info = -5
      ELSE IF( incx2 .LT. 1 ) THEN
         info = -7
      ELSE IF( ldq1 .LT. max( 1, m1 ) ) THEN
         info = -9
      ELSE IF( ldq2 .LT. max( 1, m2 ) ) THEN
         info = -11
      ELSE IF( lwork .LT. n ) THEN
         info = -13
      END IF
*
      IF( info .NE. 0 ) THEN
         CALL xerbla( 'SORBDB5', -info )
         RETURN
      END IF
*
      eps = slamch( 'Precision' )
*
*     Project X onto the orthogonal complement of Q if X is nonzero
*
      scl = realzero
      ssq = realzero
      CALL slassq( m1, x1, incx1, scl, ssq )
      CALL slassq( m2, x2, incx2, scl, ssq )
      norm = scl * sqrt( ssq )
*
      IF( norm .GT. n * eps ) THEN
*        Scale vector to unit norm to avoid problems in the caller code.
*        Computing the reciprocal is undesirable but
*         * xLASCL cannot be used because of the vector increments and
*         * the round-off error has a negligible impact on
*           orthogonalization.
         CALL sscal( m1, one / norm, x1, incx1 )
         CALL sscal( m2, one / norm, x2, incx2 )
         CALL sorbdb6( m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2,
     $              ldq2, work, lwork, childinfo )
*
*        If the projection is nonzero, then return
*
         IF( snrm2(m1,x1,incx1) .NE. realzero
     $       .OR. snrm2(m2,x2,incx2) .NE. realzero ) THEN
            RETURN
         END IF
      END IF
*
*     Project each standard basis vector e_1,...,e_M1 in turn, stopping
*     when a nonzero projection is found
*
      DO i = 1, m1
         DO j = 1, m1
            x1(j) = zero
         END DO
         x1(i) = one
         DO j = 1, m2
            x2(j) = zero
         END DO
         CALL sorbdb6( m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2,
     $                 ldq2, work, lwork, childinfo )
         IF( snrm2(m1,x1,incx1) .NE. realzero
     $       .OR. snrm2(m2,x2,incx2) .NE. realzero ) THEN
            RETURN
         END IF
      END DO
*
*     Project each standard basis vector e_(M1+1),...,e_(M1+M2) in turn,
*     stopping when a nonzero projection is found
*
      DO i = 1, m2
         DO j = 1, m1
            x1(j) = zero
         END DO
         DO j = 1, m2
            x2(j) = zero
         END DO
         x2(i) = one
         CALL sorbdb6( m1, m2, n, x1, incx1, x2, incx2, q1, ldq1, q2,
     $                 ldq2, work, lwork, childinfo )
         IF( snrm2(m1,x1,incx1) .NE. realzero
     $       .OR. snrm2(m2,x2,incx2) .NE. realzero ) THEN
            RETURN
         END IF
      END DO
*
      RETURN
*
*     End of SORBDB5
*
      END